mat11check.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    mat11check             ../starter/source/materials/mat/mat011/mat11check.F
!||--- called by ------------------------------------------------------
!||    matini                 ../starter/source/materials/mat_share/matini.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE mat11check(PM,NIX,IX,ALE_CONNECTIVITY,NUMEL,JALE_FROM_PROP,NEL,NFT,MAT_ID,NUMMAT,NPROPM)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutines is checking if material boundary
C law11 has compatible material law with adjacent element
C
C This subroutine is called when group of elem (LFT,LLT)
C is associated with material law 11
C
C NUMEL            : total number of solid elements (2d or 3d)
C IX               : element connectivity + mat_id (size NIX,NUMEL)
C PM               : material properties (real)
C ALE_CONNECTIVITY : connectivity buffer (ALE)
C JALE_FROM_PROP   : property flag which set ALE or EULER
C NEL              : number of element in current group
C MFT              : shift index to retrieve global internal identifier
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: NUMEL,NIX,IX(NIX,NUMEL),JALE_FROM_PROP,NEL,NFT
      INTEGER,INTENT(IN) :: MAT_ID,NUMMAT, NPROPM
      my_real,INTENT(IN) :: pm(npropm,nummat)
      TYPE(t_ale_connectivity), INTENT(INOUT) :: ALE_CONNECTIVITY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, IVMAT,IMAT, ELEM_UID, MLN, J, IE, IEV, IAD1,LGTH
      INTEGER lFOUND_monomat, lFOUND_multimat
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
        IF(jale_from_prop == 0)THEN
          CALL ancmsg(msgid = 122,msgtype=msgerror,anmode=aninfo,
     .                i1    = mat_id,
     .                c1    = "MATERIAL LAW 11 MUST BE DEFINED WITH ALE OR EULER FRAMEWORK" )
        ENDIF
 
        DO i=1,nel
          ie = i + nft
          elem_uid = ix(nix,ie)
          imat = ix(1,ie)
          lfound_monomat = 0
          lfound_multimat = 0
          !loop over all adjacent elems
          iad1 = ale_connectivity%ee_connect%iad_connect(ie)
          lgth = ale_connectivity%ee_connect%iad_connect(ie+1) - iad1
          DO j=1,lgth
            iev = ale_connectivity%ee_connect%connected(iad1 + j - 1)
            IF(iev == 0)cycle
            ivmat = abs(ix(1,iev))
            mln = nint(pm(19,ivmat))
            IF(mln == 51 .OR. mln == 151 .OR. mln == 37)lfound_multimat = lfound_multimat + 1
            IF(mln /= 11)lfound_monomat = lfound_monomat + 1
          enddo! next J
 
          IF(lfound_multimat /= 0)THEN
              CALL ancmsg(msgid = 122,msgtype=msgerror,anmode=aninfo,
     .                    i1    = elem_uid,
     .                    c1    = "MATERIAL LAW 11 IS NOT COMPATIBLE WITH MULTIMATERIAL FORMULATION" )
          ENDIF
          IF(lfound_monomat == 0)THEN
              CALL ancmsg(msgid = 123,msgtype=msgwarning,anmode=aninfo,
     .                    i1    = elem_uid,
     .                    c1    = "HAS NO ADJACENT FACE IN COMPUTATION DOMAIN (MATERIAL LAW11)" )
          ENDIF
          IF(lfound_monomat >= 2)THEN
              CALL ancmsg(msgid = 122,msgtype=msgerror,anmode=aninfo,
     .                    i1    = elem_uid,
     .                    c1    = "MUST HAVE ONLY ONE FACE ADJACENT TO COMPUTATION DOMAIN (MATERIAL LAW11)" )
          ENDIF
        ENDDO !next I
C-----------------------------------------------
      RETURN
      END SUBROUTINE mat11check