pzinvchk.f

Go to the documentation of this file.

      SUBROUTINE pzinvchk( MATTYP, N, A, IA, JA, DESCA, IASEED, ANORM,
     $                     FRESID, RCOND, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, IASEED, JA, N
      DOUBLE PRECISION   ANORM, FRESID, RCOND
*     ..
*     .. Array Arguments ..
      CHARACTER*3        MATTYP
      INTEGER            DESCA( * )
      COMPLEX*16         A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZINVCHK computes the scaled residual
*
*  || sub( A ) * inv( sub( A ) ) - I || / ( || sub( A ) || * N * eps ),
*
*  where sub( A ) denotes A(IA:IA+N-1,JA:JA+N-1). to check the result
*  returned by the matrix inversion routines.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  MATTYP   (global input) CHARACTER*3
*           The type of the distributed matrix to be generated:
*           if MATTYP = 'GEN' then GENeral matrix,
*           if MATTYP = 'UTR' then Upper TRiangular matrix,
*           if MATTYP = 'LTR' then Lower TRiangular matrix,
*           if MATTYP = 'UPD' then (Upper) Hermitian Positive Definite,
*           if MATTYP = 'LPD' then (Lower) Hermitian Positive Definite.
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input) COMPLEX*16 pointer into the local memory
*          to an array of local dimension (LLD_A, LOCc(JA+N-1)).  On
*          entry, sub( A ) contains the distributed matrix inverse
*          computed by PZGETRI, PZPOTRI or PZTRTRI.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IASEED  (global input) INTEGER
*          Seed for the random generation of sub( A ).
*
*  ANORM   (global input) DOUBLE PRECISION
*          The 1-norm of the original matrix sub( A ).
*
*  FRESID  (global output) DOUBLE PRECISION
*          The inversion residual.
*
*  RCOND   (global output) DOUBLE PRECISION
*          The condition number of the original distributed matrix.
*          RCOND = || sub( A ) ||.|| sub( A )^{-1} || where ||A||
*          denotes the 1-norm of A.
*
*  WORK    (local workspace) COMPLEX*16 array, dimension
*             MAX(2*LOCr(N_A+MOD(IA-1,MB_A))*MB_A, LDW)
*          where LDW is the workspace requirement for the norm computa-
*          tions, see PZLANGE, PZLANHE, PZLANSY and PZLANTR.
*
* =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX*16         ZERO,          ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          AFORM, DIAG, UPLO
      INTEGER            ICTXT, ICURCOL, ICURROW, II, IIA, IPW, IROFF,
     $                   iw, j, jb, jja, jn, kk, mycol, myrow, np,
     $                   npcol, nprow
      DOUBLE PRECISION   AUXNORM, EPS, NRMINVAXA, TEMP
