i25sors.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i25sors         ../starter/source/interfaces/inter3d1/i25sors.F
!||--- called by ------------------------------------------------------
!||    inint3          ../starter/source/interfaces/inter3d1/inint3.F
!||--- calls      -----------------------------------------------------
!||    ancmsg          ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod     ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i25sors(NSN  ,NRTS, ITAB, ILEV  ,IPARI, 
     .                  INTBUF_TAB)
C
      USE message_mod
      USE intbufdef_mod 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN, NRTS, ITAB(*), ILEV, IPARI(NPARI)
      TYPE(intbuf_struct_) INTBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J, N, M, K, NISUB, NISUBS
      INTEGER IERROR,WORK(70000)
      INTEGER, DIMENSION(:),ALLOCATABLE :: ITRI, INDEX, LISUBS, INFLG_SUBS, ADDSUBS
      INTEGER, DIMENSION(:,:),ALLOCATABLE :: ISAV
C-----------------------------------------------
      ALLOCATE (itri(nsn),isav(3,nsn),index(2*nsn),stat=ierror)
      IF (ierror /= 0) 
     .  CALL ancmsg(msgid=268,anmode=aninfo,
     .                     msgtype=msgerror,
     .               c1='SORTING SECONDARY NODES IN INTERFACE TYPE25')
C--------------------------------------------------------------
C     Tri nds SECONDARYs vs ID
C--------------------------------------------------------------
C
       DO n=1,nsn
         itri(n)  =itab(intbuf_tab%NSV(n))
         isav(1,n)=intbuf_tab%NSV(n)
         IF(ilev==2) isav(2,n)=intbuf_tab%NBINFLG(n)
       END DO
C
       nisub = ipari(36)
       nisubs =ipari(37)
       IF(nisub > 0)THEN
         ALLOCATE (lisubs(nisubs),inflg_subs(nisubs),addsubs(nsn+1),stat=ierror)
         IF (ierror /= 0) 
     .     CALL ancmsg(msgid=268,anmode=aninfo,
     .                     msgtype=msgerror,
     .                     c1='SORTING SECONDARY NODES IN INTERFACE TYPE25')
         addsubs(1:nsn+1)    =intbuf_tab%ADDSUBS(1:nsn+1)
         lisubs(1:nisubs)    =intbuf_tab%LISUBS(1:nisubs)
         inflg_subs(1:nisubs)=intbuf_tab%INFLG_SUBS(1:nisubs)
       END IF
C
       CALL my_orders(0,work,itri,index,nsn,1)
C
       DO n=1,nsn
         intbuf_tab%NSV(n)    =isav(1,index(n))
         IF(ilev==2) intbuf_tab%NBINFLG(n)=isav(2,index(n))
       END DO
C
       IF(nisub > 0)THEN
         intbuf_tab%ADDSUBS(1)=1         
         DO n=1,nsn
           m=index(n)
           intbuf_tab%ADDSUBS(n+1)= intbuf_tab%ADDSUBS(n)
     .                            + addsubs(m+1) - addsubs(m)
           DO k=addsubs(m),addsubs(m+1)-1
             intbuf_tab%LISUBS(intbuf_tab%ADDSUBS(n)+k-addsubs(m))    =lisubs(k)
             intbuf_tab%INFLG_SUBS(intbuf_tab%ADDSUBS(n)+k-addsubs(m))=inflg_subs(k)
           END DO
         END DO
       END IF
C
       DO n=1,nrts
         DO j=1,4
           m = intbuf_tab%IRECTS(4*(n-1)+j)
           IF(m/=0) intbuf_tab%IRECTS(4*(n-1)+j)=isav(1,index(m))
         END DO
       END DO
C
      DEALLOCATE (itri,isav,index)
      IF(nisub > 0)DEALLOCATE (lisubs,inflg_subs,addsubs)
C--------------------------------------------------------------
      RETURN
      END