i25gap3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i25gap3       ../engine/source/interfaces/int25/i25gap3.F
!||--- called by ------------------------------------------------------
!||    i25main_gap   ../engine/source/interfaces/int25/i25main_gap.F
!||--- calls      -----------------------------------------------------
!||    my_barrier    ../engine/source/system/machine.F
!||====================================================================
      SUBROUTINE i25gap3(
     1 ITASK,
     2 NRTM  ,IRECT   ,GAP_NM   ,GAP_M   ,
     3 NMN   ,MSR     ,GAPN_M   ,
     4 GAPMAX_M ,GAPSCALE ,MSEGTYP , THKNOD, 
     5 GAPMSAV, MAXDGAP_G)        
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NRTM,IRECT(4,*),    
     .   MSR(*),NMN,MSEGTYP(*),ITASK
C     REAL
      my_real
     .   GAP_NM(4,*),GAP_M(*), GAPMSAV(*), THKNOD(NUMNOD),
     .   gapn_m(*),gapmax_m, gapscale, maxdgap_g
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K,IW,I1,I2,I3,MG,M,IP,IGTYP,
     .        NMNF,NMNL,NRTMF,NRTML,IERROR
      my_real,
     .       DIMENSION(:), ALLOCATABLE :: WA
      my_real MAXDGAP_L
      SAVE wa
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      ALLOCATE(wa(numnod),stat=ierror)
      nmnf = 1 + itask*nmn / nthread
      nmnl = (itask+1)*nmn / nthread
      nrtmf = 1 + itask * nrtm / nthread
      nrtml = (itask+1) * nrtm / nthread
      maxdgap_l = -ep30
C------------------------------------
C GAP_S = Secnds nodes gap [NSN]
C GAPN_M = gap for each node on main [NMN]
C GAP_NM = gap of each node on each main segment [4*NRTM]
C GAP_M = for each main segment, max of gap of its connected nodes [NRTM]
 
#include "vectorize.inc"
      DO i=nmnf,nmnl
        m = msr(i)
        wa(m)=half*gapscale*thknod(m)
      END DO
C
      CALL my_barrier
C
!$OMP SINGLE
#include "vectorize.inc"
      DO i=1,nrtm
        IF (msegtyp(i)==0) THEN
          DO j=1,4
            m=irect(j,i)
            wa(m) = zero
          END DO
        END IF 
      END DO
!$OMP END SINGLE 
C
#include "vectorize.inc"
      DO i=nmnf,nmnl
        m = msr(i)
        wa(m) = min(wa(m),gapmax_m)
        gapn_m(i) = wa(m)
      END DO
C
      CALL my_barrier
C
#include "vectorize.inc" 
      DO i=nrtmf,nrtml 
        gap_m(i) = zero
        DO j=1,4
          m=irect(j,i)
          gap_nm(j,i)=wa(m)
          gap_m(i) = max(gap_m(i),wa(m))
        END DO
      END DO
C
#include "vectorize.inc"
C calculate the maximum change in the gap, to be used in sorting criteria
      DO i=nrtmf,nrtml
        maxdgap_l = max(maxdgap_l,gap_m(i)-gapmsav(i))
      END DO
C
      CALL my_barrier
C
#include "lockon.inc"
C obtain the max dgap for all
      maxdgap_g = max(maxdgap_l,maxdgap_g)
#include "lockoff.inc"      
 
      RETURN
      END
C