law119_upd.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    law119_upd             ../starter/source/materials/mat/mat119/law119_upd.F
!||--- called by ------------------------------------------------------
!||    updmat                 ../starter/source/materials/updmat.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    table_inters           ../starter/source/tools/curve/func_inters.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    table_mod              ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE law119_upd(NUPARAM ,NUMTABL ,ITABLE ,TABLE  ,TABLE_ID ,
     .                      UPARAM  ,PM      ,TITR   ,MAT_ID )          
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE table_mod
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: NUPARAM,NUMTABL,MAT_ID
      INTEGER ,DIMENSION(NUMTABL) :: ITABLE,TABLE_ID
      my_real ,DIMENSION(NPROPM)  :: pm
      my_real ,DIMENSION(NUPARAM), INTENT(INOUT) :: uparam
      TYPE(ttable) ,DIMENSION(NTABLE) ::  TABLE
      CHARACTER(LEN=NCHARTITLE)  :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,FUNC,FUND,NDIM,NPOINT
      my_real :: e11,n12,n21,nu,c1,ssp,kmax,kini,dx,dy,slope,rho,
     .           fscale1,fscale2,fscalet,det,a11,a12,a22,xint,yint
c=======================================================================
      func = itable(1)
      fund = itable(2)
      n12  = uparam(3)
      fscale1 = uparam(11)                        
      fscale2 = uparam(12)
      fscalet = uparam(13)
c
      IF (func > 0) THEN
        ndim = table(func)%NDIM
        npoint = SIZE(table(func)%X(1)%VALUES)
        dx = table(func)%X(1)%VALUES(2) - table(func)%X(1)%VALUES(1)
        dy = table(func)%Y%VALUES(2) - table(func)%Y%VALUES(1)
        kini = fscale1 * dy / dx
        kmax = kini        
        DO i = 3,npoint
          j  = i-1
          dx = table(func)%X(1)%VALUES(i) - table(func)%X(1)%VALUES(j)
          dy = table(func)%Y%VALUES(i) - table(func)%Y%VALUES(j)
          slope = fscale1 * dy / dx
          kmax  = max(kmax, slope)
        END DO
c
        IF (fund > 0) THEN
          ndim = table(fund)%NDIM
          npoint = SIZE(table(fund)%X(1)%VALUES)
          dx = table(fund)%X(1)%VALUES(2) - table(fund)%X(1)%VALUES(1)
          dy = table(fund)%Y%VALUES(2) - table(fund)%Y%VALUES(1)
          kini = fscale2 * dy / dx
          kmax =  max(kmax, kini)  
          DO i = 3,npoint
            j  = i-1
            dx = table(fund)%X(1)%VALUES(i) - table(fund)%X(1)%VALUES(j)
            dy = table(fund)%Y%VALUES(i) - table(fund)%Y%VALUES(j)
            slope = fscale2 * dy / dx
            kmax  = max(kmax, slope)
          END DO
c
c         check intersection with loading curve        
          CALL table_inters(table,func,fund,fscale1,fscale2,xint,yint)
c
          IF (xint == zero .or. yint == zero) THEN
            CALL ancmsg(msgid=3081 ,msgtype=msgerror,anmode=aninfo_blind_2,
     .                  i1 = mat_id,
     .                  i2 = table_id(1),                                               
     .                  i3 = table_id(2),                                              
     .                  c1 = titr  )
          ENDIF 
          uparam(18) = xint   
          uparam(19) = yint
        END IF
C
        uparam(1)  = kini ! E11
        uparam(22) = kmax             
C       other material parameters are recomputed in create_seatbelt when section is available
C  
      END IF      
c-----------
      RETURN
      END