pzfillpad.f

Go to the documentation of this file.

      SUBROUTINE pzfillpad( ICTXT, M, N, A, LDA, IPRE, IPOST, CHKVAL )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            ICTXT, IPOST, IPRE, LDA, M, N
      COMPLEX*16         CHKVAL
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZFILLPAD surrounds a two dimensional local array with a guard-
*  zone initialized to the value CHKVAL. The user may later call the
*  routine PZCHEKPAD to discover if the guardzone has been
*  violated. There are three guardzones. The first is a buffer of size
*  IPRE that is before the start of the array. The second is the buffer
*  of size IPOST which is after the end of the array to be padded.
*  Finally, there is a guard zone inside every column of the array to
*  be padded, in the elements of A(M+1:LDA, J).
*
*  Arguments
*  =========
*
*  ICTXT   (global input) INTEGER
*          The BLACS context handle, indicating the global context of
*          the operation. The context itself is global.
*
*  M       (local input) INTEGER
*          The number of rows in the local array.
*
*  N       (local input) INTEGER
*          The number of columns in the local array.
*
*  A       (local input/local output) COMPLEX*16, array of
*          dimension (LDA,N). A location IPRE elements in front of
*          the matrix to be padded.
*
*  LDA     (local input) INTEGER
*          The leading Dimension of the local array to be padded.
*
*  IPRE    (local input) INTEGER
*          The size of the guard zone to put before the start of
*          padded array.
*
*  IPOST   (local input) INTEGER
*          The size of the guard zone to put after padded array.
*
*  CHKVAL  (local input) COMPLEX*16
*          The value to pad matrix with.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J, K
*     ..
*     .. Executable Statements ..
*
*     Put check buffer in front of A
*
      IF( ipre.GT.0 ) THEN
         DO 10 i = 1, ipre
            a( i ) = chkval
   10    CONTINUE
      ELSE
         WRITE( *, fmt = * ) 'WARNING no pre-guardzone in PZFILLPAD'
      END IF
*
*     Put check buffer in back of A
*
      IF( ipost.GT.0 ) THEN
         j = ipre+lda*n+1
         DO 20 i = j, j+ipost-1
            a( i ) = chkval
   20    CONTINUE
      ELSE
         WRITE( *, fmt = * ) 'WARNING no post-guardzone in PZFILLPAD'
      END IF
*
*     Put check buffer in all (LDA-M) gaps
*
      IF( lda.GT.m ) THEN
         k = ipre + m + 1
         DO 40 j = 1, n
            DO 30 i = k, k + (lda-m) - 1
               a( i ) = chkval
   30       CONTINUE
            k = k + lda
   40    CONTINUE
      END IF
*
      RETURN
*
*     End of PZFILLPAD
*
      END