i3dis3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i3dis3    ../engine/source/interfaces/inter3d/i3dis3.F
!||--- called by ------------------------------------------------------
!||    i5ke3     ../engine/source/interfaces/inter3d/i5ke3.F
!||    i6main    ../engine/source/interfaces/inter3d/i6main.F
!||    i9main3   ../engine/source/interfaces/int09/i9main3.F
!||    intvo3    ../engine/source/interfaces/inter3d/intvo3.F
!||    ud_int5   ../engine/source/implicit/upd_glob_k.F
!||====================================================================
      SUBROUTINE i3dis3(
     1   IGIMP,   NTY,     DIST,    X1,
     2   X2,      X3,      X4,      XI,
     3   Y1,      Y2,      Y3,      Y4,
     4   YI,      Z1,      Z2,      Z3,
     5   Z4,      ZI,      XFACE,   N1,
     6   N2,      N3,      SSC,     TTC,
     7   ALP,     ANS,     XP,      YP,
     8   ZP,      H1,      H2,      H3,
     9   H4,      LFT,     LLT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(INOUT) :: LFT
      INTEGER, INTENT(INOUT) :: LLT
      INTEGER IGIMP,NTY
      my_real DIST(*)
      my_real, DIMENSION(MVSIZ), INTENT(IN) ::  X1,X2,X3,X4,XI
      my_real, DIMENSION(MVSIZ), INTENT(IN) ::  Y1,Y2,Y3,Y4,YI
      my_real, DIMENSION(MVSIZ), INTENT(IN) ::  Z1,Z2,Z3,Z4,ZI
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) ::  XFACE,ANS
      my_real, DIMENSION(MVSIZ), INTENT(IN) ::  N1,N2,N3,ALP
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: xp,yp,zp,ssc,ttc
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: h1,h2,h3,h4
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C-----------------------------------------------
      DO i=lft,llt
        IF (xface(i) == zero) cycle
        IF (abs(ssc(i))>one+alp(i) .OR. abs(ttc(i))>one+alp(i)) THEN
          xface(i)=zero
        ELSE
          IF(abs(ssc(i)) > one) ssc(i)=ssc(i)/abs(ssc(i))
          IF(abs(ttc(i)) > one) ttc(i)=ttc(i)/abs(ttc(i))
        ENDIF
      END DO
C
      igimp=0
      DO i=lft,llt
        igimp = igimp + abs(xface(i))
      END DO
      IF (igimp == 0) RETURN
C
      DO i=lft,llt
        h1(i) = fourth*(one-ttc(i))*(one-ssc(i))
        h2(i) = fourth*(one-ttc(i))*(one+ssc(i))
        h3(i) = fourth*(one+ttc(i))*(one+ssc(i))
        h4(i) = fourth*(one+ttc(i))*(one-ssc(i))
      END DO
C
      DO i=lft,llt
        xp(i)=h1(i)*x1(i)+h2(i)*x2(i)+h3(i)*x3(i)+h4(i)*x4(i)
        yp(i)=h1(i)*y1(i)+h2(i)*y2(i)+h3(i)*y3(i)+h4(i)*y4(i)
        zp(i)=h1(i)*z1(i)+h2(i)*z2(i)+h3(i)*z3(i)+h4(i)*z4(i)
      END DO
C
      DO i=lft,llt
        ans(i)= n1(i)*(xi(i)-xp(i))
     .         +n2(i)*(yi(i)-yp(i))
     .         +n3(i)*(zi(i)-zp(i))
      END DO
      IF (nty == 8) THEN
        DO i=lft,llt
          dist(i) = ans(i)
        ENDDO
      ENDIF
C-----------
      RETURN
      END