r4cum3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r4cum3      ../engine/source/elements/spring/r4cum3.f
!||--- called by ------------------------------------------------------
!||    r23law113   ../engine/source/elements/spring/r23law113.F
!||    r23law114   ../engine/source/elements/spring/r23law114.F
!||    rforc3      ../engine/source/elements/spring/rforc3.F
!||====================================================================
      SUBROUTINE r4cum3(
     1   F,       FORX,    FORY,    FORZ,
     2   XM,      XMOM,    YMOM,    ZMOM,
     3   STI,     STIR,    STIFN,   STIFR,
     4   FX1,     FX2,     FY1,     FY2,
     5   FZ1,     FZ2,     MX1,     MX2,
     6   MY1,     MY2,     MZ1,     MZ2,
     7   AL,      EXX,     EYX,     EZX,
     8   EXY,     EYY,     EZY,     EXZ,
     9   EYZ,     EZZ,     NC1,     NC2,
     A   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(*),NC2(*)
C     REAL
      my_real
     .   F(3,*), FORX(*), FORY(*), FORZ(*), XM(3,*), XMOM(*),
     .   YMOM(*), ZMOM(*), STI(3,*),STIR(3,*),STIFN(*),STIFR(*),
     .   FX1(MVSIZ),FY1(MVSIZ),FZ1(MVSIZ),
     .   FX2(MVSIZ),FY2(MVSIZ),FZ2(MVSIZ),
     .   MX1(MVSIZ),MY1(MVSIZ),MZ1(MVSIZ),
     .   MX2(MVSIZ),MY2(MVSIZ),MZ2(MVSIZ),
     .   exx(mvsiz), eyx(mvsiz), ezx(mvsiz),
     .   exy(mvsiz), eyy(mvsiz), ezy(mvsiz),
     .   exz(mvsiz), eyz(mvsiz), ezz(mvsiz),al(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   F11(MVSIZ), F21(MVSIZ), F31(MVSIZ), 
     .   M11(MVSIZ), M21(MVSIZ), M31(MVSIZ),
     .   M12(MVSIZ), M22(MVSIZ), M32(MVSIZ),
     . YMOM1, YMOM2, ZMOM1, ZMOM2
C-----------------------------------------------
      DO I=1,nel
        f11(i)=exx(i)*forx(i)+exy(i)*fory(i)+exz(i)*forz(i)
        f21(i)=eyx(i)*forx(i)+eyy(i)*fory(i)+eyz(i)*forz(i)
        f31(i)=ezx(i)*forx(i)+ezy(i)*fory(i)+ezz(i)*forz(i)
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      DO i=1,nel
        f(1,nc1(i))=f(1,nc1(i))+f11(i)
        f(2,nc1(i))=f(2,nc1(i))+f21(i)
        f(3,nc1(i))=f(3,nc1(i))+f31(i)
        fx1(i) = -f11(i)
        fy1(i) = -f21(i)
        fz1(i) = -f31(i)
        stifn(nc1(i))=stifn(nc1(i))+sti(1,i)
C
        f(1,nc2(i))=f(1,nc2(i))-f11(i)
        f(2,nc2(i))=f(2,nc2(i))-f21(i)
        f(3,nc2(i))=f(3,nc2(i))-f31(i)
        fx2(i) = f11(i)
        fy2(i) = f21(i)
        fz2(i) = f31(i)
        stifn(nc2(i))=stifn(nc2(i))+sti(2,i)
      ENDDO
C-------------------------
C     MOMENTS
C-------------------------
      DO i=1,nel
        ymom1 = ymom(i) - half*al(i)*forz(i)
        zmom1 = zmom(i) + half*al(i)*fory(i)
        m11(i)=exx(i)*xmom(i)+exy(i)*ymom1+exz(i)*zmom1
        m21(i)=eyx(i)*xmom(i)+eyy(i)*ymom1+eyz(i)*zmom1
        m31(i)=ezx(i)*xmom(i)+ezy(i)*ymom1+ezz(i)*zmom1
        ymom2 = ymom(i) + half*al(i)*forz(i)
        zmom2 = zmom(i) - half*al(i)*fory(i)      
        m12(i)=exx(i)*xmom(i)+exy(i)*ymom2+exz(i)*zmom2
        m22(i)=eyx(i)*xmom(i)+eyy(i)*ymom2+eyz(i)*zmom2
        m32(i)=ezx(i)*xmom(i)+ezy(i)*ymom2+ezz(i)*zmom2
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      DO i=1,nel
        xm(1,nc1(i))=xm(1,nc1(i))+m11(i)
        xm(2,nc1(i))=xm(2,nc1(i))+m21(i)
        xm(3,nc1(i))=xm(3,nc1(i))+m31(i)
        mx1(i) = -m11(i)
        my1(i) = -m21(i)
        mz1(i) = -m31(i)
        stifr(nc1(i))=stifr(nc1(i))+stir(1,i)
C
        xm(1,nc2(i))=xm(1,nc2(i))-m12(i)
        xm(2,nc2(i))=xm(2,nc2(i))-m22(i)
        xm(3,nc2(i))=xm(3,nc2(i))-m32(i)
        mx2(i) = m12(i)
        my2(i) = m22(i)
        mz2(i) = m32(i)
        stifr(nc2(i))=stifr(nc2(i))+stir(2,i)
      ENDDO
C---
      RETURN
      END