pdsepdriver.f

Go to the documentation of this file.

*
*
      PROGRAM pdsepdriver
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     Parallel DOUBLE PRECISION symmetric eigenproblem test driver
*
*     The user should modify TOTMEM to indicate the maximum amount of
*     memory in bytes her system has.  Remember to leave room in memory
*     for operating system, the BLACS buffer, etc.  INTSIZ and DBLSIZ
*     indicate the length in bytes on the given platform for an integer
*     and a double precision real.
*     For example, on our system with 8 MB of memory, TOTMEM=6500000
*     (leaves 1.5 MB for OS, code, BLACS buffer, etc), the length of a
*     DOUBLE is 8, and an integer takes up 4 bytes.  Some playing around
*     to discover what the maximum value you can set MEMSIZ to may be
*     required.
*     All arrays used by factorization and solve are allocated out of
*     big array called MEM.
*
*     The full tester requires approximately (5 n + 5 n^2/p + slop)
*     DOUBLE PRECISION words and 6*n integer words.
*     So, TOTMEM should be set to at least 1.1 * 8 * (5n + 5n^2/p)
*
*     WHAT WE TEST
*     ============
*
*     This routine tests PDSYEVX, the expert driver for the parallel
*     symmetric eigenvalue problem, PDSYEV and PDSYEVD.  We would like 
*     to cover all possible combinations of:  matrix size, process 
*     configuration (nprow and npcol), block size (nb), 
*     matrix type (??), range of eigenvalue (all, by value, 
*     by position), sorting options, and upper vs. lower storage.
*
*     As PDSYEV returns an error message when heterogeneity is detected,
*     the PDSYEV tests can be suppressed by changing the appropiate
*     entry in the input file.
*
*     We intend to provide two types of test input files, an
*     installation test and a thorough test.
*
*     We also intend that the reports be meaningful.  Our input file
*     will allow multiple requests where each request is a cross product
*     of the following sets:
*       matrix sizes:                     n
*       process configuration triples:  nprow, npcol, nb
*       matrix types:
*       eigenvalue requests:              all, by value, by position
*       storage (upper vs. lower):        uplo
*
*     TERMS:
*       Request - means a set of tests, which is the cross product of
*       a set of specifications from the input file.
*       Test - one element in the cross product, i.e. a specific input
*       size and type, process configuration, etc.
*
*     .. Parameters ..
*
      INTEGER            totmem, dblesz, nin
      parameter( totmem = 2000000, dblesz = 8, nin = 11 )
      INTEGER            memsiz
      parameter( memsiz = totmem / dblesz )
*     ..
*     .. Local Scalars ..
      CHARACTER          hetero
      CHARACTER*80       summry, usrinfo
      INTEGER            context, iam, info, isieee, maxnodes, nnocheck,
     $                   nout, npassed, nprocs, nskipped, ntests
*     ..
*     .. Local Arrays ..
*
      INTEGER            iseed( 4 )
      DOUBLE PRECISION   mem( memsiz )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
*
      EXTERNAL           blacs_exit, blacs_get, blacs_gridexit, 
     $                   blacs_gridinit, blacs_pinfo, blacs_setup, 
     $                   igamn2d, pdlachkieee, pdlasnbt, pdsepreq 
*     ..
*     .. Executable Statements ..
*
*     Get starting information
*
      CALL blacs_pinfo( iam, nprocs )
*
*
      IF( iam.EQ.0 ) THEN
*
*        Open file and skip data file header
*
         OPEN( unit = nin, file = 'SEP.dat', status = 'OLD' )
         READ( nin, fmt = * )summry
         summry = ' '
*
*        Read in user-supplied info about machine type, compiler, etc.
*
         READ( nin, fmt = 9999 )usrinfo
*
*        Read name and unit number for summary output file
*
         READ( nin, fmt = * )summry
         READ( nin, fmt = * )nout
         IF( nout.NE.0 .AND. nout.NE.6 )
     $      OPEN( nout, file = summry, status = 'UNKNOWN' )
         READ( nin, fmt = * )maxnodes
         READ( nin, fmt = * )hetero
      END IF
