nodalt_8F_source.html

Copyright>        OpenRadioss

Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.

Copyright>

Copyright>        This program is free software: you can redistribute it and/or modify

Copyright>        it under the terms of the GNU Affero General Public License as published by

Copyright>        the Free Software Foundation, either version 3 of the License, or

Copyright>        (at your option) any later version.

Copyright>

Copyright>        This program is distributed in the hope that it will be useful,

Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of

Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

Copyright>        GNU Affero General Public License for more details.

Copyright>

Copyright>        You should have received a copy of the GNU Affero General Public License

Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.

Copyright>

Copyright>

Copyright>        Commercial Alternative: Altair Radioss Software

Copyright>

Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss

Copyright>        software under a commercial license.  Contact Altair to discuss further if the

Copyright>        commercial version may interest you: https://www.altair.com/radioss/.

!||====================================================================

!||    nodalt                       ../engine/source/output/anim/generate/nodalt.F

!||--- called by ------------------------------------------------------

!||    genani                       ../engine/source/output/anim/generate/genani.f

!||    h3d_nodal_scalar             ../engine/source/output/h3d/h3d_results/h3d_nodal_scalar.F

!||--- calls      -----------------------------------------------------

!||    anim_nodal_contour_fvmbags   ../engine/source/output/anim/generate/anim_nodal_contour_fvmbags.f

!||--- uses       -----------------------------------------------------

!||    elbufdef_mod                 ../common_source/modules/mat_elem/elbufdef_mod.F90

!||    fvbag_mod                    ../engine/share/modules/fvbag_mod.F

!||    groupdef_mod                 ../common_source/modules/groupdef_mod.F

!||    i22bufbric_mod               ../common_source/modules/interfaces/cut-cell-search_mod.F

!||    i22edge_mod                  ../common_source/modules/interfaces/cut-cell-buffer_mod.f

!||    i22tri_mod                   ../common_source/modules/interfaces/cut-cell-search_mod.F

!||    initbuf_mod                  ../engine/share/resol/initbuf.F

!||====================================================================


      SUBROUTINE nodalt(IFUNC    , WA4      , WA4_FVM, IFLOW  , RFLOW,

     .                  IPARG    , ELBUF_TAB, IX     , NIX    , NUMEL,

     .                  ITAB     , NV46     , MONVOL , VOLMON , AIRBAGS_TOTAL_FVM_IN_H3D,

     .                  IS_WRITTEN_NODE,IS_WRITTEN_NODE_FVM, ISPMD, FVDATA_P,

     .                  SWA4     , AIRBAGS_NODE_ID_SHIFT)

C-----------------------------------------------

C   D e s c r i p t i o n

C-----------------------------------------------

C   This subroutine defines & writes nodal temperature requested by Engine keywords /H3D/NODA/TEMP or /ANIMNODA/TEMP

C      application :  /MONVOL/FVMBAG* (temperature from polyhedra, specific buffer).

C                     ELEMS (values expanded to adjacent nodes)

C-----------------------------------------------

C   P r e - C o n d i t i o n s

C-----------------------------------------------

C     Tested below during NG LOOP : IALEL > 0

C        where IALEL =IPARG(7,NG)+IPARG(11,NG)

C-----------------------------------------------

C   M o d u l e s

C-----------------------------------------------

      USE initbuf_mod

      USE elbufdef_mod

      USE i22bufbric_mod

      USE i22edge_mod

      USE i22tri_mod

      USE fvbag_mod , only:fvbag_data,nfvbag

      USE groupdef_mod , only:group_

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

#include      "implicit_f.inc"

C-----------------------------------------------

C   C o m m o n   B l o c k s

C-----------------------------------------------

#include      "com01_c.inc"

#include      "com04_c.inc"

#include      "vect01_c.inc"

#include      "param_c.inc"

#include      "inter22.inc"

#include      "tabsiz_c.inc"

C-----------------------------------------------

C   D u m m y   A r g u m e n t s

