i6damp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i6damp    ../engine/source/interfaces/inter3d/i6damp.f
!||--- called by ------------------------------------------------------
!||    i6main    ../engine/source/interfaces/inter3d/i6main.F
!||--- calls      -----------------------------------------------------
!||    ninterp   ../engine/source/interfaces/int14/ninterp.F
!||====================================================================
      SUBROUTINE i6damp(
     1   V,       NPC,     TF,      IRECT,
     2   MSR,     NSV,     IRTL,    IRTLO,
     3   CST,     ES,      EM,      VISC,
     4   NDAMP1,  NDAMP2,  LOLD,    MASS,
     5   VNI,     ASCALF,  ASCALV,  FSCALV,
     6   H1,      H2,      H3,      H4,
     7   FNI,     FXI,     FYI,     FZI,
     8   FX1,     FX2,     FX3,     FX4,
     9   FY1,     FY2,     FY3,     FY4,
     A   FZ1,     FZ2,     FZ3,     FZ4,
     B   LFT,     LLT,     NFT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(INOUT) :: LFT
      INTEGER, INTENT(INOUT) :: LLT
      INTEGER, INTENT(INOUT) :: NFT
      INTEGER NDAMP1 ,NDAMP2
      INTEGER IRECT(4,*),MSR(*),NSV(*),IRTL(*),IRTLO(*),NPC(*),LOLD(*)
C     REAL
      my_real
     .   VISC,ASCALF,ASCALV,FSCALV
      my_real
     .   V(3,*),CST(2,*),ES(*),EM(*),TF(*),MASS(*),VNI(*)
      my_real, DIMENSION(MVSIZ), INTENT(IN) :: H1,H2,H3,H4,FNI
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: fxi,fyi,fzi
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: fx1,fx2,fx3,fx4
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: fy1,fy2,fy3,fy4
      my_real, DIMENSION(MVSIZ), INTENT(INOUT) :: fz1,fz2,fz3,fz4
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IG,IL, L, J3, J2, J1, I3, I2, I1
C     REAL
      my_real
     .   fdamp
      my_real
     .   vis(llt),viscv(llt),fact(llt),xx(llt)
C-----------------------------------------------
C     Coefficient d'amortissement
C--------------------------------
      IF (ndamp1 > 0) THEN    ! velocity function
        DO i=lft,llt
          xx(i) = vni(i)*ascalv
        ENDDO 
        CALL ninterp(ndamp1,npc,tf,llt,xx,viscv)
      ELSE
        viscv(1:llt) = zero
      ENDIF 
c
      IF (ndamp2 > 0) THEN    ! Force amplification factor
        DO i=lft,llt
          xx(i) = fni(i)*ascalf
        ENDDO 
        CALL ninterp(ndamp2,npc,tf,llt,xx,fact)
      ELSE
        fact(1:llt) = one
      ENDIF 
C--------------------------------
      DO  i=lft,llt
        il = i+nft
        fxi(i) = zero
        fyi(i) = zero
        fzi(i) = zero
c
        IF (lold(i) /= 0) THEN
          ig = nsv(il)     
          l  = irtl(il)
c
          fdamp = - (visc*vni(i) + fscalv*viscv(i))*fact(i)   
c     
c          FXI(I) = N1(I)*FDAMP
c          FYI(I) = N2(I)*FDAMP
c          FZI(I) = N3(I)*FDAMP
          fxi(i) = fdamp
          fyi(i) = fdamp
          fzi(i) = fdamp
c
          fx1(i)=fxi(i)*h1(i)
          fy1(i)=fyi(i)*h1(i)
          fz1(i)=fzi(i)*h1(i)
C
          fx2(i)=fxi(i)*h2(i)
          fy2(i)=fyi(i)*h2(i)
          fz2(i)=fzi(i)*h2(i)
C
          fx3(i)=fxi(i)*h3(i)
          fy3(i)=fyi(i)*h3(i)
          fz3(i)=fzi(i)*h3(i)
C
          fx4(i)=fxi(i)*h4(i)
          fy4(i)=fyi(i)*h4(i)
          fz4(i)=fzi(i)*h4(i)
c
c         Force visc main        
c
          j3=3*irect(1,l)
          j2=j3-1
          j1=j2-1
          em(j1)=em(j1)+fx1(i)
          em(j2)=em(j2)+fy1(i)
          em(j3)=em(j3)+fz1(i)
C
          j3=3*irect(2,l)
          j2=j3-1
          j1=j2-1
          em(j1)=em(j1)+fx2(i)
          em(j2)=em(j2)+fy2(i)
          em(j3)=em(j3)+fz2(i)
C
          j3=3*irect(3,l)
          j2=j3-1
          j1=j2-1
          em(j1)=em(j1)+fx3(i)
          em(j2)=em(j2)+fy3(i)
          em(j3)=em(j3)+fz3(i)
C
          j3=3*irect(4,l)
          j2=j3-1
          j1=j2-1
          em(j1)=em(j1)+fx4(i)
          em(j2)=em(j2)+fy4(i)
          em(j3)=em(j3)+fz4(i)
c
c         Force visc secnd        
c
          i3 = 3*il
          i2 = i3-1
          i1 = i2-1
          es(i1) = es(i1)-fxi(i)
          es(i2) = es(i2)-fyi(i)
          es(i3) = es(i3)-fzi(i)
c
        ENDIF    ! LOLD
C
      ENDDO      ! I=LFT,LLT
C-----------
      RETURN
      END