i9grd3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i9grd3         ../engine/source/interfaces/int09/i9grd3.F
!||--- called by ------------------------------------------------------
!||    i9wal3         ../engine/source/interfaces/int09/i9wal3.F
!||--- calls      -----------------------------------------------------
!||    initbuf        ../engine/share/resol/initbuf.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    element_mod    ../common_source/modules/elements/element_mod.F90
!||    initbuf_mod    ../engine/share/resol/initbuf.F
!||====================================================================
      SUBROUTINE i9grd3(IERR  ,AREA  ,TSTIF    ,T      ,VOL     ,
     2                  II    ,X     ,IXS      ,IX     ,
     3                  IPARG ,PM    ,ELBUF_TAB,IGROU  ,IELN    )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE initbuf_mod
      USE elbufdef_mod            
      use element_mod , only : nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER II, IGROU, IELN , IERR, IX(4), IXS(NIXS),IPARG(NPARG,NGROUP) 
      my_real
     .   area, tstif, t, vol, x(3,numnod), pm(npropm,nummat)
      TYPE (ELBUF_STRUCT_), DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, N1, N2, N3, N4, NG,MAT
      my_real
     .  x1, x2, x3, x4, y1, y2, y3, y4, z1, z2, z3, z4,
     .  nx, ny, nz, dx, dy, dz, norm, dist, cond
      INTEGER :: LLT ,NFT ,MTN ,IAD ,ITY ,NPT ,JALE ,ISMSTR ,JEUL ,JTUR ,JTHE ,JLAG ,JMULT ,JHBE
      INTEGER :: JIVF, NVAUX, JPOR, JCVT, JCLOSE, JPLASOL, IREP, IINT, IGTYP
      INTEGER :: ISORTH, ISORTHG, ISRAT, ISROT, ICSEN, IFAILURE, JSMS
 
C-----------------------------------------------
      ierr = 0
C---------------------------------
C         search for the element in the buffer
C---------------------------------
          DO 200 ng=ii/nvsiz+1,ngroup
          CALL initbuf(iparg    ,ng      ,                    
     2          mtn     ,llt     ,nft     ,iad     ,ity     ,  
     3          npt     ,jale    ,ismstr  ,jeul    ,jtur    ,  
     4          jthe    ,jlag    ,jmult   ,jhbe    ,jivf    ,  
     5          nvaux   ,jpor    ,jcvt    ,jclose  ,jplasol ,  
     6          irep    ,iint    ,igtyp   ,israt   ,isrot   ,  
     7          icsen   ,isorth  ,isorthg ,ifailure,jsms    )
            IF(ity/=1)          GO TO 200
            IF(ii>nft+llt)     GO TO 200
            IF(iparg(8,ng)==1.OR.jthe/=1)THEN
              ierr = 1
              RETURN
            ENDIF
            i = ii - nft
            GOTO 250
  200     CONTINUE
              ierr = 1
              RETURN
  250     CONTINUE
 
          igrou = ng
          ieln  = i
          vol   = elbuf_tab(ng)%GBUF%VOL(i)
C----------------------
C     CONDUCTION
C----------------------
            n1=ix(1)
            n2=ix(2)
            n3=ix(3)
            n4=ix(4)
C
            x1=x(1,n1)
            y1=x(2,n1)
            z1=x(3,n1)
C
            x2=x(1,n2)
            y2=x(2,n2)
            z2=x(3,n2)
C
            x3=x(1,n3)
            y3=x(2,n3)
            z3=x(3,n3)
C
            x4=x(1,n4)
            y4=x(2,n4)
            z4=x(3,n4)
C------------------------------------------
C         calculation of the vector surface (*2.)
C------------------------------------------
            nx=(y1-y3)*(z2-z4) - (z1-z3)*(y2-y4)
            ny=(z1-z3)*(x2-x4) - (x1-x3)*(z2-z4)
            nz=(x1-x3)*(y2-y4) - (y1-y3)*(x2-x4)
            norm = sqrt(nx**2 + ny**2 + nz**2)
C--------+---------+---------+---------+---------+---------+---------+--
C         calculation of the distance between center and surface (*8.)
C-------------------------------------------------------------
            dx = two*(x1 + x2 + x3 + x4)
     .          -x(1,ixs(2))-x(1,ixs(3))
     .          -x(1,ixs(4))-x(1,ixs(5))
     .          -x(1,ixs(6))-x(1,ixs(7))
     .          -x(1,ixs(8))-x(1,ixs(9))
C
            dy = two*(y1 + y2 + y3 + y4)
     .          -x(2,ixs(2))-x(2,ixs(3))
     .          -x(2,ixs(4))-x(2,ixs(5))
     .          -x(2,ixs(6))-x(2,ixs(7))
     .          -x(2,ixs(8))-x(2,ixs(9))
C
            dz = two*(z1 + z2 + z3 + z4)
     .          -x(3,ixs(2))-x(3,ixs(3))
     .          -x(3,ixs(4))-x(3,ixs(5))
     .          -x(3,ixs(6))-x(3,ixs(7))
     .          -x(3,ixs(8))-x(3,ixs(9))
C
C---------------------------------
C         CALCULATION DISTANCE ET 1/4 SURFACE(SURFFACE NODALE))
C---------------------------------
            dist = one_over_8*(dx*nx+dy*ny+dz*nz) / max(em15,norm) 
            area = one_over_8*norm
C---------------------------------
C         calculation of the conductivity
C---------------------------------
            t = elbuf_tab(ng)%GBUF%TEMP(i)
            mat  =ixs(1)
            IF(t<=pm(80,mat))THEN
             cond=pm(75,mat)+pm(76,mat)*t
            ELSE
             cond=pm(77,mat)+pm(78,mat)*t
            ENDIF
            tstif = dist / cond 
C
C
      RETURN
      END