pevec3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    pevec3   ../engine/source/elements/beam/pevec3.F
!||--- called by ------------------------------------------------------
!||    pforc3   ../engine/source/elements/beam/pforc3.F
!||====================================================================
      SUBROUTINE pevec3(
     1   RLOC,    R,       AL,      NC1,
     2   NC2,     NC3,     X1,      X2,
     3   X3,      Y1,      Y2,      Y3,
     4   Z1,      Z2,      Z3,      RX1G,
     5   RX2G,    RY1G,    RY2G,    RZ1G,
     6   RZ2G,    E1X,     E1Y,     E1Z,
     7   E2X,     E2Y,     E2Z,     E3X,
     8   E3Y,     E3Z,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(MVSIZ), NC2(MVSIZ), NC3(MVSIZ)
      my_real
     .   RLOC(3,*),R(3,*),AL(*),X1(MVSIZ),X2(MVSIZ),X3(MVSIZ),
     .   Y1(MVSIZ),Y2(MVSIZ),Y3(MVSIZ),Z1(MVSIZ),Z2(MVSIZ),
     .   Z3(MVSIZ),RX1G(MVSIZ),RX2G(MVSIZ),RY1G(MVSIZ),RY2G(MVSIZ),
     . RZ1G(MVSIZ),RZ2G(MVSIZ),RX1(MVSIZ),RX2(MVSIZ),
     . E1X(MVSIZ),E1Y(MVSIZ),E1Z(MVSIZ),E2X(MVSIZ),
     .   e2y(mvsiz),e2z(mvsiz),e3x(mvsiz),e3y(mvsiz),e3z(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   SUM(MVSIZ), 
     .   THETA, SUM2(MVSIZ), SUM3(MVSIZ), COST(MVSIZ),
     . SINT(MVSIZ)
C--------------------------------------------
      DO I=1,nel
        rx1g(i)=r(1,nc1(i))
        ry1g(i)=r(2,nc1(i))
        rz1g(i)=r(3,nc1(i))
        rx2g(i)=r(1,nc2(i))
        ry2g(i)=r(2,nc2(i))
        rz2g(i)=r(3,nc2(i))
      ENDDO
C
      DO i=1,nel
        e2x(i)=rloc(1,i)
        e2y(i)=rloc(2,i)
        e2z(i)=rloc(3,i)
      ENDDO
C
      DO i=1,nel
        e1x(i)=x2(i)-x1(i)
        e1y(i)=y2(i)-y1(i)
        e1z(i)=z2(i)-z1(i)
      ENDDO
C
      DO i=1,nel
        al(i)=sqrt(e1x(i)**2+e1y(i)**2+e1z(i)**2)
      ENDDO
C
      DO i=1,nel
        e1x(i)=e1x(i)/al(i)
        e1y(i)=e1y(i)/al(i)
        e1z(i)=e1z(i)/al(i)
      ENDDO
C
      DO i=1,nel
        e3x(i)=e1y(i)*e2z(i)-e1z(i)*e2y(i)
        e3y(i)=e1z(i)*e2x(i)-e1x(i)*e2z(i)
        e3z(i)=e1x(i)*e2y(i)-e1y(i)*e2x(i)
      ENDDO
C
      DO i=1,nel
        e2x(i)=e3y(i)*e1z(i)-e3z(i)*e1y(i)
        e2y(i)=e3z(i)*e1x(i)-e3x(i)*e1z(i)
        e2z(i)=e3x(i)*e1y(i)-e3y(i)*e1x(i)
      ENDDO
C--------------------------------------------
C     TORSION MOYENNE EN COORDONNEES GLOBALES
C--------------------------------------------
      DO i=1,nel
        rx1(i)=e1x(i)*rx1g(i)+e1y(i)*ry1g(i)+e1z(i)*rz1g(i)
        rx2(i)=e1x(i)*rx2g(i)+e1y(i)*ry2g(i)+e1z(i)*rz2g(i)
        theta=(rx1(i)+rx2(i))/two*dt1
        sum2(i)=sqrt(e2x(i)**2+e2y(i)**2+e2z(i)**2)
        sum3(i)=sqrt(e3x(i)**2+e3y(i)**2+e3z(i)**2)
        cost(i)=cos(theta)/sum2(i)
        sint(i) =sin(theta)/sum3(i)
      ENDDO
C
C ... it is modified.
C
      DO i=1,nel
        e2x(i)=e2x(i)*cost(i)+e3x(i)*sint(i)
        e2y(i)=e2y(i)*cost(i)+e3y(i)*sint(i)
        e2z(i)=e2z(i)*cost(i)+e3z(i)*sint(i)
      ENDDO
C
      DO i=1,nel
        sum(i)=sqrt(e2x(i)**2+e2y(i)**2+e2z(i)**2)
      ENDDO
C
      DO i=1,nel
        e2x(i)=e2x(i)/sum(i)
        e2y(i)=e2y(i)/sum(i)
        e2z(i)=e2z(i)/sum(i)
      ENDDO
C
      DO i=1,nel
        e3x(i)=e1y(i)*e2z(i)-e1z(i)*e2y(i)
        e3y(i)=e1z(i)*e2x(i)-e1x(i)*e2z(i)
        e3z(i)=e1x(i)*e2y(i)-e1y(i)*e2x(i)
      ENDDO
C
      DO i=1,nel
        sum(i)=sqrt(e3x(i)**2+e3y(i)**2+e3z(i)**2)
        e3x(i)=e3x(i)/sum(i)
        e3y(i)=e3y(i)/sum(i)
        e3z(i)=e3z(i)/sum(i)
      ENDDO
C
      DO i=1,nel
        rloc(1,i)=e2x(i)
        rloc(2,i)=e2y(i)
        rloc(3,i)=e2z(i)
      ENDDO
C--------------------------------------------
      RETURN
      END