C-----------------------------------------------

      INTEGER,INTENT(IN) :: NUMEL, IFUNC, NIX, NV46,ITAB(NUMNOD), ISPMD, SWA4, AIRBAGS_NODE_ID_SHIFT

      INTEGER,INTENT(IN) :: IFLOW(*),IPARG(NPARG,NGROUP),IX(NIX,NUMEL)

      my_real,INTENT(IN) :: RFLOW(*)

      INTEGER,INTENT(IN) :: AIRBAGS_TOTAL_FVM_IN_H3D

      REAL,INTENT(INOUT) :: WA4(SWA4),WA4_FVM(AIRBAGS_TOTAL_FVM_IN_H3D)

      TYPE (ELBUF_STRUCT_), INTENT(IN), DIMENSION(NGROUP), TARGET :: ELBUF_TAB

      INTEGER,INTENT(IN) :: MONVOL(SMONVOL)

      my_real,INTENT(IN) :: volmon(svolmon)

      INTEGER,INTENT(INOUT) :: IS_WRITTEN_NODE_FVM(AIRBAGS_TOTAL_FVM_IN_H3D),IS_WRITTEN_NODE(NUMNOD)

      TYPE(fvbag_data),INTENT(IN) :: FVDATA_P(NFVBAG)

C-----------------------------------------------

C   L o c a l   V a r i a b l e s

C-----------------------------------------------

      INTEGER   I, ITYP, NEL, NELv,

     .          J, JJ,

     .        IALEL,NNOD,IPOS,IV,NGv,IDLOCv,J1,J2,IBV

      INTEGER  NG, NBF, NBL, IB, ICELL, NIN, MCELL

      TYPE(g_bufel_)  ,POINTER :: GBUF,GBUFv

      my_real, ALLOCATABLE, DIMENSION(:) :: COUNT_VOL

      my_real V,T

      INTEGER,DIMENSION(:,:), POINTER   :: pAdjBRICK

      INTEGER G_VOL

      INTEGER G_TEMP

C-----------------------------------------------

C   S o u r c e   L i n e s

C-----------------------------------------------


         nnod = nix-3   !8-node brick or 4-node quad


         IF(int22==0)THEN

C------------------------------------------------------------------

C        DEFAULT - ALL ELEMS (HEXA,PENTA, SHELL, QUAD, ..)

C           expand elem temperature to its nodes

C------------------------------------------------------------------

           ALLOCATE(count_vol(numnod))

           count_vol(:) = 0

           DO ng = 1, ngroup

             nel   =iparg(2,ng)

             nft   =iparg(3,ng)

             ityp  =iparg(5,ng)

             ialel =iparg(7,ng)+iparg(11,ng)

             IF(ityp/=1 .AND. ityp/=2)cycle

             !IF(IALEL==0)CYCLE

             gbuf => elbuf_tab(ng)%GBUF

             g_vol=elbuf_tab(ng)%GBUF%G_VOL

             g_temp = elbuf_tab(ng)%GBUF%G_TEMP

             DO i=1,nel

                IF (g_vol > 0 .AND. g_temp > 0)THEN

                  t = gbuf%TEMP(i)

                  v = gbuf%VOL(i)

                ELSE                      ! Volume is not computet with Void properties

                  t=zero

                  v=zero

                ENDIF

                DO j=2,nnod+1

                  jj=ix(j,nft+i)

                  wa4(jj)=wa4(jj)+v*t               !cumulated quantity

                  count_vol(jj) = count_vol(jj) + v !cumulated volume

                  is_written_node(jj)=1

                ENDDO

             ENDDO

           ENDDO

           !applying weight factor

           DO i=1,numnod

             IF(count_vol(i)/=zero)THEN

               wa4(i)=wa4(i)/count_vol(i)

             ENDIF

           ENDDO

           DEALLOCATE(count_vol)


C------------------------------------------------------------------

C        CUT CELLS (INTER TYPE 22)

