r2cum3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r2cum3      ../engine/source/elements/spring/r2cum3.F
!||--- called by ------------------------------------------------------
!||    r23law108   ../engine/source/elements/spring/r23law108.F
!||    rforc3      ../engine/source/elements/spring/rforc3.F
!||====================================================================
      SUBROUTINE r2cum3(
     1   F,       FORX,    FORY,    FORZ,
     2   XM,      XMOM,    YMOM,    ZMOM,
     3   STI,     STIR,    STIFN,   STIFR,
     4   FX1,     FX2,     FY1,     FY2,
     5   FZ1,     FZ2,     MX1,     MX2,
     6   MY1,     MY2,     MZ1,     MZ2,
     7   GEO,     X1,      Y1,      Z1,
     8   X2,      Y2,      Z2,      IEQUIL,
     9   EXX,     EYX,     EZX,     EXY,
     A   EYY,     EZY,     EXZ,     EYZ,
     B   EZZ,     NC1,     NC2,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(*),NC2(*),IEQUIL(*)
C     REAL
      my_real
     .   F(3,*),FORX(*),FORY(*),FORZ(*),XM(3,*),XMOM(*),YMOM(*),
     .   ZMOM(*),STI(3,*),STIR(3,*),STIFN(*),STIFR(*),
     .   FX1(MVSIZ),FY1(MVSIZ),FZ1(MVSIZ),
     .   FX2(MVSIZ),FY2(MVSIZ),FZ2(MVSIZ),
     .   MX1(MVSIZ),MY1(MVSIZ),MZ1(MVSIZ),
     .   MX2(MVSIZ),MY2(MVSIZ),MZ2(MVSIZ),
     .   GEO(NPROPG,*),X1(*),X2(*),Y1(*),Y2(*),
     .   z1(*),z2(*),
     .   exx(mvsiz), eyx(mvsiz), ezx(mvsiz), exy(mvsiz),
     .   eyy(mvsiz), ezy(mvsiz), exz(mvsiz), eyz(mvsiz), ezz(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
C     REAL
      my_real
     .   MMX, MMY, MMZ, XX
C-----------------------------------------------
C-------------------------
C     FORCES
C-------------------------
      DO I=1,nel
        fx2(i)=exx(i)*forx(i)+exy(i)*fory(i)+exz(i)*forz(i)
        fy2(i)=eyx(i)*forx(i)+eyy(i)*fory(i)+eyz(i)*forz(i)
        fz2(i)=ezx(i)*forx(i)+ezy(i)*fory(i)+ezz(i)*forz(i)
        fx1(i) = -fx2(i)
        fy1(i) = -fy2(i)
        fz1(i) = -fz2(i)
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      DO i=1,nel
        f(1,nc1(i))=f(1,nc1(i))-fx1(i)
        f(2,nc1(i))=f(2,nc1(i))-fy1(i)
        f(3,nc1(i))=f(3,nc1(i))-fz1(i)
        stifn(nc1(i))=stifn(nc1(i))+sti(1,i)
        f(1,nc2(i))=f(1,nc2(i))-fx2(i)
        f(2,nc2(i))=f(2,nc2(i))-fy2(i)
        f(3,nc2(i))=f(3,nc2(i))-fz2(i)
        stifn(nc2(i))=stifn(nc2(i))+sti(2,i)
      ENDDO
C-------------------------
C     MOMENTS
C-------------------------
      DO i=1,nel
        mx2(i)=exx(i)*xmom(i)+exy(i)*ymom(i)+exz(i)*zmom(i)
        my2(i)=eyx(i)*xmom(i)+eyy(i)*ymom(i)+eyz(i)*zmom(i)
        mz2(i)=ezx(i)*xmom(i)+ezy(i)*ymom(i)+ezz(i)*zmom(i)
        mx1(i) = -mx2(i)
        my1(i) = -my2(i)
        mz1(i) = -mz2(i)
      ENDDO
C
      DO i=1,nel
        IF (iequil(i) == 1) THEN
          mmx = half*((y2(i)-y1(i))*fz2(i) - (z2(i)-z1(i))*fy2(i))
          mmy = half*((z2(i)-z1(i))*fx2(i) - (x2(i)-x1(i))*fz2(i))
          mmz = half*((x2(i)-x1(i))*fy2(i) - (y2(i)-y1(i))*fx2(i)) 
          mx1(i) = mx1(i) - mmx
          my1(i) = my1(i) - mmy
          mz1(i) = mz1(i) - mmz
          mx2(i) = mx2(i) - mmx
          my2(i) = my2(i) - mmy
          mz2(i) = mz2(i) - mmz
          xx = (x2(i)-x1(i))*(x2(i)-x1(i)) 
     .       + (y2(i)-y1(i))*(y2(i)-y1(i))
     .       + (z2(i)-z1(i))*(z2(i)-z1(i))
          stir(1,i) = stir(1,i) + sti(2,i)*xx
          stir(2,i) = stir(2,i) + sti(1,i)*xx
        ENDIF
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      DO i=1,nel
        xm(1,nc1(i))=xm(1,nc1(i))-mx1(i)
        xm(2,nc1(i))=xm(2,nc1(i))-my1(i)
        xm(3,nc1(i))=xm(3,nc1(i))-mz1(i)
        stifr(nc1(i))=stifr(nc1(i))+stir(1,i)
        xm(1,nc2(i))=xm(1,nc2(i))-mx2(i)
        xm(2,nc2(i))=xm(2,nc2(i))-my2(i)
        xm(3,nc2(i))=xm(3,nc2(i))-mz2(i)
        stifr(nc2(i))=stifr(nc2(i))+stir(2,i)
      ENDDO
C---
      RETURN
      END