pslasizesyev.f

Go to the documentation of this file.

*
*
      SUBROUTINE pslasizesyev( JOBZ, N, DESCA, MINSIZE )
*
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ
      INTEGER            MINSIZE, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLASIZESYEV computes the amount of memory needed by PSSYEV
*  to calculate:
*    1)  Eigenvectors and eigenvalues if JOBZ = 'V'
*    2)  Eigenvalues only if JOBZ = 'N'
*
*  Arguments
*  =========
*
*     NP = the number of rows local to a given process.
*     NQ = the number of columns local to a given process.
*
*  JOBZ     (global input) CHARACTER*1
*           Specifies whether or not to compute the eigenvectors:
*           = 'N':  Compute eigenvalues only.
*           = 'V':  Compute eigenvalues and eigenvectors.
*
*  N        (global input) INTEGER
*           Size of the matrix to be tested.  (global size)
*
*  DESCA    (global input) INTEGER array dimension ( DLEN_ )
*
*  MINSIZE  (global output) INTEGER
*           Workspace required for PSSYEV to:
*           1)  Eigenvectors and eigenvalues if JOBZ = 'V'
*           2)  Eigenvalues only if JOBZ = 'N'
*
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            WANTZ
      INTEGER            CONTEXTC, CSRC_A, IACOL, IAROW, ICOFFA, IROFFA, 
     $                   LCM, LCMQ, LDC, MQ0, MYCOL, MYPCOLC, MYPROWC, 
     $                   MYROW, NB, NN, NP, NP0, NPCOL, NPCOLC, NPROCS, 
     $                   NPROW, NPROWC, NQ, NRC, QRMEM, RSRC_A, 
     $                   SIZEMQRLEFT, SIZEMQRRIGHT
*     ..
*     .. External Functions ..
*
*
      LOGICAL            LSAME
      INTEGER            ILCM, INDXG2P, NUMROC, SL_GRIDRESHAPE
      EXTERNAL           ilcm, indxg2p, lsame, numroc, sl_gridreshape
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, blacs_gridexit
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
      nb = desca( mb_ )
      n = desca( m_ )
      rsrc_a = desca( rsrc_ )
      csrc_a = desca( csrc_ )
      lcm = ilcm( nprow, npcol )
      lcmq = lcm / npcol
      iroffa = 0
      icoffa = 0
      iarow = indxg2p( 1, nb, myrow, rsrc_a, nprow )
      iacol = indxg2p( 1, nb, mycol, csrc_a, npcol )
      np = numroc( n+iroffa, nb, myrow, iarow, nprow )
      nq = numroc( n+icoffa, nb, mycol, iacol, npcol )
      sizemqrleft = max( ( nb*( nb-1 ) ) / 2, ( np+nq )*nb ) + nb*nb
      sizemqrright = max( ( nb*( nb-1 ) ) / 2,
     $               ( nq+max( np+numroc( numroc( n+icoffa, nb, 0, 0,
     $               npcol ), nb, 0, 0, lcmq ), np ) )*nb ) + nb*nb
      nn = max( n, nb, 2 )
      np0 = numroc( nn, nb, 0, 0, nprow )
      mq0 = numroc( nn, nb, 0, 0, npcol )
      nprocs = nprow*npcol
      wantz = lsame( jobz, 'V' )
      ldc = 0
*
*     Create the new context that is used in PSSYEV
*
      IF( wantz ) THEN
         contextc = sl_gridreshape( desca( ctxt_ ), 0, 1, 1, nprocs, 1 )
         CALL blacs_gridinfo( contextc, nprowc, npcolc, myprowc,
     $                        mypcolc )
         nrc = numroc( n, nb, myprowc, 0, nprocs)
         ldc = max( 1, nrc )
         CALL blacs_gridexit( contextc )
      END IF
 
*
*     Compute the total amount of space needed
*
      IF( wantz ) THEN
        qrmem = 5*n + max(  2*np0 +mq0 + nb*nn, 2*nn-2 ) + n*ldc 
        minsize = max( sizemqrleft, sizemqrright, qrmem )
      ELSE
         minsize = 5*n + 2*np0 +mq0 + nb*nn 
      END IF
*
      RETURN
*
*     End of PSLASIZESYEV
*
      END