q4kega2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4kega2     ../engine/source/elements/solid_2d/quad4/q4kega2.F
!||--- called by ------------------------------------------------------
!||    q4ke2       ../engine/source/elements/solid_2d/quad4/q4ke2.F
!||--- calls      -----------------------------------------------------
!||    q4kegaij2   ../engine/source/elements/solid_2d/quad4/q4kegaij2.F
!||====================================================================
      SUBROUTINE q4kega2(
     1   PY1,     PY2,     PZ1,     PZ2,
     2   AY,      K11,     K12,     K13,
     3   K14,     K22,     K23,     K24,
     4   K33,     K34,     K44,     SIG,
     5   AIR,     OFF,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL
      my_real
     .    PY1(*), PY2(*), PZ1(*), PZ2(*), AY(*), 
     .    K11(2,2,*), K12(2,2,*), K13(2,2,*), K14(2,2,*), K22(2,2,*),
     .    K23(2,2,*), K24(2,2,*), K33(2,2,*), K34(2,2,*), K44(2,2,*),
     .    sig(nel,6), air(*), off(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K
      my_real
     .    FYY(MVSIZ),FZZ(MVSIZ),FXX(MVSIZ),FYZ(MVSIZ),AYS(MVSIZ),
     .    GIJ(MVSIZ), HIJ(2,2,MVSIZ)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      DO i=1,nel
        fyy(i)=sig(i,1)*air(i)
        fzz(i)=sig(i,2)*air(i)
        fyz(i)=sig(i,4)*air(i)
      ENDDO
      IF (n2d==1) THEN
        DO i=1,nel
          fxx(i)=sig(i,3)*air(i)
          ays(i)=ay(i)*ay(i)
        ENDDO
      ENDIF
C-----K11,K13,K33
      CALL q4kegaij2(1, nel, 
     .               py1, pz1, py1, pz1, ays, gij, hij,  
     .               fyy, fzz, fxx, fyz)
      DO i=1,nel
        DO j=1,2
          k11(j,j,i) = k11(j,j,i) + gij(i)
          k13(j,j,i) = k13(j,j,i) - gij(i)
          k33(j,j,i) = k33(j,j,i) + gij(i)
        ENDDO
        DO j=1,2
        DO k=1,2
          k11(k,j,i) = k11(k,j,i) - hij(k,j,i)
          k13(k,j,i) = k13(k,j,i) + hij(k,j,i)
          k33(k,j,i) = k33(k,j,i) - hij(k,j,i)
        ENDDO
        ENDDO
      ENDDO
C-----K22,K24,K44
      CALL q4kegaij2(1, nel, 
     .               py2, pz2, py2, pz2, ays, gij, hij,  
     .               fyy, fzz, fxx, fyz)
      DO i=1,nel
        DO j=1,2
          k22(j,j,i) = k22(j,j,i) + gij(i)
          k24(j,j,i) = k24(j,j,i) - gij(i)
          k44(j,j,i) = k44(j,j,i) + gij(i)
        ENDDO
        DO j=1,2
        DO k=1,2
          k22(k,j,i) = k22(k,j,i) - hij(k,j,i)
          k24(k,j,i) = k24(k,j,i) + hij(k,j,i)
          k44(k,j,i) = k44(k,j,i) - hij(k,j,i)
        ENDDO
        ENDDO
      ENDDO
C-----K12,K14,K34,K23
      CALL q4kegaij2(1, nel, 
     .               py1, pz1, py2, pz2, ays, gij, hij,  
     .               fyy, fzz, fxx, fyz)
      DO i=1,nel
        DO j=1,2
          k12(j,j,i) = k12(j,j,i) + gij(i)
          k14(j,j,i) = k14(j,j,i) - gij(i)
          k34(j,j,i) = k34(j,j,i) + gij(i)
          k23(j,j,i) = k23(j,j,i) - gij(i)
        ENDDO
        DO j=1,2
        DO k=1,2
          k12(k,j,i) = k12(k,j,i) - hij(k,j,i)
          k14(k,j,i) = k14(k,j,i) + hij(k,j,i)
          k34(k,j,i) = k34(k,j,i) - hij(k,j,i)
        ENDDO
        ENDDO
        k23(1,1,i) = k23(1,1,i) + hij(1,1,i)
        k23(2,2,i) = k23(2,2,i) + hij(2,2,i)
        k23(1,2,i) = k23(1,2,i) + hij(2,1,i)
        k23(2,1,i) = k23(2,1,i) + hij(1,2,i)
      ENDDO
C
      RETURN
      END