pretag_xfem.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    pretag_xfem   ../starter/source/elements/xfem/pretag_xfem.F
!||--- called by ------------------------------------------------------
!||    lectur        ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    tag_sh        ../starter/source/elements/xfem/pretag_xfem.F
!||====================================================================
      SUBROUTINE pretag_xfem(IPARG  ,ITAGE   ,IEL_CRKXFEM,ITAGN  ,INOD_CRKXFEM)
C-----------------------------------------------
c     numerotation locale des noeuds et elems fantomes des parts xfem
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c K s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com_xfem1.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPARG(NPARG,NGROUP)
      INTEGER , DIMENSION(NUMNOD) :: ITAGN, INOD_CRKXFEM
      INTEGER , DIMENSION(NUMELC+NUMELTG) :: ITAGE, IEL_CRKXFEM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,K,NG,NEL,IXFEM,NFT,ITY,LFT,LLT,ITG,IGTYP,ICRK_ALL(2)
C=======================================================================
      itg = 1 + numelc
C
      ncrkxfe = 0   ! local par proc 
      DO i=1,numnod
        IF(itagn(i) > 0)THEN
          ncrkxfe = ncrkxfe + 1
          inod_crkxfem(i) = ncrkxfe
        ENDIF
      ENDDO
C
      icrk_all(1:2) = 0
      ecrkxfe = 0             ! local par proc, toutes les coques
c
      DO ng=1,ngroup
        ixfem=iparg(54,ng)
        IF (ixfem == 0) cycle
c
        nel  =iparg(2,ng)
        nft  =iparg(3,ng)
        ity  =iparg(5,ng)
        igtyp=iparg(38,ng)
        lft  =1
        llt  =min(nvsiz,nel)
        nxlaymax = max(nxlaymax, iparg(59,ng)) ! Max Xfem layers, for alloc
c
c---    Fill xfem elements table : IEL_CRKXFEM(NUMELC+NUMELTG) = sys numbers
c
        IF (ity==3) THEN
          CALL tag_sh(itage     ,iel_crkxfem     ,ecrkxfe,
     .                lft       ,llt             ,nft     )
        ELSE IF (ity==7) THEN
          CALL tag_sh(itage(itg),iel_crkxfem(itg),ecrkxfe,
     .                lft       ,llt             ,nft      )
        END IF
C
        IF (igtyp == 11 .AND. ixfem == 1) THEN
          icrk_all(1) = icrk_all(1) + 1
        ELSEIF (igtyp == 1 .AND. ixfem == 2) THEN
          icrk_all(2) = icrk_all(2) + 1
        END IF
      ENDDO
C
      IF (icrk_all(2) > 0) THEN
        icrack3d = icrack3d + 1
        IF (icrk_all(1) > 0) icrack3d = icrack3d + 1
      ENDIF
C---  Count Xfem elements
      ecrkxfec = 0            ! local par proc, coques 4N  
      ecrkxfetg= 0            ! local par proc, coques 3N  
      DO i=1,numelc
        IF (iel_crkxfem(i) > 0)        ecrkxfec  = ecrkxfec + 1
      END DO
      DO i=1,numeltg
        IF (iel_crkxfem(i+numelc) > 0) ecrkxfetg = ecrkxfetg + 1
      END DO
C-----------
      RETURN
      END
c
!||====================================================================
!||    tag_sh        ../starter/source/elements/xfem/pretag_xfem.F
!||--- called by ------------------------------------------------------
!||    pretag_xfem   ../starter/source/elements/xfem/pretag_xfem.F
!||====================================================================
      SUBROUTINE tag_sh(ITAGE,IEL_CRKXFEM,ECRKXFE,LFT,LLT,NFT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAGE(*),IEL_CRKXFEM(*),ECRKXFE,LFT,LLT,NFT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C=======================================================================
      DO i=lft,llt
        IF (itage(i+nft) > 0) THEN
          ecrkxfe = ecrkxfe + 1
          iel_crkxfem(i+nft) = ecrkxfe
        ENDIF
      ENDDO
C-----------
      RETURN
      END