intmass_update.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    intmass_update   ../engine/source/interfaces/interf/intmass_update.F
!||--- called by ------------------------------------------------------
!||    inttri           ../engine/source/interfaces/intsort/inttri.F
!||--- uses       -----------------------------------------------------
!||    intbufdef_mod    ../common_source/modules/interfaces/intbufdef_mod.F90
!||    message_mod      ../engine/share/message_module/message_mod.F
!||    tri25ebox        ../engine/share/modules/tri25ebox.F
!||    tri7box          ../engine/share/modules/tri7box.F
!||====================================================================
      SUBROUTINE intmass_update(NIN  , IPARI, INTBUF_TAB, MS )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE intbufdef_mod 
      USE tri25ebox
      USE tri7box
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER , INTENT(IN   ) :: NIN
      INTEGER , INTENT(IN   ) :: IPARI(NPARI) 
      my_real , INTENT(IN   ) :: ms(numnod) 
      TYPE(intbuf_struct_) , INTENT(INOUT   ) ::  INTBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER 
     .   NS ,N1, N2, N3 ,N4 ,I ,NTY ,NRTM ,NSN ,NSNR ,NEDGE ,NEDGR 
      my_real 
     .   stfacm ,ms1 ,ms2 ,ms3 ,ms4 
C----------------------------------------------------------
C    Main and secondary masses needed for contact stiffness computation 
C----------------------------------------------------------
 
        nrtm     = ipari(4)
        nsn      = ipari(5)
        stfacm   = intbuf_tab%VARIABLES(47)
        DO i=1,nsn
           ns = intbuf_tab%NSV(i)
           intbuf_tab%STIFMSDT_S(i)  = stfacm*ms(ns)
        ENDDO  
        DO i=1,nrtm
           n1=intbuf_tab%IRECTM(4*(i-1)+1)
           ms1 = ms(n1)
           n2=intbuf_tab%IRECTM(4*(i-1)+2)
           ms2 = ms(n2)
           n3=intbuf_tab%IRECTM(4*(i-1)+3)
           ms3 = ms(n3)
           n4=intbuf_tab%IRECTM(4*(i-1)+4)
           IF (n3 /= n4) THEN
              ms4 = ms(n4)
              intbuf_tab%STIFMSDT_M(i) = stfacm*fourth*(ms1+ms2+ms3+ms4)
           ELSE
              intbuf_tab%STIFMSDT_M(i) = stfacm*third*(ms1+ms2+ms3)
           ENDIF
        ENDDO  
 
        IF(ipari(7)==25.AND.ipari(58)>0) THEN ! case of edges
           nedge = ipari(68)
           DO i=1,nedge
              n1= intbuf_tab%LEDGE(nledge*(i-1)+5)
              n2= intbuf_tab%LEDGE(nledge*(i-1)+6)
              ms1 = ms(n1)
              ms2 = ms(n2)
              intbuf_tab%STIFMSDT_EDG(i) = half*stfacm*(ms1+ms2)
           ENDDO         
        ENDIF
 
        
        IF(nspmd > 1) THEN
           nsnr = ipari(24)
           DO i=1,nsnr
              stif_msdt_fi(nin)%P(i) = stfacm*msfi(nin)%P(i) 
           ENDDO
           IF(ipari(7)==25.AND.ipari(58)>0) THEN ! case of edges
              nedgr = ipari(69)
              DO i=1,nedgr
                 n1 =2*(i-1)+1
                 n2 =2*i
                 ms1 = msfie(nin)%P(n1)
                 ms2 = msfie(nin)%P(n2)
                 stife_msdt_fi(nin)%P(i) = half*stfacm*(ms1+ms2)
             ENDDO
           ENDIF
        ENDIF              
 
      RETURN
      END SUBROUTINE intmass_update