read_joint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_joint   ../engine/source/output/restart/read_joint.F
!||--- called by ------------------------------------------------------
!||    rdresb       ../engine/source/output/restart/rdresb.F
!||--- calls      -----------------------------------------------------
!||    read_i_c     ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    joint_mod    ../engine/share/modules/joint_mod.F
!||    restmod      ../engine/share/modules/restart_mod.F
!||====================================================================
        SUBROUTINE read_joint()
!$COMMENT
!       READ_JOINT description
!       read the joint structure 
!       
!       READ_JOINT organization :
!$ENDCOMMENT
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------     
        USE joint_mod
        USE restmod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: N,I,NUMBER_MAIN_NODE,IS_SMS_AVAILABLE
        INTEGER, DIMENSION(2) :: MAIN_NODE
        INTEGER, DIMENSION(NJOINT) :: NUMBER_NODE
        INTEGER, DIMENSION(:), ALLOCATABLE :: NODE_WEIGHT
 
        ALLOCATE(cyl_join(njoint))
        IF(njoint>0) THEN
            number_node(1:njoint) = 0
            !   number of node per proc (all proc --> size=nspmd)
            CALL read_i_c(number_node,njoint)
            !   ------------------------------
            DO n=1,njoint     
                !   number of node and node with weight=1
                cyl_join(n)%NUMBER_NODE = 0
                cyl_join(n)%NUMBER_NODE_WEIGHT = 0
                !   number of node sent
                ALLOCATE( cyl_join(n)%COMM_MPI%SIZE_SR(nspmd) )
                cyl_join(n)%COMM_MPI%SIZE_SR(1:nspmd) = 0
                !   ------------------------------
                IF(number_node(n)>0) THEN
                    !   number of node for the current joint
                    cyl_join(n)%NUMBER_NODE = number_node(n)
                    !   proc main for the current joint
                    CALL read_i_c(cyl_join(n)%PROC_MAIN,1)
                    !   number of proc for the current joint
                    CALL read_i_c(cyl_join(n)%NUMBER_PROC,1)
                    !   list of proc for the current joint
                    ALLOCATE( cyl_join(n)%LIST_PROC(cyl_join(n)%NUMBER_PROC) )
                    CALL read_i_c(cyl_join(n)%LIST_PROC,cyl_join(n)%NUMBER_PROC)
                    !   list of node for the current joint
                    ALLOCATE( cyl_join(n)%NODE(cyl_join(n)%NUMBER_NODE) )
                    CALL read_i_c(cyl_join(n)%NODE,cyl_join(n)%NUMBER_NODE)
                    !   weight array for the current joint
                    ALLOCATE( cyl_join(n)%WEIGHT(cyl_join(n)%NUMBER_NODE) )
                    CALL read_i_c(cyl_join(n)%WEIGHT,cyl_join(n)%NUMBER_NODE)
                    !   -----------
                    !   weight array index for the current joint                 
                    ALLOCATE( node_weight( cyl_join(n)%NUMBER_NODE ) )
                    DO  i=1,cyl_join(n)%NUMBER_NODE
                        IF(cyl_join(n)%WEIGHT(i)==1) THEN
                            cyl_join(n)%NUMBER_NODE_WEIGHT = cyl_join(n)%NUMBER_NODE_WEIGHT + 1
                            node_weight(cyl_join(n)%NUMBER_NODE_WEIGHT) = cyl_join(n)%NODE(i)
                        ENDIF
                    ENDDO
                    ALLOCATE( cyl_join(n)%NODE_WEIGHT( cyl_join(n)%NUMBER_NODE_WEIGHT ) )
                    DO i=1,cyl_join(n)%NUMBER_NODE_WEIGHT
                        cyl_join(n)%NODE_WEIGHT(i) = node_weight(i)
                    ENDDO                 
                    DEALLOCATE( node_weight )
                    !   -----------
                ENDIF
                !   ------------------------------
                !   number of sent node for mpi comm
                CALL read_i_c(cyl_join(n)%COMM_MPI%SIZE_SR,nspmd)
                !   main node
                ALLOCATE( cyl_join(n)%MAIN_NODE(2) )
                CALL read_i_c(main_node,2)
                cyl_join(n)%MAIN_NODE(1:2) = main_node(1:2)
 
                number_main_node = 0
                DO i=1,2
                    IF(cyl_join(n)%MAIN_NODE(i)>0) number_main_node = number_main_node + 1
                ENDDO
                !   number of main node 
                cyl_join(n)%NUMBER_MAIN_NODE = number_main_node
            ENDDO
            !   ------------------------------
            is_sms_available = 0
            CALL read_i_c(is_sms_available,1)
            IF(is_sms_available==0) THEN
                joint_sms = .false.
            ELSE
                joint_sms = .true.
            ENDIF
            IF(joint_sms) CALL read_i_c(ljoint,sljoint)
 
        ENDIF
C
        RETURN
        END SUBROUTINE read_joint