q4fintc2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4fintc2   ../engine/source/elements/solid_2d/quad4/q4fintc2.F
!||--- called by ------------------------------------------------------
!||    q4forc2    ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||====================================================================
      SUBROUTINE q4fintc2(
     1   PYC1,    PYC2,    PZC1,    PZC2,
     2   AY,      FAY,     FY1,     FZ1,
     3   FY2,     FZ2,     FY3,     FZ3,
     4   FY4,     FZ4,     AIRE,    VOLU,
     5   SIGM,    PP,      ICP,     NEL,
     6   JHBE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JHBE
      INTEGER ICP,NEL
C     REAL
      my_real
     .    PYC1(*),PYC2(*),PZC1(*),PZC2(*),AY(*),FAY(*),
     .    FY1(*),FZ1(*),FY2(*),FZ2(*),
     .    fy3(*),fz3(*),fy4(*),fz4(*),
     .    aire(*),volu(*),sigm(nel,6),pp(*)
C-----------------------------------------------
C FUNCTION: 
C ARGUMENTS:  (I: input, O: output, IO: input & output, W: workspace)
C TYPE NAME                FUNCTION
C  I   PYC1(*)~PZC2(*)    - SHAPE DERIVATIVES AT ELEMENT CENTER
C  O   FY1(*)~FZ4(*)      - INTERNAL FORCE IN LOCAL STORAGE
C  I   AIRE(*)            - ELEMENT AREA
C  I   VOLU(*)            - VOLUME/THICKNESS OR VOLUME/(2*PI)
C  I   SIGM(NEL,6)          - ELEMENT AVERAGE STRESS COMPONENTS
C  I   PP(*)              - ELEMENT AVERAGE PRESSURE
C  I   ICP                - FLAG FOR CONSTANT PRESURE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   SV,SY,SZ,FAC(MVSIZ)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      IF(n2d==1 .AND. jhbe==17) THEN
        DO i=1,nel
          fac(i) = aire(i)
        ENDDO
      ELSE
        DO i=1,nel
          fac(i) = volu(i)
        ENDDO
      ENDIF
C
C     FOR CONSTANT SHEAR STRAIN
      DO i=1,nel
        sv = sigm(i,4)*fac(i)
        sy = sv*pzc1(i)
        sz = sv*pyc1(i)
        fy1(i) = fy1(i) - sy
        fz1(i) = fz1(i) - sz
        fy3(i) = fy3(i) + sy
        fz3(i) = fz3(i) + sz
        sy = sv*pzc2(i)
        sz = sv*pyc2(i)
        fy2(i) = fy2(i) - sy
        fz2(i) = fz2(i) - sz
        fy4(i) = fy4(i) + sy
        fz4(i) = fz4(i) + sz
      ENDDO
C
C     FOR CONSTANT PRESSURE CASE
      IF(icp==1) THEN
        DO i=1,nel
          sv = pp(i)*fac(i)
          sy = sv*pyc1(i)
          sz = sv*pzc1(i)
          fy1(i) = fy1(i) - sy
          fz1(i) = fz1(i) - sz
          fy3(i) = fy3(i) + sy
          fz3(i) = fz3(i) + sz
          sy = sv*pyc2(i)
          sz = sv*pzc2(i)
          fy2(i) = fy2(i) - sy
          fz2(i) = fz2(i) - sz
          fy4(i) = fy4(i) + sy
          fz4(i) = fz4(i) + sz
        ENDDO
      ENDIF
C
      RETURN
      END