int18_alloc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    int18_alloc     ../engine/source/interfaces/int18/int18_alloc.F
!||--- called by ------------------------------------------------------
!||    resol           ../engine/source/engine/resol.F
!||--- uses       -----------------------------------------------------
!||    array_mod       ../common_source/modules/array_mod.F
!||    groupdef_mod    ../common_source/modules/groupdef_mod.F
!||    multi_fvm_mod   ../common_source/modules/ale/multi_fvm_mod.F90
!||    tri7box         ../engine/share/modules/tri7box.F
!||====================================================================
        SUBROUTINE int18_alloc(NUMBER_INTER18,INTER18_LIST,MULTI_FVM,IPARI,XCELL_REMOTE, NSPMD)
!$COMMENT
!       INT18_ALLOC description
!       allocation of array for interface 18 & interface 18 combined 
!       with law151
!       
!       INT18_ALLOC organization :
!       - check if /INT18 is used
!       - check if /INT18 + /LAW151 is used
!       - allocate the arrays
!$ENDCOMMENT
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------           
        USE multi_fvm_mod
        USE groupdef_mod
        USE tri7box
        USE array_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "task_c.inc" 
#include      "parit_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(in) :: NSPMD !< number of spmd
        INTEGER, INTENT(inout) :: NUMBER_INTER18 !< number of interface 18
        INTEGER, DIMENSION(NINTER), INTENT(inout) :: INTER18_LIST !< list of interface 18
        INTEGER, DIMENSION(NPARI,NINTER), INTENT(in) :: IPARI
        TYPE(multi_fvm_struct) :: MULTI_FVM
        TYPE(array_type), DIMENSION(NINTER), INTENT(inout) :: XCELL_REMOTE !< remote data structure for interface 18 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: N,II,MY_SIZE,MY_SIZE_2,MY_SIZE_3
        INTEGER :: NTY,INACTI,NODFI
        INTEGER :: P
C-----------------------------------------------
        !   check if int18 + law151 is used in the model
        !   and create a list of int18
        multi_fvm%IS_INT18_LAW151 = .false.
        my_size = 0
        my_size_2 = 0
        number_inter18 = 0
        
        DO n=1,ninter
            nty   =ipari(7,n)
            inacti = ipari(22,n)           
            xcell_remote(n)%SIZE_MY_REAL_ARRAY_1D = 0
            !   int18 = int7 + inacti=7 (7+7=18) 
            IF( (nty==7).AND.(inacti ==7)) THEN
              IF(multi_fvm%IS_USED) THEN
                multi_fvm%IS_INT18_LAW151 = .true.
                my_size = numnod + numels
                my_size_2 = numels
            ENDIF      
            number_inter18 = number_inter18 + 1
            inter18_list(number_inter18) = n  !   list of interface int18
          ENDIF
        ENDDO
        !   number & list of interface 18 for MULTI_FVM solve
        multi_fvm%NUMBER_INT18 = 0
        IF(multi_fvm%IS_INT18_LAW151) multi_fvm%NUMBER_INT18 = number_inter18
        ALLOCATE( multi_fvm%INT18_LIST(multi_fvm%NUMBER_INT18) )
        !   allocation of X/V/MASS extended to NUMNOD+NUMELS
        !   1:NUMNOD --> classical x/v/mass
        !   NUMNOD+1:NUMNOD+NUMELS --> x/v/mass of phantom nodes (located to the center of 
        !                              the ALE elements)
        ALLOCATE( multi_fvm%X_APPEND(3*my_size) )
        ALLOCATE( multi_fvm%V_APPEND(3*my_size) )
        ALLOCATE( multi_fvm%MASS_APPEND(my_size) )
        ALLOCATE( multi_fvm%KINET_APPEND(my_size) )
        !   allocation of force array : size = NUMELS
        my_size_2 = my_size_2 * nthread
        
        IF(iparit/=0) THEN
            my_size_3 = 0 
        ELSE
            my_size_3 = my_size_2
        ENDIF
 
        multi_fvm%SIZE_FORCE_INT_1 = 3
        multi_fvm%SIZE_FORCE_INT_2 = my_size_3
        ALLOCATE( multi_fvm%FORCE_INT(3,my_size_3) )
        !   allocation of INT18_GLOBAL_LIST : marker for the interface /INT18+LAW151
        ALLOCATE( multi_fvm%INT18_GLOBAL_LIST(ninter) )
 
        ! --------------------------
        ! allocation of remote array for parith/on
        IF(multi_fvm%IS_USED) THEN
            ALLOCATE( multi_fvm%R_AFI(ninter) )  
            DO ii=1,multi_fvm%NUMBER_INT18
                n = inter18_list(ii) ! list of interface 18 + law151
                IF( ALLOCATED( multi_fvm%R_AFI(n)%R_FORCE_INT ) ) DEALLOCATE( multi_fvm%R_AFI(n)%R_FORCE_INT )
                nodfi = 0
                DO p = 1,nspmd
                  nodfi = nodfi + nsnfi(n)%P(p)
                ENDDO
                multi_fvm%R_AFI(n)%NODFI = nodfi
                ALLOCATE( multi_fvm%R_AFI(n)%R_FORCE_INT(3,6,nodfi*nthread) )
                multi_fvm%R_AFI(n)%R_FORCE_INT(1:3,1:6,1:nodfi*nthread) = 0d+00 
            ENDDO
        ELSE
            ALLOCATE( multi_fvm%R_AFI(0) )
        ENDIF 
        ! allocation of local array for parith/on
        IF(iparit/=0) THEN
            ALLOCATE( multi_fvm%FORCE_INT_PON(3,6,my_size_2) )
            multi_fvm%SIZE_FORCE_INT_PON = my_size_2
        ELSE
            ALLOCATE( multi_fvm%FORCE_INT_PON(0,0,0) )
            multi_fvm%SIZE_FORCE_INT_PON = 0
        ENDIF
        ! --------------------------
 
        IF( multi_fvm%IS_INT18_LAW151 ) THEN
            multi_fvm%INT18_LIST(1:multi_fvm%NUMBER_INT18) = inter18_list(1:multi_fvm%NUMBER_INT18)
        ENDIF
 
        RETURN
        END SUBROUTINE int18_alloc
C===============================================================================