pchetdrv.f

Go to the documentation of this file.

      SUBROUTINE pchetdrv( UPLO, N, A, IA, JA, DESCA, D, E, TAU, WORK,
     $                     INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               D( * ), E( * )
      COMPLEX            A( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCHETDRV computes sub( A ) = A(IA:IA+N-1,JA:JA+N-1) from Q, the
*  Hermitian tridiagonal matrix T (or D and E), and TAU, which were
*  computed by PCHETRD:  sub( A ) := Q * T * Q'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          Hermitian matrix sub( A ) is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          This array contains the local pieces of sub( A ). On entry,
*          if UPLO='U', the diagonal and first superdiagonal of sub( A )
*          have the corresponding elements of the tridiagonal matrix T,
*          and the elements above the first superdiagonal, with the
*          array TAU, represent the unitary matrix Q as a product of
*          elementary reflectors, and the strictly lower triangular part
*          of sub( A ) is not referenced. If UPLO='L', the diagonal and
*          first subdiagonal of sub( A ) have the corresponding elements
*          of the tridiagonal matrix T, and the elements below the first
*          subdiagonal, with the array TAU, represent the unitary
*          matrix Q as a product of elementary reflectors, and the
*          strictly upper triangular part of sub( A ) is not referenced.
*          On exit, if UPLO = 'U', the upper triangular part of the
*          distributed Hermitian matrix sub( A ) is recovered.
*          If UPLO='L', the lower triangular part of the distributed
*          Hermitian matrix sub( A ) is recovered.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local input) REAL array, dimension LOCc(JA+N-1)
*          The diagonal elements of the tridiagonal matrix T:
*          D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local input) REAL array, dimension LOCc(JA+N-1)
*          if UPLO = 'U', LOCc(JA+N-2) otherwise. The off-diagonal
*          elements of the tridiagonal matrix T: E(i) = A(i,i+1) if
*          UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. E is tied to the
*          distributed matrix A.
*
*  TAU     (local input) COMPLEX, array, dimension
*          LOCc(JA+N-1). This array contains the scalar factors TAU of
*          the elementary reflectors. TAU is tied to the distributed
*          matrix A.
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK)
*          LWORK >= 2 * NB *( NB + NP )
*
*          where NB = MB_A = NB_A,
*          NP = NUMROC( N, NB, MYROW, IAROW, NPROW ),
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, a discrepancy has been found between
*          the diagonal and off-diagonal elements of A and the copies
*          contained in the arrays D and E.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               REIGHT, RONE, RZERO
      parameter( reight = 8.0e+0, rone = 1.0e+0,
     $                     rzero = 0.0e+0 )
      COMPLEX              HALF, ONE, ZERO
      parameter( half = ( 0.5e+0, 0.0e+0 ),
     $                     one = ( 1.0e+0, 0.0e+0 ),
     $                     zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IACOL, IAROW, ICTXT, II, IPT, IPV, IPX,
     $                   ipy, j, jb, jj, jl, k, mycol, myrow, nb, np,
     $                   npcol, nprow
      REAL               ADDBND, D2, E2
      COMPLEX            D1, E1
*     ..
*     .. Local Arrays ..
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ ), DESCV( DLEN_ ),
     $                   desct( dlen_ )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2P, NUMROC
      REAL               PSLAMCH
      EXTERNAL           indxg2p, lsame, numroc, pslamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, igsum2d,
     $                   pcelget, pcgemm, pchemm,
     $                   pcher2k, pclacpy, pclarft,
     $                   pclaset, pctrmm, pselget
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, max, min, mod
*     ..
*     .. Executable statements ..
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      info = 0
      nb = desca( mb_ )
      upper = lsame( uplo, 'U' )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
      np = numroc( n, nb, myrow, iarow, nprow )
*
      ipt = 1
      ipv = nb * nb + ipt
      ipx = nb * np + ipv
      ipy = nb * np + ipx
*
      CALL descset( descd, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $              desca( csrc_ ), desca( ctxt_ ), 1 )
*
      addbnd = reight * pslamch( ictxt, 'eps' )
*
      IF( upper ) THEN
