multifluid_global_tdet.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    multifluid_global_tdet   ../starter/source/multifluid/multifluid_global_tdet.F
!||--- called by ------------------------------------------------------
!||    initia                   ../starter/source/elements/initia/initia.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE multifluid_global_tdet(IPARG,ELBUF_TAB,MULTI_FVM,IPM)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C CASE OF SUBMATERIAL BASED ON JWL MATERIAL LAW (HIGH EXPLISIVE WITH TIME CONTROL DETONATION)
C
C This subroutine is computing detonation times in global buffer from detonation times of layers (submaterials
C Global detonation time is relevant when there are several explosive submaterial laws.
C
C GBUF%TB : global burning time (may not be allocated in case of JWL is not used, check GBUF%G_TB > 0)
C LBUF%TB : local burning time of current layer
C If initial volume fraction is 0.0 then detonation time of current layer is not taken into account to calculate global detonation time.
C
C This subroutine must be called after INIVIOL treatment (INITIAL VOLUME FRACTION)
C Precondition : MULTI_FVM%IS_USED=.TRUE.
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod 
      USE multi_fvm_mod
      USE message_mod
      USE multi_fvm_mod
      USE constant_mod , ONLY : zero, ep21
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
          implicit none
#include      "my_real.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IPARG(NPARG,NGROUP),IPM(NPROPMI,NUMMAT)
      TYPE(elbuf_struct_), TARGET, DIMENSION(NGROUP),INTENT(INOUT) :: ELBUF_TAB
      TYPE(multi_fvm_struct), INTENT(INOUT) :: MULTI_FVM     
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      LOGICAL IS_JWL
      INTEGER :: NEL,IG,OFFSET,NG,SUBMATLAW,ILAY,NLAY,II
      my_real :: vfrac
      TYPE(l_bufel_) ,POINTER :: LBUF     
      TYPE(g_bufel_) ,POINTER :: GBUF  
      TYPE(buf_mat_) ,POINTER :: MBUF
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      IF(multi_fvm%IS_USED)THEN
        DO ng=1,ngroup    
              mtn     = iparg(1,ng)
              nel     = iparg(2,ng)
              nft     = iparg(3,ng)
              ity     = iparg(5,ng)
              gbuf => elbuf_tab(ng)%GBUF
              !---skip if Burn Fraction is not allocated
              IF(gbuf%G_TB > 0)THEN                
                !---skip if material law is not #151
                IF (mtn == 151) THEN
                  nlay = elbuf_tab(ng)%NLAY
                  DO ig=1,nel,nvsiz                                                                               
                    offset   = ig - 1                                                                                
                    lft      = 1                                             
                    llt      = min(nvsiz,nel-offset)                                                                 
                    nft      = iparg(3,ng) + offset  
                    is_jwl = .false.
                    !Number of layers ( = number of material in law 151)
                    IF (nlay > 1) THEN
                       gbuf%TB(lft:llt) = -ep21
                       DO ilay = 1, nlay
                          !SUBMATLAW = IPM(2, IPM(20 + ILAY, MTN))
                          submatlaw = elbuf_tab(ng)%BUFLY(ilay)%ILAW
                          IF (submatlaw == 5) THEN
                             lbuf => elbuf_tab(ng)%BUFLY(ilay)%LBUF(1,1,1)
                             DO ii = lft, llt
                                vfrac = lbuf%VOL(ii)/gbuf%VOL(ii)
                                IF(vfrac >= zero)THEN
                                  gbuf%TB(ii) = max(gbuf%TB(ii), lbuf%TB(ii))
                                ENDIF
                             ENDDO
                             is_jwl = .true.
                          ENDIF
                       ENDDO
                       IF(.NOT.is_jwl)THEN
                         DO ii = lft, llt
                           gbuf%TB(ii) = zero
                         ENDDO   
                       ELSE
                         DO ii = lft, llt
                           IF(gbuf%TB(ii) <= -ep21)THEN
                             gbuf%TB(ii) = zero
                           ENDIF
                         ENDDO                                        
                       ENDIF
                     ENDIF  ! IF(NLAY > 1)
                  ENDDO ! next IG                          
                ENDIF ! IF(MTN == 151)                                      
              ENDIF ! IF(GBUF%G_TB > 0)
         ENDDO ! next NG                                 
 
      ENDIF ! IF(MULTI_FVM%IS_USED)THEN  
          
      END SUBROUTINE