i21rot.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i21rot          ../starter/source/interfaces/inter3d1/i21rot.f
!||--- called by ------------------------------------------------------
!||    inint3_thkvar   ../starter/source/interfaces/inter3d1/inint3_thkvar.F
!||====================================================================
      SUBROUTINE i21rot(IROT   ,XG, ROT, NMN, NOD_NORMAL,
     .                  XM0    ,BRACKET,NRTM,IRECTM,LXM ,
     .                  LYM    ,LZM    ,NSN ,XSAV  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IROT, NMN, NRTM, NSN, IRECTM(4,*)
      my_real
     .   rot(9), nod_normal(3,*), xm0(3,*), bracket(3),
     .   lxm, lym, lzm, xsav(3,*)
      DOUBLE PRECISION XG(3)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, IX
C     REAL
      my_real
     .     xi(3), nxi(3), lmax, dd, 
     .     x0, y0, z0, x1, y1, z1, xxx, yyy, zzz
C------------------------------------
C     Coordonnees initiales cote main : passage en coord locales.
C------------------------------------
      IF(irot==0)THEN
C--------------------------------------
        DO i=1,nmn
          DO j=1,3
            xm0(j,i)=xm0(j,i)-xg(j)
          END DO
        END DO
      ELSE
C--------------------------------------
        lmax=zero
        DO i=1,nmn
          DO j=1,3
            xi(j)=xm0(j,i)-xg(j)
          END DO
          xm0(1,i)= rot(1)*xi(1)+rot(2)*xi(2)+rot(3)*xi(3)
          xm0(2,i)= rot(4)*xi(1)+rot(5)*xi(2)+rot(6)*xi(3)
          xm0(3,i)= rot(7)*xi(1)+rot(8)*xi(2)+rot(9)*xi(3)
          dd=xm0(1,i)**2+xm0(2,i)**2+xm0(3,i)**2
          IF(dd > lmax)THEN
            lmax=dd
            bracket(1)=xm0(1,i)
            bracket(2)=xm0(2,i)
            bracket(3)=xm0(3,i)
          END IF
          xsav(1,nsn+2)=
     .       rot(1)*bracket(1)+rot(4)*bracket(2)+rot(7)*bracket(3)
          xsav(2,nsn+2)=
     .       rot(2)*bracket(1)+rot(5)*bracket(2)+rot(8)*bracket(3)
          xsav(3,nsn+2)=
     .       rot(3)*bracket(1)+rot(6)*bracket(2)+rot(9)*bracket(3)
          DO j=1,3
            nxi(j)=nod_normal(j,i)
          END DO
          nod_normal(1,i)= rot(1)*nxi(1)+rot(2)*nxi(2)+rot(3)*nxi(3)
          nod_normal(2,i)= rot(4)*nxi(1)+rot(5)*nxi(2)+rot(6)*nxi(3)
          nod_normal(3,i)= rot(7)*nxi(1)+rot(8)*nxi(2)+rot(9)*nxi(3)
        END DO
C--------------------------------------
        lxm=zero
        lym=zero
        lzm=zero
        DO i=1,nrtm
          x0=ep30
          x1=-ep30
          y0=ep30
          y1=-ep30
          z0=ep30
          z1=-ep30
          DO j=1,4
            ix=irectm(j,i)
            xxx=xm0(1,ix)
            yyy=xm0(2,ix)
            zzz=xm0(3,ix)
            x0=min(x0,xxx)
            y0=min(y0,yyy)
            z0=min(z0,zzz)
            x1=max(x1,xxx)
            y1=max(y1,yyy)
            z1=max(z1,zzz)
          END DO
          lxm=max(lxm,x1-x0)
          lym=max(lym,y1-y0)
          lzm=max(lzm,z1-z0)
        ENDDO
C------------------------------------
      END IF
      RETURN
      END