nlocal_dtnoda.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    nlocal_dtnoda    ../engine/source/time_step/nlocal_dtnoda.F
!||--- called by ------------------------------------------------------
!||    resol            ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    my_barrier       ../engine/source/system/machine.f
!||--- uses       -----------------------------------------------------
!||    nlocal_reg_mod   ../common_source/modules/nlocal_reg_mod.f
!||====================================================================
      SUBROUTINE nlocal_dtnoda(NODFT    ,NODLT    ,NLOC_DMG ,DTNOD_NLOCAL, DT2T )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE nlocal_reg_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr02_c.inc"
#include      "scr18_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NODFT, NODLT
      TYPE(nlocal_str_), TARGET :: NLOC_DMG 
      my_real
     .    dt2t,dtnod_nlocal
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N,I,NDDL,NPOS
      my_real, DIMENSION(:), ALLOCATABLE ::
     .  dtn
      my_real, POINTER, DIMENSION(:) :: 
     .  mass,stifn
      my_real
     .  dtnod,dt2p
C  
      dtnod = ep20
C
      IF (nodadt > 0) THEN
C
        ! Recovering nodal stiffness and masses
        stifn => nloc_dmg%STIFNL(1:nloc_dmg%L_NLOC,1)
        mass  => nloc_dmg%MASS(1:nloc_dmg%L_NLOC)
C
        ! Allocating non-local nodal timestep table
        ALLOCATE(dtn(nloc_dmg%L_NLOC))
        dtn(1:nloc_dmg%L_NLOC) = zero   
C
        ! Determining the minimum of non-local nodal timestep
        DO n = nodft,nodlt
          ! Position of the first additional dof
          npos = nloc_dmg%POSI(n)
          ! Number of additional degrees of freedom
          nddl = nloc_dmg%POSI(n+1) - npos
          ! Computation of the non-local nodal timestep
          DO i = npos,npos+nddl-1
            dtn(i) = dtfac1(11)*cdamp*sqrt(two*mass(i)/max(stifn(i),em20))
            dtnod  = min(dtnod,dtn(i))
          ENDDO    
        ENDDO
#include "lockon.inc"
        dtnod_nlocal = min(dtnod_nlocal,dtnod)
#include "lockoff.inc"
C
        CALL my_barrier()
        dtnod = dtnod_nlocal
        ! /DT/NODA/CSTX - Constant timestep with added mass
        IF ((idtmin(11)==3).OR.(idtmin(11)==4).OR.(idtmin(11)==8)) THEN 
          ! Added mass computation if necessary
          IF (dtnod < dtmin1(11)*(sqrt(csta))) THEN
            DO n = nodft,nodlt
              ! Position of the first additional dof
              npos = nloc_dmg%POSI(n)
              ! Number of additional degrees of freedom
              nddl = nloc_dmg%POSI(n+1) - npos
              ! Computation of the new non-local mass
              DO i = npos,npos+nddl-1
                IF (dtn(i) < dtmin1(11)) THEN
                  dt2p    = dtmin1(11)/(dtfac1(11)*cdamp)
                  mass(i) = csta*max(mass(i),half * stifn(i) * dt2p * dt2p * onep00001)
                ENDIF
              ENDDO
            ENDDO
            dtnod = dtmin1(11)*(sqrt(csta))
          ENDIF
        ENDIF 
C
#include "lockon.inc"
        ! Classical nodal timestep check
        IF (dtnod < dt2t) THEN
          dt2t = min(dt2t,dtnod)
        ENDIF
#include "lockoff.inc"
C       
        ! Resetting non-local nodal stiffness
        DO n = nodft,nodlt
          ! Position of the first additional dof
          npos = nloc_dmg%POSI(n)
          ! Number of additional degrees of freedom
          nddl = nloc_dmg%POSI(n+1) - npos
          ! Resetting nodal stiffness
          stifn(npos:npos+nddl-1) = em20
        ENDDO
C
        ! Deallocation
        IF (ALLOCATED(dtn)) DEALLOCATE(dtn)
C
      ENDIF
      END