pcoork3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    pcoork3   ../engine/source/elements/beam/pcoork3.F
!||--- called by ------------------------------------------------------
!||    pke3      ../engine/source/elements/beam/pke3.F
!||====================================================================
      SUBROUTINE pcoork3(JFT    ,JLT    ,X      ,NCC   ,OFFG  ,
     2                   PID    ,MAT    ,NGL    ,AL    ,ALI   , 
     3                   ALS    ,ISMSTR ,R11    ,R12   ,R13   ,
     4                   R21    ,R22    ,R23    ,R31   ,R32   ,
     5                   R33    ,RLOC   ,OFF    )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT ,ISMSTR
      INTEGER NCC(6,*),PID(*),MAT(*),NGL(*)
      my_real
     .   X(3,*),OFFG(*),AL(*),ALI(*),ALS(*),
     .   r11(*),r12(*),r13(*),
     .   r21(*),r22(*),r23(*),
     .   r31(*),r32(*),r33(*),rloc(3,*),off(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I, NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ)
      my_real :: X1(MVSIZ), X2(MVSIZ), X3(MVSIZ),
     .           Y1(MVSIZ), Y2(MVSIZ), Y3(MVSIZ),
     .           Z1(MVSIZ), Z2(MVSIZ), Z3(MVSIZ),NORM
C-----------------------------------------------
      DO i=jft, jlt
       mat(i)=ncc(1,i)
       pid(i)=ncc(5,i)
       ngl(i)=ncc(6,i)
       nc1(i)=ncc(2,i)
       nc2(i)=ncc(3,i)
       nc3(i)=ncc(4,i)
      ENDDO 
C----------------------------
C     COORDONNEES
C----------------------------
      DO i=jft, jlt
       x1(i)=x(1,nc1(i))
       y1(i)=x(2,nc1(i))
       z1(i)=x(3,nc1(i))
       x2(i)=x(1,nc2(i))
       y2(i)=x(2,nc2(i))
       z2(i)=x(3,nc2(i))
       x3(i)=x(1,nc3(i))
       y3(i)=x(2,nc3(i))
       z3(i)=x(3,nc3(i))
      ENDDO 
C----------------------------
C     LOCAL SYSTEM
C----------------------------
      DO  i=jft, jlt
       r12(i)=rloc(1,i)
       r22(i)=rloc(2,i)
       r32(i)=rloc(3,i)
       r11(i)=x2(i)-x1(i)
       r21(i)=y2(i)-y1(i)
       r31(i)=z2(i)-z1(i)
      ENDDO 
C
      IF (ismstr/=0) THEN
       DO  i=jft, jlt
        al(i)=als(i)
       ENDDO
      ELSE 
       DO  i=jft, jlt
        al(i)=sqrt(r11(i)*r11(i)+r21(i)*r21(i)+r31(i)*r31(i))
       ENDDO
      ENDIF 
      DO  i=jft, jlt
       IF (al(i)<em20) offg(i)=zero
       ali(i)=one/max(em20,al(i))
      ENDDO 
C
      DO i=jft, jlt
       r11(i)=r11(i)*ali(i)
       r21(i)=r21(i)*ali(i)
       r31(i)=r31(i)*ali(i)
      ENDDO 
      DO i=jft, jlt
       r13(i)=r21(i)*r32(i)-r31(i)*r22(i)
       r23(i)=r31(i)*r12(i)-r11(i)*r32(i)
       r33(i)=r11(i)*r22(i)-r21(i)*r12(i)
      ENDDO 
C
      DO i=jft, jlt
       norm=sqrt(r13(i)*r13(i)+r23(i)*r23(i)+r33(i)*r33(i))
       r13(i)=r13(i)/norm
       r23(i)=r23(i)/norm
       r33(i)=r33(i)/norm
      ENDDO 
      DO i=jft, jlt
       r12(i)=r23(i)*r31(i)-r33(i)*r21(i)
       r22(i)=r33(i)*r11(i)-r13(i)*r31(i)
       r32(i)=r13(i)*r21(i)-r23(i)*r11(i)
      ENDDO 
C
      DO i=jft,jlt
       off(i)=offg(i)
      ENDDO
C
      RETURN
      END