r4coork3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r4coork3   ../engine/source/elements/spring/r4coork3.F
!||--- called by ------------------------------------------------------
!||    r13ke3     ../engine/source/elements/spring/r13ke3.F
!||====================================================================
      SUBROUTINE r4coork3(JFT    ,JLT    ,X      ,NCC   ,PID    ,
     2                    NGL    ,AL     ,R11    ,R12   ,R13    , 
     3                    R21    ,R22    ,R23    ,R31   ,R32    ,
     4                    R33    ,RLOC   ,OFFG   ,OFF   )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "impl1_c.inc"
#include      "comlock.inc"
#include      "units_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT 
      INTEGER NCC(NIXR,*),PID(*),NGL(*)
C     REAL
      my_real
     .   x(3,*),al(*),
     .   r11(*),r12(*),r13(*),
     .   r21(*),r22(*),r23(*),
     .   r31(*),r32(*),r33(*),rloc(3,*),offg(*)   ,off(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J,NC1(MVSIZ),NC2(MVSIZ)
C     REAL
      my_real
     .   x1(mvsiz), x2(mvsiz),y1(mvsiz), y2(mvsiz),  
     .   z1(mvsiz), z2(mvsiz), norm
C-----------------------------------------------
C
      DO i=jft, jlt
       pid(i)=ncc(1,i)
       ngl(i)=ncc(5,i)
       nc1(i)=ncc(2,i)
       nc2(i)=ncc(3,i)
      ENDDO 
C----------------------------
C     COORDONNEES
C----------------------------
      DO i=jft, jlt
       x1(i)=x(1,nc1(i))
       y1(i)=x(2,nc1(i))
       z1(i)=x(3,nc1(i))
       x2(i)=x(1,nc2(i))
       y2(i)=x(2,nc2(i))
       z2(i)=x(3,nc2(i))
      ENDDO 
C----------------------------
C     LOCAL SYSTEM
C----------------------------
      DO  i=jft, jlt
       r12(i)=rloc(1,i)
       r22(i)=rloc(2,i)
       r32(i)=rloc(3,i)
       r11(i)=x2(i)-x1(i)
       r21(i)=y2(i)-y1(i)
       r31(i)=z2(i)-z1(i)
       al(i)=sqrt(r11(i)*r11(i)+r21(i)*r21(i)+r31(i)*r31(i))
      ENDDO 
C
      DO i=jft, jlt
       norm=one/max(em20,al(i))
       r11(i)=r11(i)*norm
       r21(i)=r21(i)*norm
       r31(i)=r31(i)*norm
      ENDDO 
      DO i=jft, jlt
       r13(i)=r21(i)*r32(i)-r31(i)*r22(i)
       r23(i)=r31(i)*r12(i)-r11(i)*r32(i)
       r33(i)=r11(i)*r22(i)-r21(i)*r12(i)
      ENDDO 
C
      DO i=jft, jlt
       norm=sqrt(r13(i)*r13(i)+r23(i)*r23(i)+r33(i)*r33(i))
       norm=one/max(em20,norm)
       r13(i)=r13(i)*norm
       r23(i)=r23(i)*norm
       r33(i)=r33(i)*norm
      ENDDO 
      DO i=jft, jlt
       r12(i)=r23(i)*r31(i)-r33(i)*r21(i)
       r22(i)=r33(i)*r11(i)-r13(i)*r31(i)
       r32(i)=r13(i)*r21(i)-r23(i)*r11(i)
      ENDDO 
      DO i=jft,jlt
       off(i)=offg(i)
      ENDDO
      IF (imp_chk > 0) THEN
       DO i=jft,jlt
        IF(offg(i)/=zero)THEN
         IF(al(i)<=em20)THEN
#include "lockon.inc"
            WRITE(iout ,2001) ngl(i)
#include "lockoff.inc"
            idel7nok = 1
            imp_ir = imp_ir + 1
         ENDIF 
        ENDIF 
       ENDDO
      ENDIF 
C
      RETURN
 2001 FORMAT(/'***ERROR :SPRING TYPE13 ZERO-LENGTH : ELEMENT NB:',
     .          i8/)
      END