pstrti2.f

Go to the documentation of this file.

      SUBROUTINE pstrti2( UPLO, DIAG, N, A, IA, JA, DESCA, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * )
*     ..
*
*  Purpose
*  =======
*
*  PSTRTI2 computes the inverse of a real upper or lower triangular
*  block matrix sub( A ) = A(IA:IA+N-1,JA:JA+N-1). This matrix should be
*  contained in one and only one process memory space (local operation).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER*1
*          = 'U':  sub( A ) is upper triangular;
*          = 'L':  sub( A ) is lower triangular.
*
*  DIAG    (global input) CHARACTER*1
*          = 'N':  sub( A ) is non-unit triangular
*          = 'U':  sub( A ) is unit triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)),
*          this array contains the local pieces of the triangular matrix
*          sub( A ). If UPLO = 'U', the leading N-by-N upper triangular
*          part of the matrix sub( A ) contains the upper triangular
*          matrix, and the strictly lower triangular part of sub( A )
*          is not referenced.  If UPLO = 'L', the leading N-by-N lower
*          triangular part of the matrix sub( A ) contains the lower
*          triangular matrix, and the strictly upper triangular part
*          of sub( A ) is not referenced. If DIAG = 'U', the diagonal
*          elements of sub( A ) are also not referenced and are assumed
*          to be 1.  On exit, the (triangular) inverse of the original
*          matrix, in the same storage format.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, UPPER
      INTEGER            IACOL, IAROW, ICTXT, ICURR, IDIAG, IIA, IOFFA,
     $                   JJA, LDA, MYCOL, MYROW, NA, NPCOL, NPROW
      REAL               AJJ
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, chk1mat, infog2l,
     $                   pxerbla, sscal, strmv
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(700+ctxt_)
      ELSE
         CALL chk1mat( n, 3, n, 3, ia, ja, desca, 7, info )
         upper = lsame( uplo, 'U' )
         nounit = lsame( diag, 'N' )
         IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
            info = -1
         ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
            info = -2
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PSTRTI2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      END IF
*
*     Compute local indexes
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
*
      IF( myrow.EQ.iarow .AND. mycol.EQ.iacol ) THEN
*
         lda = desca( lld_ )
*
         IF( upper ) THEN
*
            ioffa = iia + ( jja - 1 ) * lda
            icurr = ioffa + lda
*
            IF( nounit ) THEN
*
*              Compute inverse of upper non-unit triangular matrix.
*
               a( ioffa ) = one / a( ioffa )
               idiag = icurr + 1
               DO 10 na = 1, n-1
                  a( idiag ) = one / a( idiag )
                  ajj = -a( idiag )
*
*                 Compute elements 1:j-1 of j-th column.
*
                  CALL strmv( 'Upper', 'No transpose', diag, na,
     $                        a( ioffa ), lda, a( icurr ), 1 )
                  CALL sscal( na, ajj, a( icurr ), 1 )
                  idiag = idiag + lda + 1
                  icurr = icurr + lda
   10          CONTINUE
*
            ELSE
*
*              Compute inverse of upper unit triangular matrix.
*
               DO 20 na = 1, n-1
*
*                 Compute elements 1:j-1 of j-th column.
*
                  CALL strmv( 'Upper', 'No transpose', diag, na,
     $                        a( ioffa ), lda, a( icurr ), 1 )
                  CALL sscal( na, -one, a( icurr ), 1 )
                  icurr = icurr + lda
   20          CONTINUE
*
            END IF
*
         ELSE
*
            icurr = iia + n - 1 + ( jja + n - 2 ) * lda
            ioffa = icurr - lda
*
            IF( nounit ) THEN
*
*              Compute inverse of lower non-unit triangular matrix.
*
               a( icurr ) = one / a( icurr )
               idiag = ioffa - 1
               DO 30 na = 1, n-1
                  a( idiag ) = one / a( idiag )
                  ajj = -a( idiag )
*
*                 Compute elements j+1:n of j-th column.
*
                  CALL strmv( 'Lower', 'no transpose', DIAG, NA,
     $                        A( ICURR ), LDA, A( IOFFA ), 1 )
                  CALL SSCAL( NA, AJJ, A( IOFFA ), 1 )
                  ICURR = IDIAG
                  IDIAG = IDIAG - LDA - 1
                  IOFFA = IDIAG + 1
   30          CONTINUE
*
            ELSE
*
*              Compute inverse of lower unit triangular matrix.
*
               DO 40 NA = 1, N-1
*
*                 Compute elements j+1:n of j-th column.
*
                  CALL STRMV( 'lower', 'no transpose', DIAG, NA,
     $                     A( ICURR ), LDA, A( IOFFA ), 1 )
                  CALL SSCAL( NA, -ONE, A( IOFFA ), 1 )
                  ICURR = ICURR - LDA - 1
                  IOFFA = ICURR - LDA
   40          CONTINUE
*
            END IF
*
         END IF
*
      END IF
*
*     End of PSTRTI2
*
      END