q4deric2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4deric2   ../engine/source/elements/solid_2d/quad4/q4deric2.F
!||--- called by ------------------------------------------------------
!||    q4forc2    ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||    q4ke2      ../engine/source/elements/solid_2d/quad4/q4ke2.F
!||====================================================================
      SUBROUTINE q4deric2(
     1   Y1,      Y2,      Y3,      Y4,
     2   Z1,      Z2,      Z3,      Z4,
     3   Y12,     Y34,     Y13,     Y24,
     4   Y14,     Y23,     Z12,     Z34,
     5   Z13,     Z24,     Z14,     Z23,
     6   PYC1,    PYC2,    PZC1,    PZC2,
     7   AIRE,    VOLU,    YAVG,    RX,
     8   RY,      RZ,      SX,      SY,
     9   SZ,      NEL,     JHBE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JHBE
C     REAL
      my_real
     .    Y1(*),Y2(*),Y3(*),Y4(*),Z1(*),Z2(*),Z3(*),Z4(*),
     .    Y12(*),Y34(*),Y13(*),Y24(*),Y14(*),Y23(*),
     .    Z12(*),Z34(*),Z13(*),Z24(*),Z14(*),Z23(*),
     .    PYC1(*),PYC2(*),PZC1(*),PZC2(*),AIRE(*),VOLU(*),
     .   RX(MVSIZ) , RY(MVSIZ) , RZ(MVSIZ) ,
     .   sx(mvsiz) , sy(mvsiz) , sz(mvsiz) ,yavg(*)
C-----------------------------------------------
c FUNCTION: 
c ARGUMENTS:  (I: input, O: output, IO: input & output, W: workspace)
c TYPE NAME                FUNCTION
c  I   Y1(*)~Z4(*)        - NODAL COORDINATES
c  O   Y12(*)~Z23(*)      - DIFFERENCE: Yi-Yj, Zi-Zj
c  O   PYC1(*)~PZC2(*)    - SHAPE DERIVATIVES AT ELEMENT CENTER
c  I   AIRE(*)            - ELEMENT AREA
c  I/O VOL(*)            - ELEMENT VOL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .    Y,Z,V0
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      DO I=1,nel
        y12(i) = y1(i) - y2(i)
        y34(i) = y3(i) - y4(i)
        y13(i) = y1(i) - y3(i)
        y24(i) = y2(i) - y4(i)
        y14(i) = y1(i) - y4(i)
        y23(i) = y2(i) - y3(i)
        z12(i) = z1(i) - z2(i)
        z34(i) = z3(i) - z4(i)
        z13(i) = z1(i) - z3(i)
        z24(i) = z2(i) - z4(i)
        z14(i) = z1(i) - z4(i)
        z23(i) = z2(i) - z3(i)
      END DO
C
      DO i=1,nel
C       dNi/dY, dNi/dZ, A=4.*|J|
        pyc1(i) = half*(z2(i)-z4(i))/aire(i)
        pyc2(i) = half*(z3(i)-z1(i))/aire(i)
        pzc1(i) = half*(y4(i)-y2(i))/aire(i)
        pzc2(i) = half*(y1(i)-y3(i))/aire(i)
      ENDDO
C     COMPUTE VOLUME/(2*PI) FOR AXISYMMETRIC CASE 
      IF(n2d==1.AND.jhbe==17) THEN
          DO i=1,nel
            volu(i) = fourth*yavg(i)*aire(i)
          ENDDO
      ENDIF
      DO i=1,nel
        rx(i) = one
        ry(i) = zero
        rz(i) = zero
        sx(i) = zero
        sy(i) =half*(y2(i)+y3(i)-y1(i)-y4(i))
        sz(i) =half*(z2(i)+z3(i)-z1(i)-z4(i))
      END DO
C
      RETURN
      END