m75init.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    m75init                ../starter/source/materials/mat/mat075/m75init.F
!||--- called by ------------------------------------------------------
!||    matini                 ../starter/source/materials/mat_share/matini.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    finter                 ../starter/source/tools/curve/finter.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE m75init(
     1      NEL    , NUPARAM, NUVAR   , NFUNC  , IFUNC  , NPF   ,
     2      TF     , UPARAM , RHO0    , VOLUME , EINT   ,UVAR   ,
     3      PM     ,ID       ,TITR) 
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I M P L I C I T   T Y P E S
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   A n a l y s e   M o d u l e
C-----------------------------------------------
C---------+---------+---+---+--------------------------------------------
C VAR     | SIZE    |TYP| RW| DEFINITION
C---------+---------+---+---+--------------------------------------------
C NEL     |  1      | I | R | SIZE OF THE ELEMENT GROUP NEL 
C NUPARAM |  1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C NUVAR   |  1      | I | R | NUMBER OF USER ELEMENT VARIABLES
C---------+---------+---+---+--------------------------------------------
C NFUNC   |  1      | I | R | NUMBER FUNCTION USED FOR THIS USER LAW
C IFUNC   | NFUNC   | I | R | FUNCTION INDEX 
C NPF     |  *      | I | R | FUNCTION ARRAY   
C TF      |  *      | F | R | FUNCTION ARRAY 
C---------+---------+---+---+--------------------------------------------
C UPARAM  | NUPARAM | F | R | USER MATERIAL PARAMETER ARRAY
C RHO0    | NEL     | F | R | INITIAL DENSITY
C VOLUME  | NEL     | F | R | VOLUME
C EINT    | NEL     | F | R | TOTAL INTERNAL ENERGY
C---------+---------+---+---+--------------------------------------------
C UVAR    |NEL*NUVAR| F |R/W| USER ELEMENT VARIABLE ARRAY
C---------+---------+---+---+--------------------------------------------
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C----------------------------------------------------------------
C  I N P U T   A R G U M E N T S
C----------------------------------------------------------------
      INTEGER       NEL, NUPARAM, NUVAR
      my_real
     .      UPARAM(NUPARAM), RHO0(NEL), VOLUME(NEL), EINT(NEL),
     .      pm(npropm,*)                
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
C----------------------------------------------------------------
C  I N P U T  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real
     . uvar(nel,nuvar)
C----------------------------------------------------------------
C  VARIABLES FOR FUNCTION INTERPOLATION 
C----------------------------------------------------------------
      INTEGER NPF(*), NFUNC, IFUNC(NFUNC)
      my_real
     .   FINTER,TF(*)
      EXTERNAL finter
C----------------------------------------------------------------
C  L O C A L  V A R I A B L E S
C----------------------------------------------------------------
      INTEGER  I, IMAT
C     REAL
      my_real
     .        ce, pe, ps, en, rho0s, alphae, bulks, c0, beta, aa,
     .        dalpdpe, alphap, bulk
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
      bulk = uparam(1)
      pe   = uparam(2)
      ps   = uparam(3)
      en   = uparam(4)
      imat = nint(uparam(6))
      ce   = sqrt(bulk/rho0(1))
C
      IF(imat==0) THEN
        alphae=zero
        alphap=zero
        aa=zero
      ELSE
        rho0s =pm(89,imat)
        alphae=rho0s/rho0(1)
        bulks= pm(32,imat)
        c0   = sqrt(bulks/rho0s)
        beta=ce/c0
        aa=(beta-one)/(alphae-one)
        dalpdpe=(one/bulks-one/bulk)*alphae
        alphap=alphae+pe*dalpdpe
C
        IF (alphae < one) THEN
           CALL ancmsg(msgid=898,
     .                 msgtype=msgerror,
     .                 anmode=aninfo,
     .                 i1=id,
     .                 c1=titr)
        ENDIF
        IF (bulks < bulk) THEN
           CALL ancmsg(msgid=1003,
     .                 msgtype=msgerror,
     .                 anmode=aninfo,
     .                 i1=id,
     .                 c1=titr)
        ENDIF
      ENDIF
C-----------
C INITIALIZE
C-----------
      uparam(11)=alphae
      uparam(12)=alphap
      uparam(13)=aa
      uparam(14)=one/en
      uparam(15)=(ps-pe)/(alphap-one)**(one/en)
      uparam(16)=(alphap-one)/(ps-pe)**en
C
      DO i=1,nel                    
        uvar(i,1)=zero
        uvar(i,2)=zero
        uvar(i,3)=alphae
        uvar(i,4)=alphap
      ENDDO
C         
      RETURN
      END