*
      IF( nprocs.LT.1 ) THEN
         CALL blacs_setup( iam, maxnodes )
         nprocs = maxnodes
      END IF
*
      CALL blacs_get( -1, 0, context )
      CALL blacs_gridinit( context, 'R', 1, nprocs )
*
      CALL pdlasnbt( isieee )
*
      CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $              0 )
*
      IF( ( isieee.NE.0 ) ) THEN
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9998 )
            WRITE( nout, fmt = 9997 )
            WRITE( nout, fmt = 9996 )
            WRITE( nout, fmt = 9995 )
            WRITE( nout, fmt = 9994 )
            WRITE( nout, fmt = 9993 )
            WRITE( nout, fmt = 9992 )
            WRITE( nout, fmt = 9991 )
            WRITE( nout, fmt = 9990 )
         END IF
*
         CALL pdlachkieee( isieee, dlamch( 'O' ), dlamch( 'U' ) )
*
         CALL igamn2d( context, 'a', ' ', 1, 1, isieee, 1, 1, 1, -1, -1,
     $                 0 )
*
         IF( isieee.EQ.0 ) THEN
            IF( iam.EQ.0 ) THEN
               WRITE( nout, fmt = 9989 )
               WRITE( nout, fmt = 9988 )
               WRITE( nout, fmt = 9987 )
            END IF
            GO TO 20
         END IF
*
         IF( iam.EQ.0 ) THEN
            WRITE( nout, fmt = 9986 )
         END IF
*
      END IF
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9999 )
     $      'SCALAPACK symmetric Eigendecomposition routines.'
         WRITE( nout, fmt = 9999 )usrinfo
         WRITE( nout, fmt = 9999 )' '
         WRITE( NOUT, FMT = 9999 )'running tests of the parallel ' //
     $      'symmetric eigenvalue routine:  pdsyevx & '//
     $       ' pdsyev & pdsyevd.'
         WRITE( NOUT, FMT = 9999 )'the following scaled residual ' //
     $      'checks will be computed:'
         WRITE( NOUT, FMT = 9999 )' ||aq - ql|| ' //
     $      '/ ((abstol + ||a|| * eps) * n)'
         WRITE( NOUT, FMT = 9999 )' ||q^t*q - i|| ' // '/ (n * eps)'
         WRITE( NOUT, FMT = 9999 )
         WRITE( NOUT, FMT = 9999 )'an explanation of the ' //
     $      'input/output parameters follows:'
         WRITE( NOUT, FMT = 9999 )'result   : passed; or ' //
     $      'an indication of which eigen request test failed'
         WRITE( NOUT, FMT = 9999 )
     $      'n        : the number of rows and columns ' //
     $      'of the matrix a.'
         WRITE( NOUT, FMT = 9999 )
     $      'p        : the number of process rows.'
         WRITE( NOUT, FMT = 9999 )
     $      'q        : the number of process columns.'
         WRITE( NOUT, FMT = 9999 )
     $      'nb       : the size of the square blocks' //
     $      ' the matrix a is split into.'
         WRITE( NOUT, FMT = 9999 )
     $      'thresh   : If a residual value is less ' //
     $      'than thresh, result is flagged as passed.'
         WRITE( NOUT, FMT = 9999 )
     $      '         : the qtq norm is allowed to exceed thresh' //
     $      ' for those eigenvectors'
         WRITE( NOUT, FMT = 9999 )'         :  which could not be ' //
     $      'reorthogonalized for lack of workspace.'
         WRITE( nout, fmt = 9999 )
     $      'TYP      : matrix type (see PDSEPtst.f).'
         WRITE( nout, fmt = 9999 )'SUB      : Subtests ' //
     $      '(see PDSEPtst).f'
         WRITE( nout, fmt = 9999 )'CHK      : ||AQ - QL|| ' //
     $      '/ ((abstol + ||A|| * eps) * N)'
         WRITE( nout, fmt = 9999 )'QTQ      : ||Q^T*Q - I||/ (N * eps)'
         WRITE( nout, fmt = 9999 )
     $      '         : when the adjusted QTQ exceeds THRESH',
     $      ' the adjusted QTQ norm is printed'
         WRITE( nout, fmt = 9999 )
     $      '         : otherwise the true QTQ norm is printed'
         WRITE( nout, fmt = 9999 )
     $      '           If NT>1, CHK and QTQ are the max over all ' //
     $      'eigen request tests'
         WRITE( nout, fmt = 9999 )
     $      'TEST     : EVX - testing PDSYEVX, EV - testing PDSYEV, '//
     $        'EVD - testing PDSYEVD'
         WRITE( nout, fmt = 9999 )' '
      END IF
