law70_table.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    law70_table          ../starter/source/materials/mat/mat070/law70_table.F
!||--- called by ------------------------------------------------------
!||    law70_upd            ../starter/source/materials/mat/mat070/law70_upd.F
!||--- calls      -----------------------------------------------------
!||    func2d_deintersect   ../starter/source/materials/tools/func2d_deintersect.F
!||    table_values_2d      ../starter/source/materials/tools/table_values_2d.F
!||    unify_abscissa_2d    ../starter/source/materials/tools/unify_abscissas_2d.F
!||    vw_smooth            ../starter/source/tools/curve/vw_smooth.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE law70_table(TABLE, NFUNC, LENGTH, LMAX, RATE, XI, YI)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
c     create X,Y vectors for all curves before unifying all abscissas
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE table4d_mod, ONLY : table_4d_
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NFUNC
      INTEGER ,INTENT(INOUT) :: LMAX
      INTEGER ,DIMENSION(NFUNC) :: LENGTH
      my_real ,DIMENSION(NFUNC) ,INTENT(IN) :: rate
      my_real ,DIMENSION(LMAX,NFUNC) ,INTENT(IN) :: xi
      my_real ,DIMENSION(LMAX,NFUNC) ,INTENT(IN) :: yi
      TYPE(table_4d_) ,INTENT(INOUT) :: TABLE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,IPT,NPTX,NPTM,IPOS,NDIM,FUNC_ID,IERROR,STAT
      INTEGER ,DIMENSION(NFUNC) :: PERM
      INTEGER ,PARAMETER :: NPTMAX = 100   ! max number of function points
      my_real :: x1,x2,y1,y2,deri
      my_real ,DIMENSION(:)   ,ALLOCATABLE :: xf,xs,ys
      my_real ,DIMENSION(:,:) ,ALLOCATABLE :: yf
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      nptx = 0
      DO i = 1,nfunc
        nptx = nptx + length(i)
      END DO
      ALLOCATE (xf(nptx))
c
      IF (nfunc == 1) THEN
        ALLOCATE (yf(nptx,nfunc))
        xf(1:nptx)   = xi(1:nptx,1)
        yf(1:nptx,1) = yi(1:nptx,1)
c
      ELSE
c--------------------------------------------------------
c       unify abscissas
c--------------------------------------------------------
c
        CALL unify_abscissa_2d(nfunc,length,lmax,nptx ,xi  ,xf  )
c
        ALLOCATE (yf(nptx,nfunc))
        DO i = 1,nfunc
          CALL table_values_2d(length(i) ,nptx ,xi(1,i) ,yi(1,i) ,xf ,yf(1,i) )
        END DO      
c
c--------------------------------------------------------
c       check and correct intersections
c--------------------------------------------------------
c
        CALL func2d_deintersect(nptx, nfunc  ,yf   )
c
      END IF
c--------------------------------------------------------
c     d) check and correct monotonicity
c--------------------------------------------------------
      DO i = 1,nfunc
        DO ipt = 2,nptx
          IF (yf(ipt,i) < yf(ipt-1,i)) THEN
            yf(ipt,i) = yf(ipt-1,i)
          END IF
        END DO
      END DO
c--------------------------------------------------------
c     second reduction of number of points of the 1st curve
c     and reinterpolate all table functions based on its abscissa distribution
c--------------------------------------------------------
      IF (nptx > nptmax) THEN
        nptm = nptx
        ALLOCATE (xs(nptm))
        ALLOCATE (ys(nptm))
        xs(1:nptm) = xf(1:nptm)
        CALL vw_smooth(nptx,nptmax,xf,yf(1:nptx,1))
c
        DO i = 2,nfunc
          ys(1:nptm) = yf(1:nptm,i)
          CALL table_values_2d(nptm ,nptx ,xs ,ys ,xf ,yf(1,i) )
        END DO
        DEALLOCATE(ys)     
        DEALLOCATE(xs)     
      END IF
c--------------------------------------------------------------------------
c     e) create 2D function table
c--------------------------------------------------------
      ndim = min(2,nfunc)
      table%NDIM  = ndim
      ALLOCATE (table%X(ndim)              ,stat=stat)            
      ALLOCATE (table%X(1)%VALUES(nptx)     ,stat=stat)      
      IF (nfunc == 1) THEN
        ALLOCATE (table%Y1D(nptx)           ,stat=stat)
        table%X(1)%VALUES(1:nptx)   = xf(1:nptx)   
        table%Y1D(1:nptx) = yf(1:nptx,1)
      ELSE
        ALLOCATE (table%X(2)%VALUES(nfunc) ,stat=stat)
        ALLOCATE (table%Y2D(nptx,nfunc)     ,stat=stat)
        table%X(1)%VALUES(1:nptx)   = xf(1:nptx)   
        table%X(2)%VALUES(1:nfunc) = rate(1:nfunc)
        DO i = 1,nfunc
          table%Y2D(1:nptx,i) = yf(1:nptx,i)
        END DO
      END IF      
c
      length(1:nfunc) = nptx
c--------------------
      DEALLOCATE (xf)
      DEALLOCATE (yf)
c--------------------
      RETURN
      END