intstamp_ass.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    intstamp_ass       ../engine/source/interfaces/int21/intstamp_ass.F
!||--- called by ------------------------------------------------------
!||    resol              ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    spmd_glob_dpsum9   ../engine/source/mpi/interfaces/spmd_th.F
!||    spmd_glob_dsum9    ../engine/source/mpi/interfaces/spmd_th.F
!||    spmd_rbcast        ../engine/source/mpi/generic/spmd_rbcast.F
!||--- uses       -----------------------------------------------------
!||    intstamp_mod       ../engine/share/modules/intstamp_mod.F
!||====================================================================
      SUBROUTINE intstamp_ass(
     1           INTSTAMP,MS     ,IN      ,A     ,AR    ,
     2           STIFN   ,STIFR  ,WEIGHT  ,WFEXT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE intstamp_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
!#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "parit_c.inc"
#include      "task_c.inc"
#include      "intstamp_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER WEIGHT(*)
      my_real MS(*), IN(*), A(3,*), AR(3,*), STIFN(*), STIFR(*)
      TYPE(intstamp_data) INTSTAMP(*)
      DOUBLE PRECISION, INTENT(INOUT) :: WFEXT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NN, MSR, MSRR, INTDAMP, KDIR, K, IROT
      my_real BUFS(8,NINTSTAMP), ALPHA, VIS, MASS, INM, STF, STR, VX, VY, VZ, FVX, FVY, FVZ, DT05, DW
      DOUBLE PRECISION BUFS6(6,8,NINTSTAMP)
C-----------------------------------------------
      IF(iparit /= 0)THEN
        DO nn=1,nintstamp
         DO k=1,6
          DO kdir=1,3
            bufs6(k,kdir,nn)=intstamp(nn)%FC6(k,kdir)
          END DO
          bufs6(k,4,nn)=intstamp(nn)%ST6(k)
         END DO
C
C null if irot=0
         DO k=1,6
          DO kdir=1,3
            bufs6(k,kdir+4,nn)=intstamp(nn)%MC6(k,kdir)
          END DO
          bufs6(k,8,nn)=intstamp(nn)%STR6(k)
         END DO
        END DO
        IF(nspmd>1)
     .    CALL spmd_glob_dpsum9(bufs6,48*nintstamp)
        IF(ispmd==0)THEN
          DO nn=1,nintstamp
            DO kdir=1,8
              bufs(kdir,nn)=bufs6(1,kdir,nn)
     .                     +bufs6(2,kdir,nn)
     .                     +bufs6(3,kdir,nn)
     .                     +bufs6(4,kdir,nn)
     .                     +bufs6(5,kdir,nn)
     .                     +bufs6(6,kdir,nn)
            END DO
          END DO
        END IF
        IF(nspmd>1)
     .    CALL spmd_rbcast(bufs,bufs,8*nintstamp,1,0,2)
        DO nn=1,nintstamp
          DO kdir=1,3
            intstamp(nn)%FC(kdir)=bufs(kdir,nn)
          END DO
          intstamp(nn)%STF=bufs(4,nn)
          irot=intstamp(nn)%IROT
          IF(irot/=0)THEN
            DO kdir=1,3
              intstamp(nn)%MC(kdir)=bufs(kdir+4,nn)
            END DO
            intstamp(nn)%STR=bufs(8,nn)
          END IF
        END DO
      ELSE
        IF(nspmd>1)THEN
          DO nn=1,nintstamp
            DO kdir=1,3
              bufs(kdir,nn)=intstamp(nn)%FC(kdir)
            END DO
            bufs(4,nn)=intstamp(nn)%STF
C
C null if irot=0
            DO kdir=1,3
              bufs(kdir+4,nn)=intstamp(nn)%MC(kdir)
            END DO
            bufs(8,nn)=intstamp(nn)%STR
          END DO
          CALL spmd_glob_dsum9(bufs,8*nintstamp)
          CALL spmd_rbcast(bufs,bufs,8*nintstamp,1,0,2)
          DO nn=1,nintstamp
            DO kdir=1,3
              intstamp(nn)%FC(kdir)=bufs(kdir,nn)
            END DO
            intstamp(nn)%STF=bufs(4,nn)
            irot=intstamp(nn)%IROT
            IF(irot /= 0)THEN
C rotations
              DO kdir=1,3
                intstamp(nn)%MC(kdir)=bufs(kdir+4,nn)
              END DO
              intstamp(nn)%STR=bufs(8,nn)
            END IF
          END DO
        END IF
      END IF
C---------------------
C contact force / Interface => Rbody
C---------------------
      DO nn=1,nintstamp
C
       irot=intstamp(nn)%IROT
       msr =intstamp(nn)%MSR
       DO kdir=1,3
        a(kdir,msr)=a(kdir,msr)+intstamp(nn)%FC(kdir)
       END DO
       IF(irot/=0)THEN
         DO kdir=1,3
          ar(kdir,msr)=ar(kdir,msr)+intstamp(nn)%MC(kdir)
         END DO
       END IF
      END DO
C---------------------
C damping
C---------------------
      dt05=half*dt1
      DO nn=1,nintstamp
        msr=intstamp(nn)%MSR
        intdamp=intstamp(nn)%INTDAMP
        alpha  =intstamp(nn)%DAMP
        mass   =ms(msr)
        stf =intstamp(nn)%STF
        vis =alpha*sqrt(four*mass*stf)
        wfext=wfext + dt05*intstamp(nn)%DW
        IF(intdamp==0)THEN
          a(1,msr)=a(1,msr)-vis*intstamp(nn)%V(1)
          a(2,msr)=a(2,msr)-vis*intstamp(nn)%V(2)
          a(3,msr)=a(3,msr)-vis*intstamp(nn)%V(3)
          IF(ispmd==0)THEN
              dw=-vis*( intstamp(nn)%V(1)*intstamp(nn)%V(1)
     .         +intstamp(nn)%V(2)*intstamp(nn)%V(2)
     .         +intstamp(nn)%V(3)*intstamp(nn)%V(3))
              wfext=wfext + dt05 * dw
          END IF
        ELSE
          vx=(intstamp(nn)%V(1)-intstamp(intdamp)%V(1))
          vy=(intstamp(nn)%V(2)-intstamp(intdamp)%V(2))
          vz=(intstamp(nn)%V(3)-intstamp(intdamp)%V(3))
          fvx=vis*vx
          fvy=vis*vy
          fvz=vis*vz
          a(1,msr)=a(1,msr)-fvx
          a(2,msr)=a(2,msr)-fvy
          a(3,msr)=a(3,msr)-fvz
          msrr=intstamp(intdamp)%MSR
          a(1,msrr)=a(1,msrr)+fvx
          a(2,msrr)=a(2,msrr)+fvy
          a(3,msrr)=a(3,msrr)+fvz
          IF(ispmd==0)THEN
            dw=-two*(fvx*vx+fvy*vy+fvz*vz)
            wfext=wfext + dt05 * dw
          END IF
        END IF
        irot=intstamp(nn)%IROT
        IF(irot/=0)THEN
          alpha=intstamp(nn)%DAMPR
          inm=in(msr)
          str =intstamp(nn)%STR
          vis =alpha*sqrt(four*inm*str)
          IF(intdamp==0)THEN
            ar(1,msr)=ar(1,msr)-vis*intstamp(nn)%VR(1)
            ar(2,msr)=ar(2,msr)-vis*intstamp(nn)%VR(2)
            ar(3,msr)=ar(3,msr)-vis*intstamp(nn)%VR(3)
            IF(ispmd==0)THEN
                dw=-vis*( intstamp(nn)%VR(1)*intstamp(nn)%VR(1)
     .           +intstamp(nn)%VR(2)*intstamp(nn)%VR(2)
     .           +intstamp(nn)%VR(3)*intstamp(nn)%VR(3))
                wfext=wfext + dt05 * dw
            END IF
          ELSE
            vx=intstamp(nn)%VR(1)-intstamp(intdamp)%VR(1)
            vy=intstamp(nn)%VR(2)-intstamp(intdamp)%VR(2)
            vz=intstamp(nn)%VR(3)-intstamp(intdamp)%VR(3)
            fvx=vis*vx
            fvy=vis*vy
            fvz=vis*vz
            ar(1,msr)=ar(1,msr)-fvx
            ar(2,msr)=ar(2,msr)-fvy
            ar(3,msr)=ar(3,msr)-fvz
            msrr=intstamp(intdamp)%MSR
            ar(1,msrr)=ar(1,msrr)+fvx
            ar(2,msrr)=ar(2,msrr)+fvy
            ar(3,msrr)=ar(3,msrr)+fvz
            IF(ispmd==0)THEN
              dw=-two*(fvx*vx+fvy*vy+fvz*vz)
              wfext=wfext + dt05 * dw
            END IF
          END IF
        END IF
      ENDDO
C---------------------
      RETURN
      END