*
      ntests = 0
      npassed = 0
      nskipped = 0
      nnocheck = 0
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9979 )
         WRITE( nout, fmt = 9978 )
      END IF
*
   10 CONTINUE
*
      iseed( 1 ) = 139
      iseed( 2 ) = 1139
      iseed( 3 ) = 2139
      iseed( 4 ) = 3139
*
      CALL pdsepreq( hetero, nin, mem, memsiz, nout, iseed, ntests,
     $               nskipped, nnocheck, npassed, info )
      IF( info.EQ.0 )
     $   GO TO 10
*
      IF( iam.EQ.0 ) THEN
         WRITE( nout, fmt = 9985 )ntests
         WRITE( nout, fmt = 9984 )npassed
         WRITE( nout, fmt = 9983 )nnocheck
         WRITE( nout, fmt = 9982 )nskipped
         WRITE( nout, fmt = 9981 )ntests - npassed - nskipped -
     $      nnocheck
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = * )
         WRITE( nout, fmt = 9980 )
      END IF
*
*     Uncomment this line on SUN systems to avoid the useless print out
*
c      CALL IEEE_FLAGS( 'clear', 'exception', 'underflow', ' ')
*
*
*
   20 CONTINUE
      IF( iam.EQ.0 ) THEN
         CLOSE ( nin )
         IF( nout.NE.6 .AND. nout.NE.0 )
     $      CLOSE ( nout )
      END IF
*
      CALL blacs_gridexit( context )
*
      CALL blacs_exit( 0 )
      stop
*
*
 9999 FORMAT( a )
 9998 FORMAT( ' I am about to check to make sure that overflow' )
 9997 FORMAT( ' is handled in the ieee default manner.  If this' )
 9996 FORMAT( ' is the last output you see, you should assume' )
 9995 FORMAT( ' that overflow caused a floating point exception.' )
 9994 FORMAT( ' In that case, we recommend that you add -DNO_IEEE' )
 9993 FORMAT( ' to the CDEFS line in SLmake.inc.' )
 9992 FORMAT( ' Alternatively, you could set CDEFS in SLmake.inc ' )
 9991 FORMAT( ' to enable the default ieee behaviour, However, this' )
 9990 FORMAT( ' may result in good or very bad performance.' )
 9989 FORMAT( ' Either signed zeroes or signed infinities ' )
 9988 FORMAT( ' work incorrectly or your system.  Change your' )
 9987 FORMAT( ' SLmake.inc as suggested above.' )
*
 9986 FORMAT( ' Your system appears to handle ieee overflow.' )
*
 9985 FORMAT( 'Finished ', i6, ' tests, with the following results:' )
 9984 FORMAT( i5, ' tests completed and passed residual checks.' )
 9983 FORMAT( i5, ' tests completed without checking.' )
 9982 FORMAT( i5, ' tests skipped for lack of memory.' )
 9981 FORMAT( i5, ' tests completed and failed.' )
 9980 FORMAT( 'END OF TESTS.' )
 9979 FORMAT( '     N  NB   P   Q TYP SUB   WALL      CPU  ',
     $      '    CHK       QTQ    CHECK    TEST' )
 9978 FORMAT( ' ----- --- --- --- --- --- -------- --------',
     $      ' --------- --------- -----    ----' )
*
*     End of PDSEPDRIVER
*
      END