C------------------------------------------------------------------

         ELSEIF(int22>0)THEN

         !---------------------------------------------------------!

         !         /INTER/TYPE22                                   !

         !---------------------------------------------------------!

         !1. TAG FOR CUT CELLS                                     !

         !2. COMPUTE NODAL TEMPERATURE                             !

         !     NOT INTERSECTED : NODAL T COMPUTED FROM GLOBAL BUF  !

         !         INTERSECTED : NODAL T COMPUTED FROM SUBVOLUME   !

         !---------------------------------------------------------!

           ALLOCATE(count_vol(numnod))

           count_vol = 0

           nbf = 1

           nbl = nb

           nin = 1

           !---1. COMPUTE NODAL PRESSURE---!

           DO ng = 1, ngroup

             nel   =iparg(2,ng)

             nft   =iparg(3,ng)

             ityp  =iparg(5,ng)

             ialel =iparg(7,ng)+iparg(11,ng)

             IF(ityp/=1 .AND. ityp/=2)cycle

             IF(ialel==0)cycle

             gbuf => elbuf_tab(ng)%GBUF

              DO i=1,nel

                ib = nint(gbuf%TAG22(i))

                !---------------------------!

                ! NOT A CUT CELL            !

                !---------------------------!

                IF(ib>0)THEN

                  IF(brick_list(nin,ib)%NBCUT==0)ib=0 !in cut cell buffer but not partitioned (because it is adjacent to a cut cell)

                ENDIF

                IF(ib==0)THEN

                  t = gbuf%TEMP(i)

                  v = gbuf%VOL(i)

                  DO j=2,nnod+1

                    jj=ix(j,nft+i)

                    wa4(jj)=wa4(jj)+ t*v              !cumulated quantity

                    count_vol(jj) = count_vol(jj) + v !cumulated volume

                    is_written_node(jj)=1

                  ENDDO

                !---------------------------!

                !        CUT CELL           !

                !---------------------------!

                ELSE

                  nin   = 1

                  ib    = nint(gbuf%TAG22(i))

                  mcell = brick_list(nin,ib)%MainID

                  nel   = iparg(2,ng)

                  DO j=2,nnod+1

                    jj=ix(j,nft+i)

                    is_written_node(jj)=1

                    icell=brick_list(nin,ib)%NODE(j-1)%WhichCell

                    IF(icell == mcell)THEN

                      t  = gbuf%TEMP(i)

                      v  = gbuf%VOL(i)

                    ELSE

                      padjbrick  => brick_list(nin,ib)%Adjacent_Brick(1:6,1:5)

                      ipos       =  brick_list(nin,ib)%POLY(icell)%WhereIsMain(1)

                      IF(ipos<=nv46)THEN

                        iv     =  brick_list(nin,ib)%Adjacent_Brick(ipos,1)

                        ngv    =  brick_list(nin,ib)%Adjacent_Brick(ipos,2)

                        idlocv =  brick_list(nin,ib)%Adjacent_Brick(ipos,3)

                        nelv   =  iparg(2,ngv)

                      ELSE

                        j1     =  ipos/10

                        j2     =  mod(ipos,10)

                        ibv    =  brick_list(nin,ib )%Adjacent_Brick(j1,4)

                        iv     =  brick_list(nin,ibv)%Adjacent_Brick(j2,1)

                        ngv    =  brick_list(nin,ibv)%Adjacent_Brick(j2,2)

                        idlocv =  brick_list(nin,ibv)%Adjacent_Brick(j2,3)

                        nelv   =  iparg(2,ngv)

                      ENDIF

                      gbufv      => elbuf_tab(ngv)%GBUF

                      t          =  gbufv%TEMP(idlocv)

                      v          =  gbufv%VOL(idlocv)

                    ENDIF

                    wa4(jj)=wa4(jj)+t*v

                    count_vol(jj) = count_vol(jj) + v

                  ENDDO

                ENDIF

              ENDDO

           ENDDO

           !applying weight factor

           DO i=1,numnod

             IF(count_vol(i)/=zero)THEN

               wa4(i)=wa4(i)/count_vol(i)

             ENDIF

           ENDDO

           DEALLOCATE(count_vol)

         ENDIF


C------------------------------------------------------------------

C        /MONVOL/FVMBAG*

C           set temperature from polyhedra centroids

