ige3ddefo.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ige3ddefo    ../engine/source/elements/ige3d/ige3ddefo.F
!||--- called by ------------------------------------------------------
!||    ig3duforc3   ../engine/source/elements/ige3d/ig3duforc3.F
!||====================================================================
      SUBROUTINE ige3ddefo(
     1   VX,      VY,      VZ,      MATB,
     2   NCTRL,   WXX,     WYY,     WZZ,
     3   DXX,     DYY,     DZZ,     DXY,
     4   DYX,     DYZ,     DZY,     DXZ,
     5   DZX,     D4,      D5,      D6,
     6   BA,      A,       NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NCTRL
      my_real
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   DZX(*), DZY(*), DZZ(*),
     .    d4(*),  d5(*),  d6(*),
     .   wxx(*), wyy(*), wzz(*)
      my_real
     .   vx(nctrl,mvsiz),vy(nctrl,mvsiz),vz(nctrl,mvsiz),
     .   ba(6,mvsiz), a(3*nctrl,mvsiz),matb(3*nctrl,mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I, J, INCTRL
      my_real DT1D2, DT1D, AAA
C=======================================================================
 
      DO I=1,nel
        dxx(i)=zero
        dyy(i)=zero
        dzz(i)=zero
        dxy(i)=zero
        dxz(i)=zero
        dyx(i)=zero
        dyz(i)=zero
        dzx(i)=zero
        dzy(i)=zero
        wxx(i)=zero
        wyy(i)=zero
        wzz(i)=zero     
      ENDDO
C                   NEL
C   [B] = [dNi/dx  dNk/dx  ..  ] \  3
C         [dNi/dy  dNk/dy  ..  ] |  *
C         [dNi/dz  dNk/dz  ..  ] |  N
C         [dNj/dx  dNl/dx  ..  ] |  C
C         [dNj/dy  dNl/dy  ..  ] |  T
C         [dNj/dz  dNl/dz  ..  ] |  R
C         [  ..      ..    ..  ] /  L
 
      DO i=1,nel
        DO j=1,nctrl 
          inctrl = (j-1)*3
          dxx(i)=dxx(i)+matb(inctrl+1,i)*vx(j,i) 
          dyy(i)=dyy(i)+matb(inctrl+2,i)*vy(j,i)  
          dzz(i)=dzz(i)+matb(inctrl+3,i)*vz(j,i)  
          dxy(i)=dxy(i)+matb(inctrl+2,i)*vx(j,i)
          dyx(i)=dyx(i)+matb(inctrl+1,i)*vy(j,i)
          dyz(i)=dyz(i)+matb(inctrl+3,i)*vy(j,i)
          dzy(i)=dzy(i)+matb(inctrl+2,i)*vz(j,i)
          dzx(i)=dzx(i)+matb(inctrl+1,i)*vz(j,i)
          dxz(i)=dxz(i)+matb(inctrl+3,i)*vx(j,i)
        ENDDO
      ENDDO
 
          dt1d2=half*dt1 
 
      DO i=1,nel
          dxx(i)  = dxx(i)
     .             -dt1d2*(dxx(i)*dxx(i)+dyx(i)*dyx(i)+dzx(i)*dzx(i))
          dyy(i)  = dyy(i)
     .             -dt1d2*(dyy(i)*dyy(i)+dzy(i)*dzy(i)+dxy(i)*dxy(i))
          dzz(i)  = dzz(i)
     .             -dt1d2*(dzz(i)*dzz(i)+dxz(i)*dxz(i)+dyz(i)*dyz(i))
          aaa = dt1d2*(dxx(i)*dxy(i)+dyx(i)*dyy(i)+dzx(i)*dzy(i))
          dxy(i)  = dxy(i) - aaa
          dyx(i)  = dyx(i) - aaa
          d4(i)   = dxy(i)+dyx(i)
          aaa = dt1d2*(dyy(i)*dyz(i)+dzy(i)*dzz(i)+dxy(i)*dxz(i))
          dyz(i)  = dyz(i) - aaa
          dzy(i)  = dzy(i) - aaa
          d5(i)   = dyz(i)+dzy(i)
          aaa = dt1d2*(dzz(i)*dzx(i)+dxz(i)*dxx(i)+dyz(i)*dyx(i))
          dxz(i)  = dxz(i) - aaa
          dzx(i)  = dzx(i) - aaa
          d6(i)   = dxz(i)+dzx(i)
 
          wxx(i)=dt1d2*(dzy(i)-dyz(i))
          wyy(i)=dt1d2*(dxz(i)-dzx(i))   
          wzz(i)=dt1d2*(dyx(i)-dxy(i))
      ENDDO
 
 
 
C-----------
      RETURN
      END