lec_inistate_d00_brick-check.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    lec_inistate_d00_brick_check   ../starter/source/elements/initia/lec_inistate_d00_brick-check.F
!||--- called by ------------------------------------------------------
!||    hm_read_inistate_d00           ../starter/source/elements/initia/hm_read_inistate_d00.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                         ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod                    ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE lec_inistate_d00_brick_check (
     1                  IXS            ,IGEO          ,ITRIS         ,ISOLNODD00    ,IE            ,
     2                  NPT            ,NLAY          ,ISOLNOD       ,JJHBE         ,IGTYP         ,
     3                  ISROT          ,KEYWORD )
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8----+----9----+----A----+----B----+----C----+----D--
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------                     
      USE message_mod      
      use element_mod , only : nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXS(NIXS,*), IGEO(NPROPGI,*) ,ITRIS(*), ISOLNODD00(*)
      INTEGER IE, NPT, ISOLNOD, JJHBE, IGTYP, ISROT, NLAY
      CHARACTER*15,KEYWORD 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IPIDD00, JJHBED00, NPTD00, NPTF, NPTR, NPTS, NPTT, ICSTR, IINT, NLY,NNOD
C-----------------------------------------------
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8----+----9----+----A----+----B----+----C----+----D--
C-----------------------------------------
C     INITIALE STRESS FILE D00
C     CHECK INPUT CONSISTENCY BETWEEN /INIBRI AND D00
C     Erreur if difference in data ( D00 & INIBRI)
C-----------------------------------------
      ipidd00  = ixs(10,ie)
      jjhbed00 = igeo(10,ipidd00)
      igtyp    = igeo(11,ipidd00)
      isrot    = igeo(20,ipidd00)
      icstr    = igeo(14,ipidd00)
      iint     = igeo(15,ipidd00)
C
C  Solid property ISOLID
C
      IF (jjhbed00 == 0) jjhbed00 = 1
      IF (isolnod==4.OR.isolnod==10) jjhbed00=1
      IF (isolnod==16.OR.isolnod==20) jjhbed00=16
      IF ((isolnod==4.OR.isolnod==10).AND.jjhbe /= 1) jjhbe = 1
      IF (jjhbe == 0) jjhbe = 1
      IF (jjhbed00 == 1 .AND. iint == 3 .AND. isolnod==8) jjhbed00 = 5
 
      IF ((jjhbed00 /=jjhbe) .AND.((jjhbed00 /= 2).AND.
     .         (jjhbe /= 0)) .AND. isolnod /= 4)  THEN
          CALL ancmsg(msgid=695,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=itris(ie),
     .                c1='FORMULATION',
     .                c2='SOLID PROPERTY',
     .                i2=igeo(1,ipidd00),
     .                c3=keyword)
      ENDIF
C
C  Number of nodes
C
      nnod = isolnod
      IF (isolnod==10 .AND. isrot==1) nnod=4
      IF (isolnodd00(ie) /=nnod) THEN
          CALL ancmsg(msgid=695,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=itris(ie),
     .                c1='NUMBER OF NODES',
     .                c2='BRICK',
     .                i2=itris(ie),
     .                c3=keyword)
      ENDIF
C
      nptd00 = 0
      nptr = 0
      npts = 0
      nptt = 0
      IF (jjhbed00 == 14 .OR.isolnod==16 .OR.isolnod==20 ) THEN
       nptf = igeo(4,ipidd00)
       IF (nptf<=8) nptf = 222
       nptr=nptf/100
       npts=mod(nptf/10,10)
       nptt=mod(nptf,10)
      END IF
C      
      IF (jjhbed00 == 14 .AND.igtyp==22 ) THEN
       SELECT CASE (icstr)
        CASE(100)                                             
         nly = nptr
         IF (nly ==0) nly =iint 
         nptd00 = nly*npts*nptt
        CASE(10)                                          
         nly = npts
         IF (nly ==0) nly =iint 
         nptd00 = nly*nptr*nptt
        CASE(1)                                          
         nly = nptt
         IF (nly ==0) nly =iint 
         nptd00 = nly*nptr*npts
        CASE DEFAULT 
         nly = -huge(nly)
         nptd00 = -huge(nptd00)
       END SELECT
C
C  Number of layers
C
       IF (keyword == '/INIBRI/ORTHO  ' .AND. nly /= nlay) THEN
          CALL ancmsg(msgid=695,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=itris(ie),
     .                c1='NUMBER OF LAYERS',
     .                c2='SOLID PROPERTY',
     .                i2=igeo(1,ipidd00),
     .                c3=keyword)
       ENDIF
C
C     
      ELSEIF (jjhbed00 == 14 .OR.isolnod==16 .OR.isolnod==20 ) THEN
       nptd00 = nptr*npts*nptt
      ELSEIF (jjhbed00 == 12 .OR.jjhbed00==17.OR.jjhbed00==18) THEN
       nptd00 = 8
      ENDIF
 
      IF (nptd00 == 0 .and. igtyp == 43)   nptd00 = 4
           
      IF (nptd00 == 0)   nptd00 = 1
      IF (isolnod == 10) nptd00 = 4
      IF (isolnod == 4 .AND. (isrot == 0 .OR. isrot == 3)) THEN
          nptd00 = 1
      ELSEIF(isolnod == 4 )THEN
          nptd00 = 4
      ELSEIF(jjhbed00 == 15)THEN
          nptd00 = igeo(4,ipidd00)
      ENDIF
 
      IF(keyword =='/INIBRI/ORTHO  '.OR.keyword=='/INIBRI/EREF ')RETURN
C
C  Number of integration points
C
      IF (nptd00 /=npt) THEN
          CALL ancmsg(msgid=695,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=itris(ie),
     .                c1='NUMBER OF INTEGRATION POINTS',
     .                c2='SOLID PROPERTY',
     .                i2=igeo(1,ipidd00),
     .                c3=keyword)
      ENDIF
C
      RETURN
      END