mnsvis.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    mnsvis   ../engine/source/materials/mat_share/mnsvis.F
!||--- called by ------------------------------------------------------
!||    m24law   ../engine/source/materials/mat/mat024/m24law.F
!||    mmain    ../engine/source/materials/mat_share/mmain.F90
!||====================================================================
      SUBROUTINE mnsvis(
     1   PM,      OFF,     RHO,     GEO,
     2   PID,     SSP,     AIRE,    VOL,
     3   D1,      D2,      D3,      D4,
     4   D5,      D6,      MAT,     ISVIS,
     5   RHOREF,  NEL,     SVIS)
 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
C     REAL
      my_real
     .   PM(NPROPM,*), OFF(*), RHO(*),GEO(NPROPG,*), SSP(*),
     .   AIRE(*), VOL(*), D1(*), D2(*), D3(*),
     .   d4(*), d5(*), d6(*), rhoref(*)
      my_real, DIMENSION(MVSIZ,6), INTENT(INOUT) :: svis
      INTEGER PID(*), MAT(*),ISVIS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, MT
C     REAL
      my_real
     .   dd(mvsiz), al(mvsiz), cns1, cns2, cns3,
     .   dav, pvis, rho0(mvsiz), nrho(mvsiz)
C-----------------------------------------------
      IF (isvis==0) RETURN
      DO 10 i=1,nel
   10 dd(i)=-d1(i)-d2(i)-d3(i)
C
      DO 20 i=1,nel
       al(i)=zero
       IF(off(i)<one) GO TO 20
       IF(n2d>0) THEN
        al(i)=sqrt(aire(i))
       ELSE
        al(i)=exp(third*log(vol(i)))
       END IF
 20   CONTINUE
C-----------------------------------------------
C     Large strain :: Critical damping D = L * rho * c, c = sqrt(A11/rho)
C       BUT c is computed as sqrt(A11/rho0) for most of the materials
C       <=> D = L * sqrt(rho) * sqrt(rho0) * sqrt(A11/rho0)
C     Note : if for a given material, c is computed as sqrt(A11/rho), 
C     ----     then damping will result in L * sqrt(rho) * sqrt(rho0) * c
C              and will be in the ratio sqrt(rho0) / sqrt(rho) wrt critical damping
C                                       < 1 in compression
C                                       > 1 in tension 
C                                       this ratio will be more likely limited.
C
C     Small strain :: Critical damping D = L * rhoref * c, c = sqrt(A11/rhoref)
C       BUT c is computed as sqrt(A11/rho0) for most of the materials
C       <=> D = L * sqrt(rhoref) * sqrt(rho0) * sqrt(A11/rho0)
C
C-----------------------------------------------
      mt = mat(1)
      DO i=1,nel
        rho0(i) = pm(1,mt)
        nrho(i) = sqrt(rhoref(i)*rho0(i))
      ENDDO
C
      IF(geo(16,pid(1)) >= zero)THEN
        DO i=1,nel
          cns1=geo(16,pid(1))*al(i)*nrho(i)*ssp(i)*off(i)
          cns2=geo(17,pid(1))*al(i)*nrho(i)*ssp(i)*off(i)
          cns3=half*cns2
          dav=dd(i) * third
          pvis=-cns1*dd(i)
          svis(i,1)=cns2 *(d1(i)+dav) + pvis
          svis(i,2)=cns2 *(d2(i)+dav) + pvis
          svis(i,3)=cns2 *(d3(i)+dav) + pvis
          svis(i,4)=cns3 * d4(i)
          svis(i,5)=cns3 * d5(i)
          svis(i,6)=cns3 * d6(i)
C          IF(GEO(16,PID(I)) /= ZERO .OR. GEO(17,PID(I))/=ZERO) ISVIS = 1
        ENDDO
      ELSE
        DO i=1,nel
          cns1=abs(geo(16,pid(1)))*nrho(i)*ssp(i)**2*off(i)
          cns2=abs(geo(17,pid(1)))*nrho(i)*ssp(i)**2*off(i)
          cns3=half*cns2
          dav=dd(i) * third
          pvis=-cns1*dd(i)
          svis(i,1)=cns2 *(d1(i)+dav) + pvis
          svis(i,2)=cns2 *(d2(i)+dav) + pvis
          svis(i,3)=cns2 *(d3(i)+dav) + pvis
          svis(i,4)=cns3 * d4(i)
          svis(i,5)=cns3 * d5(i)
          svis(i,6)=cns3 * d6(i)
C          IF(GEO(16,PID(I)) /= ZERO .OR. GEO(17,PID(I))/=ZERO) ISVIS = 1
        ENDDO
      END IF
C
      RETURN
      END