i9grd2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i9grd2         ../engine/source/interfaces/int09/i9grd2.F
!||--- called by ------------------------------------------------------
!||    i9wal2         ../engine/source/interfaces/int09/i9wal2.F
!||--- calls      -----------------------------------------------------
!||    initbuf        ../engine/share/resol/initbuf.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    element_mod    ../common_source/modules/elements/element_mod.F90
!||    initbuf_mod    ../engine/share/resol/initbuf.F
!||====================================================================
      SUBROUTINE i9grd2(IERR  ,AREA  ,TSTIF    ,T      ,VOL     ,
     2                  II    ,X     ,IXQ      ,IX     ,
     3                  IPARG ,PM    ,ELBUF_TAB,IGROU  ,IELN    )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE initbuf_mod
      USE elbufdef_mod  
      use element_mod , only : nixq          
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER II, IGROU, IELN, IERR, IX(4), IXQ(NIXQ),IPARG(NPARG,*) 
C     REAL
      my_real
     .   dist, area, tstif, t, vol, x(3,*), pm(npropm,*)
      TYPE (ELBUF_STRUCT_), DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, N1, N2, NG,MAT
      my_real
     .  y1, y2, z1, z2,ny, nz, dy, dz,norm,cond
      INTEGER :: LLT ,NFT ,MTN ,IAD ,ITY ,NPT ,JALE ,ISMSTR ,JEUL ,JTUR ,JTHE ,JLAG ,JMULT ,JHBE
      INTEGER :: JIVF, NVAUX, JPOR, JCVT, JCLOSE, JPLASOL, IREP, IINT, IGTYP
      INTEGER :: ISORTH, ISORTHG, ISRAT, ISROT, ICSEN, IFAILURE, JSMS
 
C-----------------------------------------------
      ierr = 0
C---------------------------------
C         search for the element in the buffer
C---------------------------------
          DO 200 ng=1,ngroup
            CALL initbuf(iparg    ,ng      ,                  
     2            mtn     ,llt     ,nft     ,iad     ,ity     ,
     3            npt     ,jale    ,ismstr  ,jeul    ,jtur    ,
     4            jthe    ,jlag    ,jmult   ,jhbe    ,jivf    ,
     5            nvaux   ,jpor    ,jcvt    ,jclose  ,jplasol ,
     6            irep    ,iint    ,igtyp   ,israt   ,isrot   ,
     7            icsen   ,isorth  ,isorthg ,ifailure,jsms    )
            IF(ity/=2)          GO TO 200
            IF(ii>nft+llt)     GO TO 200
            IF(iparg(8,ng)==1.OR.jthe/=1)THEN
              ierr = 1
              RETURN
            ENDIF
            i = ii - nft
            GOTO 250
  200     CONTINUE
              ierr = 1
              RETURN
  250     CONTINUE
 
          igrou = ng
          ieln  = i
          vol   = elbuf_tab(ng)%GBUF%VOL(i)
C----------------------
C     CONDUCTION
C----------------------
            n1=ix(1)
            n2=ix(2)
C
            y1=x(2,n1)
            z1=x(3,n1)
C
            y2=x(2,n2)
            z2=x(3,n2)
C
C------------------------------------------
C         calculation of the vector surface (*1.)
C------------------------------------------
            ny= (z2-z1)
            nz=-(y2-y1)
            norm = sqrt(ny**2 + nz**2)
C--------+---------+---------+---------+---------+---------+---------+--
C         calculation of the distance between center and surface (*4.)
C-------------------------------------------------------------
            dy = two*(y1 + y2)
     .          -x(2,ixq(2))-x(2,ixq(3))
     .          -x(2,ixq(4))-x(2,ixq(5))
C
            dz = two*(z1 + z2)
     .          -x(3,ixq(2))-x(3,ixq(3))
     .          -x(3,ixq(4))-x(3,ixq(5))
C----------------------------------------------------------
C         CALCULATION DISTANCE ET 1/2 SURFACE(SURFACE NODALE))
C----------------------------------------------------------
            dist = fourth*(dy*ny+dz*nz) / max(em15,norm) 
            area = half*norm
C--------------------------------------------
C         calculation of the thermal resistance
C--------------------------------------------
            t = elbuf_tab(ng)%GBUF%TEMP(i)
            mat  =ixq(1)
            IF(t<=pm(80,mat))THEN
             cond=pm(75,mat)+pm(76,mat)*t
            ELSE
             cond=pm(77,mat)+pm(78,mat)*t
            ENDIF
            tstif = dist / cond
C
C
      RETURN
      END