*
         CALL descset( desce, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
         DO 10 j = 0, n-1
            d1 = zero
            e1 = zero
            d2 = rzero
            e2 = rzero
            CALL pselget( ' ', ' ', d2, d, 1, ja+j, descd )
            CALL pcelget( 'Columnwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(n-1) ) THEN
               CALL pselget( ' ', ' ', e2, e, 1, ja+j+1, desce )
               CALL pcelget( 'Columnwise', ' ', e1, a, ia+j, ja+j+1,
     $                       desca )
            END IF
*
            IF( ( abs( d1 - cmplx( d2 ) ).GT.( abs( d2 )*addbnd ) ) .OR.
     $          ( abs( e1 - cmplx( e2 ) ).GT.( abs( e2 )*addbnd ) ) )
     $         info = info + 1
   10    CONTINUE
*
*        Compute the upper triangle of sub( A ).
*
         CALL descset( descv, n, nb, nb, nb, iarow, iacol, ictxt,
     $                 max( 1, np ) )
         CALL descset( desct, nb, nb, nb, nb, iarow, iacol, ictxt, nb )
*
         DO 20 k = 0, n-1, nb
            jb = min( nb, n-k )
            i = ia + k
            j = ja + k
*
*           Compute the lower triangular matrix T.
*
            CALL pclarft( 'Backward', 'Columnwise', k+jb-1, jb, a, ia,
     $                    j, desca, tau, work( ipt ), work( ipv ) )
*
*           Copy Householder vectors into WORK( IPV ).
*
            CALL pclacpy( 'All', k+jb-1, jb, a, ia, j, desca,
     $                    work( ipv ), 1, 1, descv )
*
            IF( k.GT.0 ) THEN
               CALL pclaset( 'Lower', jb+1, jb, zero, one, work( ipv ),
     $                       k, 1, descv )
            ELSE
               CALL pclaset( 'Lower', jb, jb-1, zero, one, work( ipv ),
     $                       1, 2, descv )
               CALL pclaset( 'Ge', jb, 1, zero, zero, work( ipv ), 1,
     $                       1, descv )
            END IF
*
*           Zero out the strict upper triangular part of A.
*
            IF( k.GT.0 ) THEN
               CALL pclaset( 'Ge', k-1, jb, zero, zero, a, ia, j,
     $                       desca )
               CALL pclaset( 'Upper', jb-1, jb-1, zero, zero, a, i-1,
     $                       j+1, desca )
            ELSE IF( jb.GT.1 ) THEN
               CALL pclaset( 'Upper', jb-2, jb-2, zero, zero, a, ia,
     $                       j+2, desca )
            END IF
*
*           (1) X := A * V * T'
*
            CALL pchemm( 'Left', 'Upper', k+jb, jb, one, a, ia, ja,
     $                   desca, work( ipv ), 1, 1, descv, zero,
     $                   work( ipx ), 1, 1, descv )
            CALL pctrmm( 'Right', 'Lower', 'conjugate transpose',
     $                   'non-unit', K+JB, JB, ONE, WORK( IPT ), 1, 1,
     $                   DESCT, WORK( IPX ), 1, 1, DESCV )
*
*           (2) X := X - 1/2 * V * (T * V' * X)
*
            CALL PCGEMM( 'conjugate transpose', 'no transpose', jb, jb,
     $                   k+jb, one, work( ipv ), 1, 1, descv,
     $                   work( ipx ), 1, 1, descv, zero, work( ipy ),
     $                   1, 1, desct )
            CALL pctrmm( 'Left', 'Lower', 'No transpose', 'Non-Unit',
     $                   jb, jb, one, work( ipt ), 1, 1, desct,
     $                   work( ipy ), 1, 1, desct )
            CALL pcgemm( 'No tranpose', 'No transpose', k+jb, jb, jb,
     $                   -half, work( ipv ), 1, 1, descv, work( ipy ),
     $                   1, 1, desct, one, work( ipx ), 1, 1, descv )
*
*           (3) A := A - X * V' - V * X'
*
            CALL pcher2k( 'Upper', 'No transpose', k+jb, jb, -one,
     $                    work( ipv ), 1, 1, descv, work( ipx ), 1, 1,
     $                    descv, rone, a, ia, ja, desca )
*
            descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
            desct( csrc_ ) = mod( desct( csrc_ ) + 1, npcol )
*
   20    CONTINUE
*
      ELSE
*
         CALL descset( desce, 1, ja+n-2, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
         DO 30 j = 0, n-1
            d1 = zero
            e1 = zero
            d2 = rzero
            e2 = rzero
            CALL pselget( ' ', ' ', d2, d, 1, ja+j, descd )
            CALL pcelget( 'Columnwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(n-1) ) THEN
               CALL pselget( ' ', ' ', e2, e, 1, ja+j, desce )
               CALL pcelget( 'columnwise', ' ', E1, A, IA+J+1, JA+J,
     $                       DESCA )
            END IF
*
.GT..OR.            IF( ( ABS( D1 - CMPLX( D2 ) )( ABS( D2 )*ADDBND ) ) 
.GT.     $          ( ABS( E1 - CMPLX( E2 ) )( ABS( E2 )*ADDBND ) ) )
     $         INFO = INFO + 1
   30    CONTINUE
*
*        Compute the lower triangle of sub( A ).
*
         JL = MAX( ( ( JA+N-2 ) / NB ) * NB + 1, JA )
         IACOL = INDXG2P( JL, NB, MYCOL, DESCA( CSRC_ ), NPCOL )
         CALL DESCSET( DESCV, N, NB, NB, NB, IAROW, IACOL, ICTXT,
     $                 MAX( 1, NP ) )
         CALL DESCSET( DESCT, NB, NB, NB, NB, INDXG2P( IA+JL-JA+1, NB,
     $                 MYROW, DESCA( RSRC_ ), NPROW ), IACOL, ICTXT,
     $                 NB )
*
         DO 40 J = JL, JA, -NB
            K  = J - JA + 1
            I  = IA + K - 1
            JB = MIN( N-K+1, NB )
*
*           Compute upper triangular matrix T from TAU.
*
            CALL PCLARFT( 'forward', 'columnwise', N-K, JB, A, I+1, J,
     $                    DESCA, TAU, WORK( IPT ), WORK( IPV ) )
*
*           Copy Householder vectors into WORK( IPV ).
*
            CALL PCLACPY( 'lower', N-K, JB, A, I+1, J, DESCA,
     $                    WORK( IPV ), K+1, 1, DESCV )
            CALL PCLASET( 'upper', N-K, JB, ZERO, ONE, WORK( IPV ),
     $                    K+1, 1, DESCV )
            CALL PCLASET( 'ge', 1, JB, ZERO, ZERO, WORK( IPV ), K, 1,
     $                    DESCV )
*
*           Zero out the strict lower triangular part of A.
*
            CALL PCLASET( 'lower', N-K-1, JB, ZERO, ZERO, A, I+2, J,
     $                    DESCA )
*
*           (1) X := A * V * T'
*
            CALL PCHEMM( 'left', 'lower', N-K+1, JB, ONE, A, I, J,
     $                   DESCA, WORK( IPV ), K, 1, DESCV, ZERO,
     $                   WORK( IPX ), K, 1, DESCV )
            CALL PCTRMM( 'right', 'upper', 'conjugate transpose',
     $                   'non-unit', N-K+1, JB, ONE, WORK( IPT ), 1, 1,
     $                   DESCT, WORK( IPX ), K, 1, DESCV )
*
*           (2) X := X - 1/2 * V * (T * V' * X)
*
            CALL PCGEMM( 'conjugate transpose', 'no transpose', JB, JB,
     $                   N-K+1, ONE, WORK( IPV ), K, 1, DESCV,
     $                   WORK( IPX ), K, 1, DESCV, ZERO, WORK( IPY ),
     $                   1, 1, DESCT )
            CALL PCTRMM( 'left', 'upper', 'no transpose', 'non-unit',
     $                   JB, JB, ONE, WORK( IPT ), 1, 1, DESCT,
     $                   WORK( IPY ), 1, 1, DESCT )
            CALL PCGEMM( 'no transpose', 'no transpose', N-K+1, JB, JB,
     $                   -HALF, WORK( IPV ), K, 1, DESCV, WORK( IPY ),
     $                   1, 1, DESCT, ONE, WORK( IPX ), K, 1, DESCV )
*
*           (3) A := A - X * V' - V * X'
*
            CALL PCHER2K( 'lower', 'no tranpose', N-K+1, JB, -ONE,
     $                    WORK( IPV ), K, 1, DESCV, WORK( IPX ), K, 1,
     $                    DESCV, RONE, A, I, J, DESCA )
*
            DESCV( CSRC_ ) = MOD( DESCV( CSRC_ ) + NPCOL - 1, NPCOL )
            DESCT( RSRC_ ) = MOD( DESCT( RSRC_ ) + NPROW - 1, NPROW )
            DESCT( CSRC_ ) = MOD( DESCT( CSRC_ ) + NPCOL - 1, NPCOL )
*
   40    CONTINUE
*
      END IF
*
      CALL IGSUM2D( ICTXT, 'all', ' ', 1, 1, INFO, 1, -1, 0 )
*
      RETURN
*
*     End of PCHETDRV
*
      END