inrch2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    inrch2                 ../starter/source/interfaces/inter2d1/inrch2.F
!||--- called by ------------------------------------------------------
!||    i1chk2                 ../starter/source/interfaces/inter2d1/i1chk2.F
!||    i3sti2                 ../starter/source/interfaces/inter2d1/i3sti2.F
!||    i9sti2                 ../starter/source/interfaces/int09/i9sti2.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE inrch2(X   , IRECT, ICO, ISG, NEL ,
     .                  NINT, YM1, YM2, ZM1 ,
     .                  ZM2 , YE   , ZE , ID , TITR)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C INIT INTERFACE : SEARCH THE CONNECTED ELEMENT TO A GIVEN SEGMENT
C   WHEN FOUND ELEM NODES COORDINATES ARE STORED IN (YE, ZE)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ISG, NEL, NINT
      INTEGER IRECT(4,*), ICO(7,*)
      my_real x(3,*), ym1, ym2, zm1, zm2,ye(4) ,ze(4)
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IX(4), NE, I1, I2, K, J, JJ, II
      LOGICAL lFOUND
C-----------------------------------------------
C   P r e - C o n d i t i o n
C-----------------------------------------------
      nel = 0
      IF(numelq == 0) RETURN
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      DO ne=1,numelq
      i1=irect(1,isg)
      i2=irect(2,isg)
      ix(1)=ico(2,ne)
      ix(2)=ico(3,ne)
      ix(3)=ico(4,ne)
      ix(4)=ico(5,ne)
      DO k=1,4
      IF(ix(k)/=i1)cycle
       DO j=1,4
       IF(ix(j)/=i2)cycle
        nel=ne
        ym1=x(2,i1)
        zm1=x(3,i1)
        ym2=x(2,i2)
        zm2=x(3,i2)
         DO jj=1,4
           ii=ix(jj)
           ye(jj)=x(2,ii)
           ze(jj)=x(3,ii)
         ENDDO !next JJ
         RETURN
        ENDDO !next J
       ENDDO !next K
      END DO !next NE
 
         IF(nint>0) THEN
            !** WARNING: CANNOT FIND ELEMENT OF SECONDARY
            CALL ancmsg(msgid=92,msgtype=msgwarning,anmode=aninfo_blind_2,i1=id,c1=titr,i2=isg)
         ENDIF
 
         IF(nint<0) THEN
            ! ** WARNING: CANNOT FIND ELEMENT OF MAIN SEGMENT
            CALL ancmsg(msgid=93,msgtype=msgwarning,anmode=aninfo_blind_2,i1=id,c1=titr,i2=isg)
         ENDIF
      RETURN
 
      END