noble_abel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    noble_abel_mod   ../common_source/eos/noble_abel.F
!||--- called by ------------------------------------------------------
!||    eosmain          ../common_source/eos/eosmain.F
!||    eosmain51        ../engine/source/materials/mat/mat051/eosmain51.F90
!||====================================================================
      MODULE noble_abel_mod
      IMPLICIT NONE
      CONTAINS
!||====================================================================
!||    noble_abel      ../common_source/eos/noble_abel.F
!||--- called by ------------------------------------------------------
!||    eosmain         ../common_source/eos/eosmain.F
!||    eosmain51       ../engine/source/materials/mat/mat051/eosmain51.F90
!||--- uses       -----------------------------------------------------
!||    constant_mod    ../common_source/modules/constant_mod.F
!||    eos_param_mod   ../common_source/modules/mat_elem/eos_param_mod.F90
!||====================================================================
      SUBROUTINE noble_abel(
     1                      IFLAG  , NEL    ,OFF  ,EINT      ,MU   ,
     2                      ESPE   , DVOL   ,DF   ,VNEW      ,PSH ,
     3                      PNEW   , DPDM   ,DPDE ,EOS_STRUCT)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of NOBLE-ABEL EOS
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE eos_param_mod , ONLY : eos_param_
        USE constant_mod , ONLY : em15,half,one,zero
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        IMPLICIT NONE
#include "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IFLAG
      INTEGER,INTENT(IN) :: NEL
      my_real,INTENT(INOUT) :: DPDM(NEL),DPDE(NEL),PSH(NEL)  ,EINT(NEL),PNEW(NEL)
      my_real,INTENT(IN) :: off(nel)  ,mu(nel)
      my_real,INTENT(IN) :: espe(nel) ,dvol(nel) ,df(nel), vnew(nel)
      TYPE(eos_param_),INTENT(IN) :: EOS_STRUCT !< data structure for EoS parameters
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I
      my_real :: GM1, DVV, PP,BB_,RHO0,DENOM,BB
C-----------------------------------------------
 
      bb_  = eos_struct%UPARAM(1)
      gm1  = eos_struct%UPARAM(2)
      rho0 = eos_struct%UPARAM(3)
      psh(1:nel)  = eos_struct%PSH
 
      IF(iflag == 0) THEN
        DO i=1,nel
          denom   = one-bb_*rho0*(one+mu(i))
          pp      = espe(i)*gm1*(mu(i)+one)/denom
          dpde(i) = gm1*(one+mu(i))/denom
          dpdm(i) = gm1*espe(i)/denom + pp/denom*bb_*rho0 + pp*df(i)*df(i)*dpde(i)
          pnew(i) = max(pp,zero)*off(i)! P(mu[n+1],E[n])
          pnew(i) = pnew(i)-psh(i)
        ENDDO
 
      ELSEIF(iflag == 1) THEN
        DO i=1,nel
          denom   = one-bb_*rho0*(one+mu(i))
          bb      = gm1*(one+mu(i))/denom
          dpde(i) = bb
          dvv     = half*dvol(i)*df(i) / max(em15,vnew(i))
          pnew(i) = (bb*espe(i))/(one+bb*dvv)
          pnew(i) = pnew(i)*off(i)! P(mu[n+1],E[n])
          eint(i) = eint(i) - half*dvol(i)*pnew(i)
          pnew(i) = pnew(i)-psh(i)
        ENDDO
 
      ELSEIF(iflag == 2) THEN
        DO i=1, nel
          IF (vnew(i) > zero) THEN
            denom   = one-bb_*rho0*(one+mu(i))
            pp      = espe(i)*gm1*(mu(i)+one)/denom
            dpde(i) = gm1*(one+mu(i))/denom
            dpdm(i) = gm1*espe(i)/denom + pp/denom*bb_*rho0 + pp*df(i)*df(i)*dpde(i)
            pnew(i) = pp-psh(i)
          ENDIF
        ENDDO
      ENDIF
      RETURN
 
      END SUBROUTINE noble_abel
      END MODULE noble_abel_mod