m26th.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    m26th      ../engine/source/materials/mat/mat026/m26th.F
!||--- called by ------------------------------------------------------
!||    atherm     ../engine/source/ale/atherm.F
!||--- calls      -----------------------------------------------------
!||    mintp_rt   ../common_source/eos/mintp_rt.F
!||====================================================================
      SUBROUTINE m26th(
     1   MAT,     RHO,     T,       XK,
     2   PM,      SESAME,  Z,       NEL,
     3   NFT)
C----------------------------------------
C     CALCUL DE LA CONDUCTIVITE THERMIQUE
C----------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: NFT
      INTEGER MAT(*)
      my_real
     .   rho(*), t(*), xk(*), pm(npropm,*), sesame(*), z(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, MX, NR, NT, IDR, IDT, IDQ
      my_real
     .   ZZ, DELTAT, XLAMB, STEFAN, RL, TL, OPAC, DXDR, ROSSEL, XKR
      real*8 ne, na, atom
C-----------------------------------------------
      DATA na /6.0225e+23/
C-----------------------------------------------
      !----------------------------
      !     CONDUCTION ELECTRONIQUE
      !----------------------------
      DO i=1,nel
        j=i+nft
        mx = mat(i)
        zz = max(em10,z(i))
        deltat= threep44 * zep26 * log(zz) / zz
        IF(deltat>zero)THEN
          deltat= one / ( one +  deltat)
        ELSE
          deltat= zero
        ENDIF
        atom  = pm(37,mx)
        ne    = rho(i)*na*zz/atom
        xlamb = pm(36,mx)*t(i)**three_half/sqrt(ne)
        xlamb = max(one,xlamb)
        xlamb = max(em10, log(xlamb))
        xk(j) = xk(j) + zep4*deltat*pm(35,mx)*t(i)**twop5 / (zz*xlamb)
      ENDDO
 
      !----------------------------
      !     RADIATION
      !----------------------------
      DO i=1,nel
        j=i+nft
        mx = mat(i)
        stefan = pm(51,mx)
        IF(stefan>zero.AND.t(i)>ep04)THEN
          nr     = nint(pm(48,mx))
          nt     = nint(pm(49,mx))
          idr    = nint(pm(50,mx))
          idt = idr + nr
          idq = idt + nt
          rl = log10(rho(i))
          tl = log10(t(i))
          CALL mintp_rt(sesame(idr),nr,
     +        sesame(idt),nt,sesame(idq),rl,tl,opac,dxdr)
          opac = ten**opac
          rossel = one / ( rho(i) * opac)
          xkr = sixteen * stefan * t(i)**3 * rossel * third
          xk(j) = xk(j) + xkr
        ENDIF
        xk(j) = min(xk(j),pm(52,mx))
      ENDDO
C
      RETURN
      END