leccut.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    leccut   ../engine/source/tools/sect/leccut.F
!||--- called by ------------------------------------------------------
!||    lectur   ../engine/source/input/lectur.f
!||--- calls      -----------------------------------------------------
!||    sysfus   ../engine/source/system/sysfus.F
!||====================================================================
      SUBROUTINE leccut(ICUT,XCUT,ITABM1)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ICUT(44,*),ITABM1(*)
      my_real xcut(7,*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
#include      "scrcut_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I,J,ITYP
      my_real x0(3),vn(3),vit,vnn
      CHARACTER IDTITL*40
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      my_real, EXTERNAL :: sysfus
C-----------------------------------------------
      WRITE(iout,2000)ncuts
      DO i=1,ncuts
        READ(iin,'(I8,A40)')ityp,idtitl
        IF(ityp==0)ityp=1
        WRITE(iout,1100)idtitl,ityp
        icut(1,i)=ityp
        DO j=1,40
          icut(4+j,i) = ichar(idtitl(j:j))
        ENDDO
        IF(ityp<3)THEN
          READ(iin,'(7E16.0)')(x0(j),j=1,3),(vn(j),j=1,3),vit
          IF(ityp==2)vit=0
          xcut(7,i)=vit
          DO j=1,3
            xcut(j,i)=x0(j)
          ENDDO
          vnn=sqrt(vn(1)**2+vn(2)**2+vn(3)**2)
          IF(vnn==zero)THEN
            WRITE(istdo,1000) idtitl
            vn(1)=one
          ELSE
            vn(1)=vn(1)/vnn
            vn(2)=vn(2)/vnn
            vn(3)=vn(3)/vnn
          ENDIF
          DO j=1,3
            icut(j+1,i)=0
            xcut(j+3,i)=vn(j)
          ENDDO
          WRITE(iout,1200)(x0(j),j=1,3),(vn(j),j=1,3),vit
         ELSE
          READ(iin,'(3I8)')(icut(j,i),j=2,4)
          WRITE(iout,1300)(icut(j,i),j=2,4)          
          DO j=1,7
            xcut(j,i)=zero
          ENDDO
          DO j=2,4
            icut(j,i)=sysfus(icut(j,i),itabm1,numnod,' ** ERROR ** CUT')
          ENDDO 
         ENDIF
      ENDDO ! I    
C
      RETURN
C
 1000 FORMAT(//' ** ERROR CUT ',a40,' ZERO VECTOR NORM')
 2000 FORMAT(' NUMBER OF SOLID CUTS . . . . . . .', i8 //)
 1100 FORMAT(//' CUT ',a40/
     .          ' TYPE  . . . . . . . . . . . . =',i5/
     .          '     =1 PLANE CUT OF DEFORMED GEOMETRY'/
     .          '     =2 DEFORMED CUT OF UNDEFORMED GEOMETRY'/
     .          '     =3 PLANE CUT GIVEN BY 3 REFERENCE NODES')
 1200 FORMAT(
     .          ' REFERENCE COORDINATES . . . X =',e12.4/
     .          ' . . . . . . . . . .  . . . .Y =',e12.4/
     .          ' . . . . . . . . . .  . . . .Z =',e12.4/
     .          ' REFERENCE VECTOR  . . . . . X =',e12.4/
     .          ' . . . . . . . . . . . . . . Y =',e12.4/
     .          ' . . . . . . . . . . . . . . Z =',e12.4/
     .          ' VELOCITY  . . . . . . . . VIT =',e12.4)
 1300 FORMAT(
     .          ' REFERENCE NODE . . . . . . 1 =',i8/
     .          ' . . . . . . . . . . . . . .2 =',i8/
     .          ' . . . . . . . . . . . . . .3 =',i8)
      END