multi_i18_force_poff.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    multi_i18_force_poff   ../engine/source/interfaces/int18/multi_i18_force_poff.F
!||--- called by ------------------------------------------------------
!||    i18for3                ../engine/source/interfaces/int18/i18for3.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod           ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    multi_fvm_mod          ../common_source/modules/ale/multi_fvm_mod.f90
!||    tri7box                ../engine/share/modules/tri7box.f
!||====================================================================
      SUBROUTINE multi_i18_force_poff(DT, JLT   ,IX1  ,IX2  ,IX3  ,IX4    ,
     .     NSVG  ,H1   ,H2   ,H3   ,H4     ,STIF ,
     .     FX1   ,FY1  ,FZ1  ,FX2  ,FY2    ,FZ2  ,
     .     FX3   ,FY3  ,FZ3  ,FX4  ,FY4    ,FZ4  ,
     .     FXI   ,FYI  ,FZI  ,A    ,STIFN  ,NIN,
     .     JTASK, MULTI_FVM  ,X    ,IXS    ,V  ,
     .     ELBUF_TAB,IGROUPS,IPARG ,MSI)
!$COMMENT
!       MULTI_I18_FORCE_POFF description
!       accumulation of force for local and remote nodes
!       
!       MULTI_I18_FORCE_POFF organization :
!       - secondary nodes:
!            * if NSV > 0 --> local node (phantom node id = NSV - NUMNOD)
!                             accumulation in FORC_INT array
!            * if NSV < 0 --> remote node
!                             accumulation in AFI array
!$ENDCOMMENT
 
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE multi_fvm_mod
      USE tri7box
      USE elbufdef_mod       
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (ELBUF_STRUCT_), DIMENSION(NGROUP) :: ELBUF_TAB
      INTEGER JLT, NIN,INTTH,JTASK,IGROUPS(NUMELS),IPARG(NPARG,*),
     .        IX1(MVSIZ),IX2(MVSIZ),IX3(MVSIZ),IX4(MVSIZ),NSVG(MVSIZ),IXS(NIXS,*)
      my_real, DIMENSION(2*MVSIZ), INTENT(in) :: MSI
      my_real
     .    DT, H1(MVSIZ),H2(MVSIZ),H3(MVSIZ),H4(MVSIZ),STIF(MVSIZ),
     .    fx1(mvsiz),fy1(mvsiz),fz1(mvsiz),
     .    fx2(mvsiz),fy2(mvsiz),fz2(mvsiz),
     .    fx3(mvsiz),fy3(mvsiz),fz3(mvsiz),
     .    fx4(mvsiz),fy4(mvsiz),fz4(mvsiz),
     .    fxi(mvsiz),fyi(mvsiz),fzi(mvsiz),
     .    a(3,*), x(3,*), stifn(*), v(3,*)
      TYPE(multi_fvm_struct), INTENT(INOUT) :: MULTI_FVM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J1, IG, ISHIFT, NODFI, NG, ILOC, NEL, NFT
      INTEGER :: SHIFT_FORCE_INT
      my_real mass
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
c     Nodal forces on the interface
      DO i=1,jlt
         j1=ix1(i)
         a(1,j1)=a(1,j1)+fx1(i)
         a(2,j1)=a(2,j1)+fy1(i)
         a(3,j1)=a(3,j1)+fz1(i)
         stifn(j1) = stifn(j1) + stif(i)*abs(h1(i))
C     
         j1=ix2(i)
         a(1,j1)=a(1,j1)+fx2(i)
         a(2,j1)=a(2,j1)+fy2(i)
         a(3,j1)=a(3,j1)+fz2(i)
         stifn(j1) = stifn(j1) + stif(i)*abs(h2(i))
C     
         j1=ix3(i)
         a(1,j1)=a(1,j1)+fx3(i)
         a(2,j1)=a(2,j1)+fy3(i)
         a(3,j1)=a(3,j1)+fz3(i)
         stifn(j1) = stifn(j1) + stif(i)*abs(h3(i))
C     
         j1=ix4(i)
         a(1,j1)=a(1,j1)+fx4(i)
         a(2,j1)=a(2,j1)+fy4(i)
         a(3,j1)=a(3,j1)+fz4(i)
         stifn(j1) = stifn(j1) + stif(i)*abs(h4(i))
      ENDDO
C
      nodfi = nlskyfi(nin)
      ishift = nodfi*(jtask-1)
      DO i=1,jlt
         ig=nsvg(i)
         ! --------------------
         ! local node
         IF (ig > 0) THEN
            ig = ig - numnod
            ng = igroups(ig)
            nft=iparg(3,ng)
            nel=iparg(2,ng)
            iloc=ig-nft     
 
            shift_force_int = (jtask-1)*numels
            multi_fvm%FORCE_INT(1,ig+shift_force_int) = multi_fvm%FORCE_INT(1,ig+shift_force_int) - dt*fxi(i)
            multi_fvm%FORCE_INT(2,ig+shift_force_int) = multi_fvm%FORCE_INT(2,ig+shift_force_int) - dt*fyi(i)
            multi_fvm%FORCE_INT(3,ig+shift_force_int) = multi_fvm%FORCE_INT(3,ig+shift_force_int) - dt*fzi(i)
         ! --------------------
         ! remote node
         ELSE
            ig = - ig
            afi(nin)%P(1,ig+ishift) = afi(nin)%P(1,ig+ishift) - dt * fxi(i) 
            afi(nin)%P(2,ig+ishift) = afi(nin)%P(2,ig+ishift) - dt * fyi(i) 
            afi(nin)%P(3,ig+ishift) = afi(nin)%P(3,ig+ishift) - dt * fzi(i) 
         ENDIF
         ! --------------------
      ENDDO
      END SUBROUTINE multi_i18_force_poff