qbilan.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    qbilan                ../engine/source/elements/solid_2d/quad/qbilan.F
!||--- called by ------------------------------------------------------
!||    bforc2                ../engine/source/ale/bimat/bforc2.f
!||    q4forc2               ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||    qforc2                ../engine/source/elements/solid_2d/quad/qforc2.F
!||--- calls      -----------------------------------------------------
!||    grelem_sav            ../engine/source/output/th/grelem_sav.F
!||    sensor_energy_bilan   ../engine/source/tools/sensor/sensor_energy_bilan.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod            ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE qbilan(
     1   PARTSAV, OFF,     EINT,    RHO,
     2   RK,      VOL,     VY1,     VY2,
     3   VY3,     VY4,     VZ1,     VZ2,
     4   VZ3,     VZ4,     VNEW,    IPARTQ,
     5   EHOU,    R22,     R23,     R32,
     6   R33,     GRESAV,  GRTH,    IGRTH,
     7   IEXPAN,  EINTTH,  ITASK,   NEL,
     8   JTUR,    JCVT,    IGRE,SENSORS,
     9   G_WPLA,  WPLA)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C----6------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JTUR
      INTEGER, INTENT(IN) :: JCVT
      INTEGER, INTENT(IN) :: IGRE
      my_real
     .   PARTSAV(NPSAV,*), OFF(*), EINT(*), RHO(*), RK(*), VOL(*),
     .   VY1(*),VY2(*),VY3(*),VY4(*),VZ1(*),VZ2(*),VZ3(*),VZ4(*),
     .   VNEW(*), EHOU(*), R22(*), R23(*), R32(*), R33(*),GRESAV(*),
     .   EINTTH(*)
      INTEGER IEXPAN,ITASK,
     .   ipartq(*),grth(*),igrth(*)
      type (sensors_),INTENT(INOUT) :: SENSORS
      INTEGER, INTENT(IN) :: G_WPLA
      my_real,DIMENSION(NEL*G_WPLA), INTENT(IN) :: wpla
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .  vya(mvsiz), vza(mvsiz), va2(mvsiz), xmas(mvsiz), vy, vz,
     .  off_sav(mvsiz),rbidon(1),ei_sav(mvsiz),ek_sav(mvsiz),
     .  xm_sav(mvsiz),ym_sav(mvsiz),zm_sav(mvsiz),ei(mvsiz),ek(mvsiz)
      INTEGER I,M, FLAG
C-----------------------------------------------
      rbidon = zero
      off_sav= zero
      ei_sav = zero
      ek_sav = zero
      xm_sav = zero
      ym_sav = zero
      zm_sav = zero
      
      DO i=1,nel
        vya(i)=vy1(i)+vy2(i)+vy3(i)+vy4(i)
        vza(i)=vz1(i)+vz2(i)+vz3(i)+vz4(i)
      ENDDO
 
      IF(jcvt/=0)THEN
        DO i=1,nel
          vy=r22(i)*vya(i)+r23(i)*vza(i)
          vz=r32(i)*vya(i)+r33(i)*vza(i)
          vya(i)=vy
          vza(i)=vz
        END DO
      END IF
 
      DO i=1,nel
        va2(i)=
     1         vy1(i)*vy1(i)+vy2(i)*vy2(i)+vy3(i)*vy3(i)+vy4(i)*vy4(i)
     2        +vz1(i)*vz1(i)+vz2(i)*vz2(i)+vz3(i)*vz3(i)+vz4(i)*vz4(i)
      ENDDO
 
      DO i=1,nel
        xmas(i)=rho(i)*vnew(i)*off(i)  
      ENDDO
 
      flag = 0
      IF (igre /= 0) THEN
          DO i=1,nel
            off_sav(i) = one
            ei_sav(i)  = eint(i)*vol(i)
            ek_sav(i)  = xmas(i)*va2(i)*one_over_8
            xm_sav(i)  = zero
            ym_sav(i)  = xmas(i)*vya(i)*fourth
            zm_sav(i)  = xmas(i)*vza(i)*fourth
          ENDDO
          CALL grelem_sav(1   ,nel   ,gresav,igrth ,grth  ,
     2                    off_sav,ei_sav,ek_sav,xm_sav,ym_sav,
     3                    zm_sav,xmas  ,rbidon,rbidon,rbidon,
     4                    rbidon,rbidon,rbidon,rbidon,rbidon,
     5                    rbidon,rbidon,rbidon,rbidon,rbidon,
     6                    rbidon,flag)
      ENDIF
 
      DO i=1,nel
        m=ipartq(i)
        partsav(1,m)=partsav(1,m) + eint(i)*vol(i)*off(i)
        partsav(2,m)=partsav(2,m) + xmas(i)*va2(i)*one_over_8
        partsav(3,m)=zero
        partsav(4,m)=partsav(4,m) + xmas(i)*vya(i)*fourth
        partsav(5,m)=partsav(5,m) + xmas(i)*vza(i)*fourth
        partsav(6,m)=partsav(6,m) + xmas(i)
        IF (g_wpla > 0)  partsav(29,m)=partsav(29,m) + wpla(i)
      ENDDO
 
      IF(jtur/=0)THEN
       DO i=1,nel
         m=ipartq(i)
         partsav(7,m)=partsav(7,m) + rk(i)*vol(i)*off(i)
       ENDDO
      ENDIF
 
      IF(iexpan/=0)THEN
       DO i=1,nel
        m=ipartq(i)
        partsav(27,m)=partsav(27,m) + eintth(i)*vol(i)*off(i)
       ENDDO
      ENDIF
 
      DO i=1,nel
        m=ipartq(i)
        ei(i) = eint(i)*vol(i)*off(i)
        ek(i) = xmas(i)*va2(i)*one_over_8
      ENDDO
      CALL sensor_energy_bilan(1,nel,ei,ek,off,ipartq,itask,sensors)  
 
      RETURN
      END