ingrbric_nodes.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C  
C   Node definition for second side of Interface Type18.
C   Input for second side is a GRBRIC. Nodes are extracted 
C   from it into a sorted list
!||====================================================================
!||    ingrbric_nodes   ../starter/source/interfaces/interf1/ingrbric_nodes.F
!||--- called by ------------------------------------------------------
!||    lecins           ../starter/source/interfaces/interf1/lecins.F
!||    lecint           ../starter/source/interfaces/interf1/lecint.F
!||--- uses       -----------------------------------------------------
!||    format_mod       ../starter/share/modules1/format_mod.F90
!||====================================================================
      SUBROUTINE ingrbric_nodes(MSN,IBUFSSG,ITAB,MSV, IXS, NBRIC, NALE, IPM, BUFMAT, S_MSV)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE ale_mod
        USE format_mod , ONLY : fmw_10i
        use element_mod , only : nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr03_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN)    :: NBRIC,S_MSV
      INTEGER,INTENT(INOUT) :: MSN
      INTEGER,INTENT(IN)    :: IBUFSSG(NBRIC), ITAB(NUMNOD), IXS(NIXS,NUMELS)
      INTEGER,INTENT(INOUT) :: MSV(1:S_MSV)
      INTEGER,INTENT(IN) :: NALE(NUMNOD)
      INTEGER,INTENT(IN) :: IPM(NPROPMI,NUMMAT)
      my_real,INTENT(IN),TARGET :: bufmat(sbufmat)
C-----------------------------------------------
C   L o c a l   V a r a i b l e s
C-----------------------------------------------
      INTEGER :: I, J, TMP, INOD
      INTEGER, DIMENSION(:),ALLOCATABLE,TARGET :: MSVTMP
      my_real, DIMENSION(:), POINTER :: uparam
      INTEGER NPAR, IADBUF, IFORM, IMAT, IELEM, ILAW
      LOGICAL IS_ELEM_A_BOUNDARY_MAT
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      ALLOCATE(msvtmp(1:numnod))
      msvtmp(1:numnod)=0
 
      !TAG NODES - remove lagrangian nodes
      DO i=1,nbric
        ielem = ibufssg(i)
        DO j=2,9
          inod = ixs(j,ielem)
          IF(nale(inod)/=0 .AND. inod>0)msvtmp(inod)=1   !NALE(node_i)==0 <=> lagrangian node_i
        ENDDO      
      ENDDO
      !TAG NODES - remove nodes from boundary materials (law11, & law51 iform=2,3,4,5,6)
      ! (do not loop unnecessarily otherwise)
      IF(ale%GLOBAL%IS_BOUNDARY_MATERIAL)THEN
        DO i=1,nbric
          ielem = ibufssg(i)
          is_elem_a_boundary_mat = .false.
          imat = ixs(1,ielem)
          ilaw = ipm(2,imat)
          iform = 0
          IF(ilaw == 51)THEN
            npar   = ipm(9,imat)                
            iadbuf = ipm(7,imat)                
            iadbuf = max(1,iadbuf)                
            uparam => bufmat(iadbuf:iadbuf+npar-1)
            iform  = nint(uparam(31))
            IF(iform>=2 .AND. iform<=6)is_elem_a_boundary_mat=.true.
          ELSEIF(ilaw == 11)THEN
            is_elem_a_boundary_mat=.true.
          ENDIF
          IF(is_elem_a_boundary_mat)THEN
            DO j=2,9
              inod = ixs(j,ielem)
              msvtmp(inod)=0
            ENDDO
          ENDIF
        END DO
      ENDIF
 
      !ORDERING
      tmp=0
      DO i=1,numnod
        IF(msvtmp(i)==1)THEN
          msvtmp(tmp+1)=i
          tmp=tmp+1
        ENDIF     
      END DO      
      msn = tmp ! size of ordered list
      
      DO i=1,s_msv
        msv(i)=msvtmp(i)
      ENDDO   
      DEALLOCATE(msvtmp)
 
      !PRINTOUT
      IF(ipri >= 1) THEN
        WRITE(iout,'(/,A,/)')' NODES EXTRACTED FROM SOLID ELEMENTS'
        WRITE(iout,fmt=fmw_10i)(itab(msv(i)),i=1,msn)
      ENDIF
C------------------------------------------------------------
      RETURN
      END