m14ama.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    m14ama   ../engine/source/materials/mat/mat014/m14ama.F
!||--- called by ------------------------------------------------------
!||    m12law   ../engine/source/materials/mat/mat012/m12law.F
!||    m14law   ../engine/source/materials/mat/mat014/m14law.F
!||====================================================================
      SUBROUTINE m14ama(
     1   PM,      A,       RX,      RY,
     2   RZ,      SX,      SY,      SZ,
     3   AX,      AY,      AZ,      BX,
     4   BY,      BZ,      CX,      CY,
     5   CZ,      NEL,     JCVT,    JSPH)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JCVT
      INTEGER, INTENT(IN) :: JSPH
C     REAL
      my_real PM(NPROPM,*), A(MVSIZ,6)
      my_real
     .   rx(*), ry(*), rz(*), sx(*), sy(*), sz(*),
     .   ax(*), ay(*), az(*), bx(*), by(*), bz(*), cx(*), cy(*),cz(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   TX(MVSIZ), TY(MVSIZ),TZ(MVSIZ), RR
C-----------------------------------------------
C
      IF (jsph==1) THEN
        DO i=1,nel
          ax(i)=a(i,1)
          ay(i)=a(i,2)
          az(i)=a(i,3)
          bx(i)=a(i,4)
          by(i)=a(i,5)
          bz(i)=a(i,6)
          cx(i)=ay(i)*bz(i)-az(i)*by(i)
          cy(i)=az(i)*bx(i)-ax(i)*bz(i)
          cz(i)=ax(i)*by(i)-ay(i)*bx(i)
        END DO
C
      ELSEIF(jcvt==0)THEN
       IF (n2d==0) THEN
        DO i=1,nel
          rr=one/sqrt(rx(i)**2+ry(i)**2+rz(i)**2)
          rx(i)=rx(i)*rr
          ry(i)=ry(i)*rr
          rz(i)=rz(i)*rr
C
          tx(i)=ry(i)*sz(i)-rz(i)*sy(i)
          ty(i)=rz(i)*sx(i)-rx(i)*sz(i)
          tz(i)=rx(i)*sy(i)-ry(i)*sx(i)
          rr=one/sqrt(tx(i)**2+ty(i)**2+tz(i)**2)
          tx(i)=tx(i)*rr
          ty(i)=ty(i)*rr
          tz(i)=tz(i)*rr
C
          sx(i)=ty(i)*rz(i)-tz(i)*ry(i)
          sy(i)=tz(i)*rx(i)-tx(i)*rz(i)
          sz(i)=tx(i)*ry(i)-ty(i)*rx(i)
          rr=1./sqrt(sx(i)**2+sy(i)**2+sz(i)**2)
          sx(i)=sx(i)*rr
          sy(i)=sy(i)*rr
          sz(i)=sz(i)*rr
        ENDDO
       ELSE
        DO i=1,nel
          rr=one/sqrt(sy(i)**2+sz(i)**2)
          sy(i)=sy(i)*rr
          sz(i)=sz(i)*rr
C
          ty(i)=-rx(i)*sz(i)
          tz(i)=rx(i)*sy(i)
          rr=one/sqrt(ty(i)**2+tz(i)**2)
          ty(i)=ty(i)*rr
          tz(i)=tz(i)*rr
        ENDDO
       ENDIF
C
       DO 200 i=1,nel
       ax(i)= a(i,1)*rx(i)+a(i,2)*sx(i)+a(i,3)*tx(i)
       ay(i)= a(i,1)*ry(i)+a(i,2)*sy(i)+a(i,3)*ty(i)
       az(i)= a(i,1)*rz(i)+a(i,2)*sz(i)+a(i,3)*tz(i)
C
       bx(i)= a(i,4)*rx(i)+a(i,5)*sx(i)+a(i,6)*tx(i)
       by(i)= a(i,4)*ry(i)+a(i,5)*sy(i)+a(i,6)*ty(i)
       bz(i)= a(i,4)*rz(i)+a(i,5)*sz(i)+a(i,6)*tz(i)
C
C   22/06/98
C       CX(I)= A(7,I)*RX(I)+A(8,I)*SX(I)+A(9,I)*TX(I)
C       CY(I)= A(7,I)*RY(I)+A(8,I)*SY(I)+A(9,I)*TY(I)
C       CZ(I)= A(7,I)*RZ(I)+A(8,I)*SZ(I)+A(9,I)*TZ(I)
C
        cx(i)=ay(i)*bz(i)-az(i)*by(i)
        cy(i)=az(i)*bx(i)-ax(i)*bz(i)
        cz(i)=ax(i)*by(i)-ay(i)*bx(i)
  200  CONTINUE
C-------------------------------
C     CO-ROTATIONAL FORMULATION IN  ORTHOTROPIC CO-ROTATIONAL SYSTEM.
      ELSE
        DO 500 i=1,nel
         ax(i)=one
         bx(i)=zero
         cx(i)=zero
         ay(i)=zero
         by(i)=one
         cy(i)=zero
         az(i)=zero
         bz(i)=zero
         cz(i)=one 
  500   CONTINUE
      ENDIF
C
      RETURN
      END