read_monvol.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_monvol                 ../starter/source/airbag/read_monvol.F
!||--- called by ------------------------------------------------------
!||    lectur                      ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                      ../starter/source/output/message/message.f
!||    fretitl                     ../starter/source/starter/freform.F
!||    hm_option_read_key          ../starter/source/devtools/hm_reader/hm_option_read_key.f
!||    hm_option_start             ../starter/source/devtools/hm_reader/hm_option_start.F
!||    hm_read_monvol_type1        ../starter/source/airbag/hm_read_monvol_type1.F
!||    hm_read_monvol_type10       ../starter/source/airbag/hm_read_monvol_type10.F
!||    hm_read_monvol_type11       ../starter/source/airbag/hm_read_monvol_type11.f
!||    hm_read_monvol_type2        ../starter/source/airbag/hm_read_monvol_type2.f
!||    hm_read_monvol_type3        ../starter/source/airbag/hm_read_monvol_type3.F
!||    hm_read_monvol_type4        ../starter/source/airbag/hm_read_monvol_type4.F
!||    hm_read_monvol_type5        ../starter/source/airbag/hm_read_monvol_type5.F
!||    hm_read_monvol_type6        ../starter/source/airbag/hm_read_monvol_type6.F
!||    hm_read_monvol_type7        ../starter/source/airbag/hm_read_monvol_type7.F
!||    hm_read_monvol_type8        ../starter/source/airbag/hm_read_monvol_type8.F
!||    hm_read_monvol_type9        ../starter/source/airbag/hm_read_monvol_type9.F
!||    hm_sz_r2r                   ../starter/source/coupling/rad2rad/routines_r2r.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod          ../starter/share/modules1/hm_option_read_mod.F
!||    hm_read_monvol_type10_mod   ../starter/source/airbag/hm_read_monvol_type10.F
!||    hm_read_monvol_type11_mod   ../starter/source/airbag/hm_read_monvol_type11.F
!||    hm_read_monvol_type1_mod    ../starter/source/airbag/hm_read_monvol_type1.F
!||    hm_read_monvol_type2_mod    ../starter/source/airbag/hm_read_monvol_type2.F
!||    hm_read_monvol_type3_mod    ../starter/source/airbag/hm_read_monvol_type3.F
!||    hm_read_monvol_type4_mod    ../starter/source/airbag/hm_read_monvol_type4.F
!||    hm_read_monvol_type5_mod    ../starter/source/airbag/hm_read_monvol_type5.F
!||    hm_read_monvol_type6_mod    ../starter/source/airbag/hm_read_monvol_type6.F
!||    hm_read_monvol_type7_mod    ../starter/source/airbag/hm_read_monvol_type7.F
!||    hm_read_monvol_type8_mod    ../starter/source/airbag/hm_read_monvol_type8.F
!||    hm_read_monvol_type9_mod    ../starter/source/airbag/hm_read_monvol_type9.F
!||    message_mod                 ../starter/share/message_module/message_mod.F
!||    monvol_struct_mod           ../starter/share/modules1/monvol_struct_mod.F
!||    r2r_mod                     ../starter/share/modules1/r2r_mod.F
!||    submodel_mod                ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE read_monvol(T_MONVOL, T_MONVOL_METADATA, ITAB, ITABM1, IPM, IGEO, 
     .     X, PM, GEO, IXC, IXTG, SENSORS,
     .     UNITAB, NPC, NPT, PLD, IGRSURF, IGRBRIC, NOM_OPT,IFRAME, XFRAME, 
     .     LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE r2r_mod
      USE message_mod
      USE groupdef_mod , only:group_,surf_
      USE monvol_struct_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE sensor_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
      USE hm_read_monvol_type1_mod  ,ONLY : hm_read_monvol_type1
      USE hm_read_monvol_type2_mod  ,ONLY : hm_read_monvol_type2
      USE hm_read_monvol_type3_mod  ,ONLY : hm_read_monvol_type3
      USE hm_read_monvol_type4_mod  ,ONLY : hm_read_monvol_type4
      USE hm_read_monvol_type5_mod  ,ONLY : hm_read_monvol_type5
      USE hm_read_monvol_type6_mod  ,ONLY : hm_read_monvol_type6
      USE hm_read_monvol_type7_mod  ,ONLY : hm_read_monvol_type7
      USE hm_read_monvol_type8_mod  ,ONLY : hm_read_monvol_type8
      USE hm_read_monvol_type9_mod  ,ONLY : hm_read_monvol_type9
      USE hm_read_monvol_type10_mod ,ONLY : hm_read_monvol_type10
      USE hm_read_monvol_type11_mod ,ONLY : hm_read_monvol_type11
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C     NVOLU
#include      "com04_c.inc"
C     KMONVO, IREC
#include      "scr17_c.inc"
C     NSUBDOM
#include      "r2r_c.inc"
C     NIMV, NRVOLU
#include      "param_c.inc"
C     LUNIT, NUNITS
C     IOUT
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(monvol_struct_), DIMENSION(NVOLU + NMONVOL), INTENT(INOUT) :: T_MONVOL
      TYPE(MONVOL_METADATA_), INTENT(INOUT) :: T_MONVOL_METADATA
      TYPE(UNIT_TYPE_), INTENT(IN) :: UNITAB
      my_real, INTENT(IN) :: x(3, numnod), geo(npropg, numgeo), pm(npropm, nummat), pld(2, *), 
     .     xframe(nxframe,*)
      INTEGER, INTENT(IN) :: NPC(*), NPT(*), ITAB(*), ITABM1(*), 
     .     ixc(nixc, numelc), ixtg(nixtg, numeltg),ipm(npropmi, nummat), 
     .     igeo(npropgi, numgeo),iframe(liskn,*)
      INTEGER, INTENT(INOUT) :: NOM_OPT(LNOPT1, *)
      TYPE (SURF_), INTENT(INOUT), DIMENSION(NSURF) :: IGRSURF
      TYPE (GROUP_), DIMENSION(NGRBRIC), INTENT(IN) :: IGRBRIC
      TYPE (SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE (SENSORS_) ,INTENT(IN) :: SENSORS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: II, JJ
      INTEGER :: NVB, ITYPE, ID, UID, LOCAL_UID
      CHARACTER(len=ncharkey) :: KEY
      CHARACTER(len=nchartitle) :: TITR
      LOGICAL :: FOUND
C-----------------------------------------------
C     B e g i n n i n g   o f   s o u r c e
C-----------------------------------------------
C     Beginning of MONVOL cards in the IIN file
      WRITE(iout, 1000)
      t_monvol_metadata%LCA = 0
      nvb = 0
C
!     **************************    !
!     MONVOL read with hm reader    !
!     **************************    !
      CALL hm_option_start('/MONVOL')
      DO ii = 1, nmonvol
         nvb = nvb + 1
C     Multidomain -> skip untagged monvols
         IF (nsubdom > 0) THEN
            IF( tagmon(nvb) == 0) THEN
            CALL hm_sz_r2r(tagmon, nvb, lsubmodel)
         ENDIF
         ENDIF
         CALL hm_option_read_key(lsubmodel, option_id = id, unit_id = uid, option_titr = titr,
     .        keyword2 = key)
         nom_opt(1, ii) = id
         CALL fretitl(titr,nom_opt(lnopt1-ltitr+1,ii),ltitr)
C     Check units
         found = .false.
         DO jj = 1,unitab%NUNITS
            IF (unitab%UNIT_ID(jj) == uid) THEN
               found = .true.
               local_uid = jj
               EXIT
            ENDIF
         ENDDO
         IF (.NOT. found) THEN
            CALL ancmsg(msgid = 659, anmode = aninfo, msgtype = msgerror,
     .           i2 = uid, i1 = id, c1 = 'MONITORED VOLUME', c2 = 'MONITORED VOLUME', c3=titr)
         ENDIF
         IF (key(1:4) == 'AREA') THEN
            itype = 1
         ELSEIF (key(1:4) == 'PRES') THEN
            itype = 2
         ELSEIF (key(1:3) == 'GAS') THEN
            itype = 3
         ELSEIF (key(1:7) == 'AIRBAG1') THEN
            itype = 7
         ELSEIF (key(1:6) == 'AIRBAG') THEN
            itype = 4
         ELSEIF (key(1:6) == 'COMMU1') THEN
            itype = 9
         ELSEIF (key(1:5) == 'COMMU') THEN
            itype = 5
         ELSEIF (key(1:7) == 'FVMBAG2') THEN
            itype = 11
         ELSEIF (key(1:7) == 'FVMBAG1') THEN
            itype = 8
         ELSEIF (key(1:6) == 'FVMBAG') THEN
            itype = 6
         ELSEIF (key(1:6) == 'LFLUID') THEN
            itype = 10
         ELSE
            itype = 0
            CALL ancmsg(msgid=7,anmode=aninfo,msgtype=msgerror,
     .           i1=id,c1=titr)
         ENDIF
 
         t_monvol(ii)%ID = id
         t_monvol(ii)%IVOLU(1) = id
         t_monvol(ii)%IVOLU(27) = -1 !ID_DT_OPTION  ( /DT/FVMBAG/[id_dt_option] )
         t_monvol(ii)%TYPE = itype
         t_monvol(ii)%IVOLU(2) = itype
         t_monvol(ii)%TITLE = trim(titr)
         
         WRITE(iout,1001) id, t_monvol(ii)%TITLE, key(1:len_trim(key))
 
         SELECT CASE(itype)
         CASE(1)
!     ************     !
!     /MONVOL/AREA     !
!     ************     !
            CALL hm_read_monvol_type1(t_monvol(ii),
     .           unitab, local_uid, igrsurf,
     .           itab, x, pm, geo, ixc, ixtg,lsubmodel)
         CASE(2)
!     ************     !
!     /MONVOL/PRES     !
!     ************     !
            CALL hm_read_monvol_type2(t_monvol(ii),
     .           unitab, local_uid, npc, igrsurf,
     .           itab, x, pm, geo, ixc, ixtg,lsubmodel)
         CASE(3)
!     ***********     !
!     /MONVOL/GAS     !
!     ***********     !
            CALL hm_read_monvol_type3(t_monvol(ii),
     .           unitab, local_uid, npc, igrsurf,
     .           itab, x, pm, geo, ixc, ixtg, lsubmodel)
         CASE(4)
!     **************     !
!     /MONVOL/AIRBAG     !
!     **************     !
            CALL hm_read_monvol_type4(t_monvol(ii), itabm1,
     .           sensors, npt, pld, unitab, local_uid, npc, igrsurf,
     .           itab, x, pm, geo, ixc, ixtg, lsubmodel)
         CASE(5)
!     *************     !
!     /MONVOL/COMMU     !
!     *************     !
            CALL hm_read_monvol_type5(t_monvol(ii), t_monvol_metadata, itabm1,
     .           sensors, npt, pld, 
     .           unitab, local_uid, npc, igrsurf, itab, x, pm, geo, ixc, ixtg,
     .           lsubmodel)
         CASE(6)
!     **************     !
!     /MONVOL/FVMBAG     !
!     **************     !
            CALL hm_read_monvol_type6(t_monvol(ii),
     .           sensors, npt, pld, igrbric,
     .           unitab,  npc, igrsurf, itab, x, pm, geo, ixc, ixtg,
     .           lsubmodel)
         CASE(7)
!     ***************     !
!     /MONVOL/AIRBAG1     !
!     ***************     !
            CALL hm_read_monvol_type7(t_monvol(ii), ipm, igeo, itabm1,
     .           sensors,
     .           unitab, local_uid, npc, igrsurf, itab, x, pm, geo, ixc, ixtg,
     .           lsubmodel)
         CASE(8)
!     ***************     !
!     /MONVOL/FVMBAG1     !
!     ***************     !
           CALL hm_read_monvol_type8(t_monvol(ii), ipm, igeo, itabm1,   
     .           sensors, iframe, xframe, igrbric,
     .           unitab, local_uid, npc, igrsurf, itab, x, pm, geo, ixc, ixtg, 
     .           lsubmodel)           
 
         CASE(9)
!     **************     !
!     /MONVOL/COMMU1     !
!     **************     !
            CALL hm_read_monvol_type9(t_monvol(ii), t_monvol_metadata, ipm, igeo, itabm1,   
     .           sensors,
     .           unitab, local_uid, npc, igrsurf, itab, x, pm, geo, ixc, ixtg,
     .           lsubmodel)
         CASE(10)
!     **************     !
!     /MONVOL/LFLUID     !
!     **************     !
            CALL hm_read_monvol_type10(t_monvol(ii),
     .           unitab,  npc, igrsurf, itab, x, pm, geo, ixc, ixtg,lsubmodel)
         CASE(11)
!     ***************     !
!     /MONVOL/FVMBAG2     !
!     ***************     !
            CALL hm_read_monvol_type11(t_monvol(ii), ipm, igeo, itabm1,   
     .           sensors, xframe, igrbric,
     .           unitab, local_uid, npc, igrsurf, itab, x, pm, geo, ixc, ixtg, 
     .           lsubmodel)
         END SELECT
      ENDDO
 
      nvolu = nvolu + nmonvol
 
      RETURN
 1000 FORMAT(
     . //,'     MONITORED VOLUME DEFINITION      '/
     .     '     ----------------------------     ')
 1001 FORMAT(//5x,'VOLUME NUMBER ',i10,
     .     / 5x,'------------------------',
     .     / 5x,'TITLE: ',a,
     .     / 5x,'TYPE OF MONITORED VOLUME. . . . . . . .=',a10)
      END SUBROUTINE read_monvol