*     ..
*     .. Local Arrays ..
      INTEGER            DESCW( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pzgemm,
     $                   pzhemm, pzlaset, pzmatgen, pztrmm
*     ..
*     .. External Functions ..
      LOGICAL            LSAMEN
      INTEGER            ICEIL, NUMROC
      DOUBLE PRECISION   PDLAMCH, PZLANGE, PZLANHE, PZLANTR
      EXTERNAL           iceil, lsamen, numroc, pdlamch, pzlange,
     $                   pzlanhe, pzlansy, pzlantr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
      eps = pdlamch( desca( ctxt_ ), 'eps' )
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Compute the condition number
*
      IF( lsamen( 1, mattyp( 1:1 ), 'U' ) ) THEN
         uplo = 'U'
      ELSE
         uplo = 'L'
      END IF
*
      IF( lsamen( 3, mattyp, 'GEN' ) ) THEN
*
         aform = 'N'
         diag = 'D'
         auxnorm = pzlange( '1', n, n, a, ia, ja, desca, work )
*
      ELSE IF( lsamen( 2, mattyp( 2:3 ), 'tr' ) ) THEN
*
         AFORM = 'n'
         DIAG = 'd'
         AUXNORM = PZLANTR( '1', UPLO, 'non unit', N, N, A, IA, JA,
     $                      DESCA, WORK )
      ELSE IF( LSAMEN( 2, MATTYP( 2:3 ), 'pd' ) ) THEN
*
         AFORM = 'h'
         DIAG = 'd'
         AUXNORM = PZLANHE( '1', UPLO, N, A, IA, JA, DESCA, WORK )
*
      END IF
      RCOND   = ANORM*AUXNORM
*
*     Compute inv(A)*A
*
      CALL INFOG2L( IA, JA, DESCA, NPROW, NPCOL, MYROW, MYCOL, IIA, JJA,
     $              ICURROW, ICURCOL )
*
*     Define array descriptor for working array WORK
*
      IROFF = MOD( IA-1, DESCA( MB_ ) )
      NP = NUMROC( N+IROFF, DESCA( MB_ ), MYROW, ICURROW, NPROW )
      CALL DESCSET( DESCW, N+IROFF, DESCA( NB_ ), DESCA( MB_ ),
     $              DESCA( NB_ ), ICURROW, ICURCOL, DESCA( CTXT_ ),
     $              MAX( 1, NP ) )
      IPW = DESCW( LLD_ ) * DESCW( NB_ ) + 1
*
.EQ.      IF( MYROWICURROW ) THEN
         II = IROFF + 1
         NP = NP - IROFF
      ELSE
         II = 1
      END IF
      JN = MIN( ICEIL( JA, DESCA( NB_ ) ) * DESCA( NB_ ), JA+N-1 )
      JB = JN - JA + 1
*
*     Handle first block separately, regenerate a block of columns of A
*
      IW = IROFF + 1
.EQ.      IF( MYCOLICURCOL ) THEN
         IF( LSAMEN( 2, MATTYP( 2:3 ), 'tr' ) ) THEN
            CALL PZMATGEN( ICTXT, AFORM, DIAG, DESCA( M_ ), DESCA( N_ ),
     $                     DESCW( MB_ ), DESCW( NB_ ), WORK,
     $                     DESCW( LLD_ ), DESCA( RSRC_ ),
     $                     DESCA( CSRC_ ), IASEED, IIA-1, NP,
     $                     JJA-1, JB, MYROW, MYCOL, NPROW, NPCOL )
            IF( LSAMEN( 3, MATTYP, 'utr' ) ) THEN
               CALL PZLASET( 'lower', N-1, JB, ZERO, ZERO, WORK, IW+1,
     $                       1, DESCW )
            ELSE
               CALL PZLASET( 'upper', jb-1, jb-1, zero, zero, work, iw,
     $                       2, descw )
            END IF
         ELSE
            CALL pzmatgen( ictxt, aform, diag, desca( m_ ), desca( n_ ),
     $                     descw( mb_ ), descw( nb_ ), work( ipw ),
     $                     descw( lld_ ), desca( rsrc_ ),
     $                     desca( csrc_ ), iaseed,
     $                     iia-1, np, jja-1, jb, myrow, mycol, nprow,
     $                     npcol )
         END IF
      END IF
*
*     Multiply A^{-1}*A
*
      IF( lsamen( 3, mattyp, 'GEN' ) ) THEN
*
         CALL pzgemm( 'No tranpose', 'No transpose', n, jb, n, one, a,
     $                ia, ja, desca, work( ipw ), iw, 1, descw, zero,
     $                work, iw, 1, descw )
*
      ELSE IF( lsamen( 2, mattyp( 2:3 ), 'TR' ) ) THEN
*
         CALL pztrmm( 'Left', uplo, 'No tranpose', 'Non unit', n, jb,
     $                one, a, ia, ja, desca, work, iw, 1, descw )
*
      ELSE IF( lsamen( 2, mattyp( 2:3 ), 'PD' ) ) THEN
*
         CALL pzhemm( 'Left', uplo, n, jb, one, a, ia, ja, desca,
     $                work(ipw), iw, 1, descw, zero, work, iw, 1,
     $                descw )
*
      END IF
*
*     subtract the identity matrix to the diagonal block of these cols
*
      IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
         DO 10 kk = 0, jb-1
            work( ii+kk*(descw(lld_)+1) ) =
     $                 work( ii+kk*(descw( lld_ )+1) )-one
   10    CONTINUE
      END IF
*
      nrminvaxa = pzlange( '1', n, jb, work, iw, 1, descw, work( ipw ) )
*
      IF( myrow.EQ.icurrow )
     $   ii = ii + jb
      IF( mycol.EQ.icurcol )
     $   jja = jja + jb
      icurrow = mod( icurrow+1, nprow )
      icurcol = mod( icurcol+1, npcol )
      descw( csrc_ ) = icurcol
*
      DO 30 j = jn+1, ja+n-1, desca( nb_ )
*
         jb = min( n-j+ja, desca( nb_ ) )
*
*        regenerate a block of columns of A
*
         IF( mycol.EQ.icurcol ) THEN
            IF( lsamen( 2, mattyp( 2:3 ), 'TR' ) ) THEN
               CALL pzmatgen( ictxt, aform, diag, desca( m_ ),
     $                        desca( n_ ), descw( mb_ ), descw( nb_ ),
     $                        work, descw( lld_ ), desca( rsrc_ ),
     $                        desca( csrc_ ),
     $                        iaseed, iia-1, np, jja-1, jb, myrow,
     $                        mycol, nprow, npcol )
               IF( lsamen( 3, mattyp, 'UTR' ) ) THEN
                  CALL pzlaset( 'Lower', ja+n-j-1, jb, zero, zero,
     $                       work, iw+j-ja+1, 1, descw )
               ELSE
                  CALL pzlaset( 'All', j-ja, jb, zero, zero, work, iw,
     $                          1, descw )
                  CALL pzlaset( 'Upper', jb-1, jb-1, zero, zero,
     $                          work, iw+j-ja, 2, descw )
               END IF
            ELSE
               CALL pzmatgen( ictxt, aform, diag, desca( m_ ),
     $                        desca( n_ ), descw( mb_ ), descw( nb_ ),
     $                        work( ipw ), descw( lld_ ),
     $                        desca( rsrc_ ), desca( csrc_ ), iaseed,
     $                        iia-1, np,
     $                        jja-1, jb, myrow, mycol, nprow, npcol )
            END IF
         END IF
*
*        Multiply A^{-1}*A
*
         IF( lsamen( 3, mattyp, 'GEN' ) ) THEN
*
            CALL pzgemm( 'No tranpose', 'No transpose', n, jb, n, one,
     $                   a, ia, ja, desca, work( ipw ), iw, 1, descw,
     $                   zero, work, iw, 1, descw )
*
         ELSE IF( lsamen( 2, mattyp(2:3), 'TR' ) ) THEN
*
            CALL pztrmm( 'Left', uplo, 'No tranpose', 'Non unit', n, jb,
     $                   one, a, ia, ja, desca, work, iw, 1, descw )
*
         ELSE IF( lsamen( 2, mattyp( 2:3 ), 'PD' ) ) THEN
*
            CALL pzhemm( 'Left', uplo, n, jb, one, a, ia, ja, desca,
     $                   work(ipw), iw, 1, descw, zero, work, iw, 1,
     $                   descw )
*
         END IF
*
*        subtract the identity matrix to the diagonal block of these
*        cols
*
         IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
            DO 20 kk = 0, jb-1
               work( ii+kk*(descw( lld_ )+1) ) =
     $                   work( ii+kk*(descw( lld_ )+1) ) - one
   20       CONTINUE
         END IF
*
*        Compute the 1-norm of these JB cols
*
         temp = pzlange( '1', n, jb, work, iw, 1, descw, work( ipw ) )
         nrminvaxa = max( temp, nrminvaxa )
*
         IF( myrow.EQ.icurrow )
     $      ii = ii + jb
         IF( mycol.EQ.icurcol )
     $      jja = jja + jb
         icurrow = mod( icurrow+1, nprow )
         icurcol = mod( icurcol+1, npcol )
         descw( csrc_ ) = icurcol
*
   30 CONTINUE
*
*     Compute the scaled residual
*
      fresid = nrminvaxa / ( n * eps * anorm )
*
      RETURN
*
*     End of PZINVCHK
*
      END