mstrain_rate.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    mstrain_rate   ../engine/source/materials/mat_share/mstrain_rate.F
!||--- called by ------------------------------------------------------
!||    m2law          ../engine/source/materials/mat/mat002/m2law.F
!||    mulaw          ../engine/source/materials/mat_share/mulaw.F90
!||    sigeps44       ../engine/source/materials/mat/mat044/sigeps44.F
!||    sigeps93       ../engine/source/materials/mat/mat093/sigeps93.F
!||====================================================================
      SUBROUTINE mstrain_rate(NEL    ,ISRATE ,ASRATE ,EPSD   ,IDEV   ,
     .                        EP1    ,EP2    ,EP3    ,EP4    ,EP5    ,EP6)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  NEL,ISRATE,IDEV
      my_real  asrate
      my_real, DIMENSION(NEL), INTENT(IN)    :: ep1, ep2, ep3, ep4, ep5, ep6
      my_real, DIMENSION(NEL), INTENT(INOUT) :: epsd
C---------------------------------------------------
C   L o c a l   V a r i a b l e s
C---------------------------------------------------
      INTEGER I
      my_real :: e1, e2, e3, e4, e5, e6, dav, epsp
      my_real :: epsdot(nel)
c-----------------------------------------------------------------------
c  COMPUTE EQUIVALENT STRAIN RATE
c        IDEV = 0 => total strain rate
c        IDEV = 1 => deviatoric strain rate
C=======================================================================
      IF (israte >= 0) THEN   ! calculate strain rate
        IF (idev == 0) THEN   ! total strain rate
          DO i=1,nel
            e1 = ep1(i)
            e2 = ep2(i)
            e3 = ep3(i)
            e4 = half*ep4(i)
            e5 = half*ep5(i)
            e6 = half*ep6(i)
            epsp = e1**2 + e2**2 + e3**2 + two*(e4**2 + e5**2 + e6**2)
            epsdot(i) = sqrt(epsp)
          ENDDO
        ELSE                  ! deviatoric strain rate
          DO i=1,nel
            dav = (ep1(i)+ep2(i)+ep3(i))*third
            e1  = ep1(i) - dav
            e2  = ep2(i) - dav
            e3  = ep3(i) - dav
            e4  = half*ep4(i)
            e5  = half*ep5(i)
            e6  = half*ep6(i)
            epsp = half*(e1**2 + e2**2 + e3**2) + e4**2 + e5**2 + e6**2
            epsdot(i) = sqrt(three*epsp)/three_half
          ENDDO
        ENDIF
      ENDIF
c
      IF (israte == 0) THEN
        epsd(:) = epsdot(:)
      ELSEIF (israte > 0) THEN
        epsd(:) = asrate*epsdot(:) + (one - asrate)*epsd(:)
      ENDIF
c-----------
      RETURN
      END