qvolu2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    qvolu2                ../engine/source/elements/solid_2d/quad/qvolu2.F
!||--- called by ------------------------------------------------------
!||    bforc2                ../engine/source/ale/bimat/bforc2.F
!||    multi_computevolume   ../engine/source/multifluid/multi_computevolume.F
!||    q4forc2               ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||    q4ke2                 ../engine/source/elements/solid_2d/quad4/q4ke2.F
!||    qforc2                ../engine/source/elements/solid_2d/quad/qforc2.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                ../engine/source/output/message/message.F
!||    arret                 ../engine/source/system/arret.F
!||--- uses       -----------------------------------------------------
!||    message_mod           ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE qvolu2(
     1   OFF,     AIRE,    VOLU,    NGL,
     2   Y1,      Y2,      Y3,      Y4,
     3   Z1,      Z2,      Z3,      Z4,
     4   Y234,    Y124,    NEL,     JMULT,
     5   JCVT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JMULT
      INTEGER, INTENT(IN) :: JCVT
      INTEGER, INTENT(IN) :: NGL(NEL)
      my_real, INTENT(IN) ::  Y1(NEL),Y2(NEL),Y3(NEL),Y4(NEL),Z1(NEL),Z2(NEL),Z3(NEL),Z4(NEL),Y234(NEL),Y124(NEL)
      my_real, INTENT(INOUT) :: off(nel),aire(nel),volu(nel)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com06_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real A1(MVSIZ), A2(MVSIZ)
C-----------------------------------------------
C  S o u r c e   L i n e s
C-----------------------------------------------
      DO i=1,nel
        a1(i) =y2(i)*(z3(i)-z4(i))+y3(i)*(z4(i)-z2(i))+y4(i)*(z2(i)-z3(i))
        a2(i) =y2(i)*(z4(i)-z1(i))+y4(i)*(z1(i)-z2(i))+y1(i)*(z2(i)-z4(i))
        aire(i)=(a1(i)+a2(i))*half
      ENDDO
C-----------------------------------------------
      IF(n2d == 1) THEN
        IF(jcvt == 0)THEN
          DO i=1,nel
            volu(i)=((y2(i)+y3(i)+y4(i))*a1(i)+(y1(i)+y2(i)+y4(i))*a2(i))*one_over_6
          ENDDO
        ELSE
          DO i=1,nel
           volu(i)=(y234(i)*a1(i)+y124(i)*a2(i))*one_over_6
          ENDDO
        END IF
      ELSE
        DO i=1,nel
          volu(i)=aire(i)
        ENDDO
      ENDIF
C-----------------------------------------------
      IF(jmult == 0)THEN
        DO i=1,nel
          IF(off(i) == zero)THEN
            volu(i)=one
            aire(i)=one
          ELSE
            IF(volu(i) <= volmin)THEN
              volu(i)=one
              off(i)=zero
              CALL ancmsg(msgid=142,anmode=aninfo,i1=ngl(i))
              idel7nok = 1
            ENDIF
          ENDIF
        ENDDO
      ENDIF
C-----------------------------------------------
      DO i=1,nel
        IF(off(i) >= one .AND. volu(i) <= zero) THEN
          CALL ancmsg(msgid=142,anmode=aninfo,i1=ngl(i))
          CALL arret(2)
        ENDIF
      ENDDO
C-----------------------------------------------
      RETURN
      END