rcum33.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rcum33    ../engine/source/elements/joint/rcum33.F
!||--- called by ------------------------------------------------------
!||    rgjoint   ../engine/source/elements/joint/rgjoint.F
!||====================================================================
      SUBROUTINE rcum33(JFT   ,JLT    ,XL    ,NC1  ,NC2    ,
     .                  F     ,FORX   ,FORY  ,FORZ ,XM     ,
     .                  XMOM  ,YMOM   ,ZMOM  ,STI  ,STIR   ,
     .                  STIFN ,STIFR  ,FX1   ,FX2  ,FY1    ,
     .                  FY2   ,FZ1    ,FZ2   ,MX1  ,MX2    ,
     .                  MY1   ,MY2    ,MZ1   ,MZ2  ,NUVAR  ,
     .                  UVAR)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT,NUVAR,NC1(*),NC2(*)
C     REAL
      my_real
     .   F(3,*), FORX(*), FORY(*), FORZ(*), XM(3,*), XMOM(*),
     .   YMOM(*), ZMOM(*), STI(3,*),STIR(3,*),STIFN(*),STIFR(*),
     .   FX1(*) ,FX2(*)  ,FY1(*),  FY2(*) ,FZ1(*)  ,
     .   fz2(*), mx1(*) ,mx2(*)  ,my1(*),  my2(*) ,mz1(*)  ,
     .   mz2(*),uvar(nuvar,*)
      DOUBLE PRECISION XL(MVSIZ,3)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
      my_real F11(MVSIZ), F21(MVSIZ), F31(MVSIZ),
     .        m11(mvsiz), m21(mvsiz), m31(mvsiz),
     .        m12(mvsiz), m22(mvsiz), m32(mvsiz),
     .        xmom1, xmom2, ymom1, ymom2, zmom1, zmom2, m1,m2,m3,
     .        ex(9), xx
C=======================================================================
C-------------------------
C     FORCES
C-------------------------
      DO i=jft,jlt
        DO j=1,9
          ex(j) = uvar(21+j,i)
        ENDDO
        f11(i)=ex(1)*forx(i)+ex(4)*fory(i)+ex(7)*forz(i)
        f21(i)=ex(2)*forx(i)+ex(5)*fory(i)+ex(8)*forz(i)
        f31(i)=ex(3)*forx(i)+ex(6)*fory(i)+ex(9)*forz(i)
      ENDDO
   
C----  Assembly
      DO i=jft,jlt
        f(1,nc1(i))=f(1,nc1(i))+f11(i)
        f(2,nc1(i))=f(2,nc1(i))+f21(i)
        f(3,nc1(i))=f(3,nc1(i))+f31(i)
        fx1(i) = -f11(i)
        fy1(i) = -f21(i)
        fz1(i) = -f31(i)
        stifn(nc1(i))=stifn(nc1(i))+two*sti(1,i)
        f(1,nc2(i))=f(1,nc2(i))-f11(i)
        f(2,nc2(i))=f(2,nc2(i))-f21(i)
        f(3,nc2(i))=f(3,nc2(i))-f31(i)
        fx2(i) = f11(i)
        fy2(i) = f21(i)
        fz2(i) = f31(i)
        stifn(nc2(i))=stifn(nc2(i))+two*sti(2,i)
      ENDDO
C
C-------------------------
C     MOMENTS
C-------------------------
C
      DO i=jft,jlt
C      
        DO j=1,9
          ex(j) = uvar(21+j,i)
        END DO
        m1 = half*(xl(i,2)*forz(i)-xl(i,3)*fory(i))
        m2 = half*(xl(i,3)*forx(i)-xl(i,1)*forz(i))
        m3 = half*(xl(i,1)*fory(i)-xl(i,2)*forx(i))
        xmom1 = xmom(i) + m1
        ymom1 = ymom(i) + m2
        zmom1 = zmom(i) + m3
        m11(i)=ex(1)*xmom1+ex(4)*ymom1+ex(7)*zmom1
        m21(i)=ex(2)*xmom1+ex(5)*ymom1+ex(8)*zmom1
        m31(i)=ex(3)*xmom1+ex(6)*ymom1+ex(9)*zmom1
C
        xmom2 = xmom(i) - m1
        ymom2 = ymom(i) - m2
        zmom2 = zmom(i) - m3
        m12(i)=ex(1)*xmom2+ex(4)*ymom2+ex(7)*zmom2
        m22(i)=ex(2)*xmom2+ex(5)*ymom2+ex(8)*zmom2
        m32(i)=ex(3)*xmom2+ex(6)*ymom2+ex(9)*zmom2
C
        xx = xl(i,1)*xl(i,1) + xl(i,2)*xl(i,2) + xl(i,3)*xl(i,3)
        stir(1,i) = stir(1,i) + sti(2,i)*xx
        stir(2,i) = stir(2,i) + sti(1,i)*xx
      ENDDO
 
C----   Assembly
      DO i=jft,jlt
        xm(1,nc1(i))=xm(1,nc1(i))+m11(i)
        xm(2,nc1(i))=xm(2,nc1(i))+m21(i)
        xm(3,nc1(i))=xm(3,nc1(i))+m31(i)
        mx1(i) = -m11(i)
        my1(i) = -m21(i)
        mz1(i) = -m31(i)
        stifr(nc1(i))=stifr(nc1(i))+stir(1,i)
        xm(1,nc2(i))=xm(1,nc2(i))-m12(i)
        xm(2,nc2(i))=xm(2,nc2(i))-m22(i)
        xm(3,nc2(i))=xm(3,nc2(i))-m32(i)
        mx2(i) = m12(i)
        my2(i) = m22(i)
        mz2(i) = m32(i)
        stifr(nc2(i))=stifr(nc2(i))+stir(2,i)
      ENDDO
C-----------------------------------------------
      RETURN
      END