invoi3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    invoi3                 ../starter/source/interfaces/inter3d1/invoi3.F
!||--- called by ------------------------------------------------------
!||    iniend                 ../starter/source/interfaces/inter3d1/iniend.f
!||    inint3                 ../starter/source/interfaces/inter3d1/inint3.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.f
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE invoi3(X,IRECT,LMSR,MSR,NSV,ILOC,IRTL,NSEG,NSN,NMN,ITAB,ID,TITR,NRT)
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN)  :: NSN, NMN, NRT, ID
      INTEGER, INTENT(IN)  :: IRECT(4,*), LMSR(*), MSR(*), NSV(*), NSEG(*), ITAB(*)
      INTEGER, INTENT(INOUT) :: ILOC(*), IRTL(*)
      my_real, INTENT(IN)  :: x(3,*)
      CHARACTER(LEN=NCHARTITLE)::TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, K, L, M, N, II, JJ, KK, LL
      INTEGER LG, MG, NG, J1, J2, K1, K2, KKK, JNEW
      INTEGER KM1(4), KN1(4), LSEG, LSEG_NEW
      my_real cms, dms, ems, fms, bmin, bmax
C
      DATA km1/2,3,4,1/
      DATA kn1/4,1,2,3/
C-------------------------------------------------------------------------------------
      IF(nrt==0) RETURN
C
      DO ii=1,nsn
        i=nsv(ii)
        j=iloc(ii)
        jnew=j
        k=msr(j)
        cms=(x(1,i)-x(1,k))**2+(x(2,i)-x(2,k))**2+(x(3,i)-x(3,k))**2
        j1=nseg(j)
        j2=nseg(j+1)-1
        DO jj=j1,j2
          ll=lmsr(jj)
          IF(j==irect(1,ll)) THEN
            l=irect(2,ll)
            m=irect(3,ll)
            n=irect(4,ll)
          ELSEIF(j==irect(2,ll)) THEN
            l=irect(1,ll)
            m=irect(3,ll)
            n=irect(4,ll)
          ELSEIF(j==irect(3,ll)) THEN
            l=irect(1,ll)
            m=irect(2,ll)
            n=irect(4,ll)
          ELSEIF(j==irect(4,ll)) THEN
            l=irect(1,ll)
            m=irect(2,ll)
            n=irect(3,ll)
          ELSE
            CALL ancmsg(msgid=105,
     .                  msgtype=msgerror,
     .                  anmode=aninfo,
     .                  i1=id,
     .                  c1=titr,
     .                  i2=itab(msr(irect(1,ll))),
     .                  i3=itab(msr(irect(2,ll))),
     .                  i4=itab(msr(irect(3,ll))),
     .                  i5=itab(msr(irect(4,ll))))
            l=irect(1,ll)
            m=irect(2,ll)
            n=irect(3,ll)
          ENDIF
C
          lg=msr(l)
          mg=msr(m)
          ng=msr(n)
          dms=(x(1,i)-x(1,lg))**2+(x(2,i)-x(2,lg))**2+(x(3,i)-x(3,lg))**2
          ems=(x(1,i)-x(1,mg))**2+(x(2,i)-x(2,mg))**2+(x(3,i)-x(3,mg))**2
          fms=(x(1,i)-x(1,ng))**2+(x(2,i)-x(2,ng))**2+(x(3,i)-x(3,ng))**2
          IF(dms<=cms) THEN
            cms=dms
            jnew=l
            k=lg
          ENDIF
          IF(ems<=cms) THEN
            cms=ems
            jnew=m
            k=mg
          ENDIF
          IF(fms<=cms) THEN
            cms=fms
            jnew=n
            k=ng
          ENDIF
        ENDDO  !JJ=J1,J2
        j=jnew
        iloc(ii)=j
C
C
        bmax=-ep30
        lseg_new=0
        l=irtl(ii)
        IF(l==0) GO TO 100
        lseg=l
        DO kkk=1,4
          kk=kkk
          IF(irect(kk,l)==j) EXIT
        ENDDO
        j1=km1(kk)
        j2=kn1(kk)
        IF(kk==3.AND.irect(3,l)==irect(4,l)) j1=1
        m=msr(irect(j1,l))
        n=msr(irect(j2,l))
        CALL nearest_seg(x, i, k, m, n, lseg, lseg_new, bmin, bmax)
        IF(bmin >= zero) GO TO 200
C
 100    CONTINUE   ! L=0
        j1=nseg(j)
        j2=nseg(j+1)-1
        DO jj=j1,j2
          ll=lmsr(jj)
          lseg=ll
          IF(l==ll) cycle
          DO kkk=1,4
            kk=kkk
            IF(irect(kk,ll)==j) EXIT
          ENDDO
          k1=km1(kk)
          k2=kn1(kk)
          IF(kk==3.AND.irect(3,ll)==irect(4,ll)) k1=1
          m=msr(irect(k1,ll))
          n=msr(irect(k2,ll))
          CALL nearest_seg(x, i, k, m, n, lseg, lseg_new, bmin, bmax)
          IF(bmin < zero) cycle
          irtl(ii)=lseg_new
          GO TO 200
        ENDDO
        irtl(ii)=lseg_new
 200    CONTINUE
      ENDDO   !II=1,NSN
 
      RETURN
      END