C------------------------------------------------------------------

        IF(nfvbag > 0 .AND. ispmd == 0 .AND. airbags_total_fvm_in_h3d > 0)THEN

          CALL anim_nodal_contour_fvmbags('TEMP', wa4_fvm, monvol , volmon                  , fvdata_p           ,

     .                                    nfvbag, smonvol, svolmon, airbags_total_fvm_in_h3d, is_written_node_fvm,

     .                                    airbags_node_id_shift)


        ENDIF


      RETURN


      END

anim_nodal_contour_fvmbags
subroutine anim_nodal_contour_fvmbags(key, wa4, monvol, volmon, fvdata_p, nfvbag, smonvol, svolmon, airbags_total_fvm, is_written_node_fvm, airbags_node_id_shift)
Definition anim_nodal_contour_fvmbags.F:38

genani
subroutine genani(x, d, v, a, bufel, ixs, ixq, ixc, ixt, ixp, ixr, ixtg, swaft, smas, sxnorm, siad, iparg, pm, geo, ms, sinvert, cont, smater, icut, skew, xcut, fint, itab, sel2fa, fext, fopt, lpby, npby, nstrf, rwbuf, nprw, tani, elbuf_tab, mat_param, dd_iad, weight, eani, ipart, cluster, iparts, ipartq, ipartc, ipartt, ipartp, ipartr, ipartur, iparttg, rby, swa4, tors, nom_opt, igrsurf, bufsf, idata, rdata, siadg, bufmat, bufgeo, kxx, ixx, ipartx, suix, sxusr, snfacptx, sixedge, sixfacet, sixsolid, snumx1, snumx2, snumx3, soffx1, soffx2, soffx3, smass1, smass2, smass3, sfunc1, sfunc2, sfunc3, kxsp, ixsp, nod2sp, ipartsp, spbuf, ixs10, ixs20, ixs16, vr, monvol, volmon, ipm, igeo, nodglob, iad_elem, fr_elem, fr_sec, fr_rby2, iad_rby2, fr_wall, iflow, rflow, fncont, ftcont, temp, thke, err_thk_sh4, err_thk_sh3, diag_sms, ipari, fncont2, dr, ale_connectivity, irbe2, irbe3, lrbe2, lrbe3, fr_rbe2, fr_rbe3m, iad_rbe2, dxancg, nod_pxfem, iel_pxfem, zi_ply, vgaz, fcontg, fncontg, ftcontg, fanreac, inod_crk, iel_crk, elcutc, iadc_crk, pdama2, res_sms, weight_md, nodglobxfe, nodedge, fcluster, mcluster, xfem_tab, w, nv46, ipartig3d, kxig3d, ixig3d, sig3dsolid, knot, wige, nercvois, nesdvois, lercvois, lesdvois, crkedge, indx_crk, xedge4n, xedge3n, stack, sph2sol, stifn, stifr, igrnod, h3d_data, subset, multi_fvm, knotlocpc, knotlocel, fcont_max, fncontp2, ftcontp2, glob_therm, drape_sh4n, drape_sh3n, drapeg, output)
Definition genani.F:240

fvbag_mod
Definition fvbag_mod.F:44

fvbag_mod::nfvbag
integer nfvbag
Definition fvbag_mod.F:127

groupdef_mod
Definition groupdef_mod.F:668

i22bufbric_mod
Definition cut-cell-search_mod.F:95

i22bufbric_mod::brick_list
type(brick_entity), dimension(:,:), allocatable, target brick_list
Definition cut-cell-search_mod.F:105

i22edge_mod
Definition cut-cell-buffer_mod.F:48

i22tri_mod
Definition cut-cell-search_mod.F:212

i22tri_mod::nb
integer nb
Definition cut-cell-search_mod.F:487

initbuf_mod
Definition initbuf.F:160

nodalt
subroutine nodalt(ifunc, wa4, wa4_fvm, iflow, rflow, iparg, elbuf_tab, ix, nix, numel, itab, nv46, monvol, volmon, airbags_total_fvm_in_h3d, is_written_node, is_written_node_fvm, ispmd, fvdata_p, swa4, airbags_node_id_shift)
Definition nodalt.F:44

fvbag_mod::fvbag_data
Definition fvbag_mod.F:52

groupdef_mod::group_
Definition groupdef_mod.F:706