initnoise.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    initnoise     ../engine/source/general_controls/computation/initnoise.F
!||--- called by ------------------------------------------------------
!||    noise         ../engine/source/general_controls/computation/noise.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE initnoise(IN,NOIADD,IXS,IWA,LENGTH,IXQ)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------        
      use element_mod , only : nixs,nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scrnoi_c.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IN(*),IXS(NIXS,*),IWA(0:*),IXQ(NIXQ,*)
      INTEGER NOIADD(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,LENGTH,K
C-----------------------------------------------
C
C ADDRESS DES NODES SAUVES DS NOISE
C
      DO i=0,numnod
       iwa(i)=0
      ENDDO
      DO i=1,nnoise
       iwa(in(i))=i                 ! In (i) = 0 if not present in SPMD
       noiadd(i)=0
      ENDDO
      noiadd(nnoise+1)=0
C
C STOCKE IN NOIADD(K) LE NUMBER d'ELEMENTS CONNECTES AU NODE K-1
C
      IF(n2d==0)THEN
        DO i=1,numels
         DO j=2,9
          k=iwa(ixs(j,i))
          IF(k/=0)
     .       noiadd(k+1)=noiadd(k+1)+1
         ENDDO
        ENDDO
      ELSE
        DO i=1,numelq
         DO j=2,5
          k=iwa(ixq(j,i))
          IF(k/=0)
     .       noiadd(k+1)=noiadd(k+1)+1
         ENDDO
        ENDDO
      ENDIF      
C
C address per node in the array of elements to be saved in nodes
C
      noiadd(1)=1
      DO i=2,nnoise+1
       noiadd(i)=noiadd(i)+noiadd(i-1)
      ENDDO
      length=noiadd(nnoise+1)-1
c-----------
      RETURN
      END
 
!||====================================================================
!||    initnoise2    ../engine/source/general_controls/computation/initnoise.F
!||--- called by ------------------------------------------------------
!||    noise         ../engine/source/general_controls/computation/noise.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE initnoise2(IN,ELNOI,ELG,NOIADD,IXS,IWA,IPARG,IXQ)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------        
      use element_mod , only : nixs,nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scrnoi_c.inc"
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IN(*),IXS(NIXS,*),IXQ(NIXQ,*),IWA(*),IPARG(NPARG,*),
     .   ELNOI(*),ELG(*),NOIADD(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER , DIMENSION (:), ALLOCATABLE :: KN
      INTEGER I,J,K,II
      INTEGER NG,NEL,ITY,NB2,NFT
C-----------------------------------------------
      IF(nnoise>0)THEN
        ALLOCATE(kn(nnoise))
      ENDIF
      DO i=1,nnoise
        kn(i)=0
      ENDDO
C
C filling elnoi with the addresses from elbuf
C
      DO ng=1,ngroup
        ity   =iparg(5,ng)
        IF(ity==1)THEN
         nel   =iparg(2,ng)
         nb2   =iparg(4,ng) + nel
         nft   =iparg(3,ng)
         DO i=1,nel
          ii=i+nft
          DO j=2,9
            k=iwa(ixs(j,ii))
            IF(k /=0)THEN
              elnoi(noiadd(k)+kn(k))=i
              elg(noiadd(k)+kn(k))=ng
              kn(k)=kn(k)+1
            ENDIF
          ENDDO
         ENDDO
        ELSEIF(ity==2)THEN
         nel   =iparg(2,ng)
         nb2   =iparg(4,ng) + nel
         nft   =iparg(3,ng)
         DO i=1,nel
          ii=i+nft
          DO j=2,5
            k=iwa(ixq(j,ii))
            IF(k /=0)THEN
              elnoi(noiadd(k)+kn(k))=(i-1)*6
              elg(noiadd(k)+kn(k))=ng
              kn(k)=kn(k)+1
            ENDIF
          ENDDO
         ENDDO
        ENDIF
        
      ENDDO
C
      IF(nnoise>0)THEN
        DEALLOCATE(kn)
      ENDIF
C-----------
      RETURN
      END